Get dialyzer warnings working in umbrella apps. (#149)

* Get dialyzer warnings working in umbrella apps.

* Add helper functions after the function that needs them.

Author: hworld

apps/language_server/lib/language_server/dialyzer.ex

@@ -365,13 +365,13 @@ defmodule ElixirLS.LanguageServer.Dialyzer do
 
   defp add_warnings(warnings, raw_warnings) do
     new_warnings =
-      for {_, {file, line, m_or_mfa}, _} = warning <- raw_warnings, in_project?(file) do
-        module =
-          case m_or_mfa do
-            module when is_atom(module) -> module
-            {module, _, _} when is_atom(module) -> module
-          end
-
+      for {_, {file, line, m_or_mfa}, _} = warning <- raw_warnings,
+          module = resolve_module(m_or_mfa),
+          # Dialyzer warnings have the file path at the start of the app it's
+          # in, which breaks umbrella apps. We have to manually resolve the file
+          # from the module instead.
+          file = resolve_module_file(module, file),
+          in_project?(file) do
         {module, {file, line, warning}}
       end
 
@@ -380,6 +380,19 @@ defmodule ElixirLS.LanguageServer.Dialyzer do
     |> Enum.into(warnings)
   end
 
+  defp resolve_module(module) when is_atom(module), do: module
+  defp resolve_module({module, _, _}) when is_atom(module), do: module
+
+  defp resolve_module_file(module, fallback) do
+    # We try to resolve the module to its source file. The only time the source
+    # info may not be available is when it has been stripped by the beam_lib
+    # module, but that shouldn't be the case. More info:
+    # http://erlang.org/doc/reference_manual/modules.html#module_info-0-and-module_info-1-functions
+    module.module_info(:compile)
+    |> Keyword.get(:source, fallback)
+    |> Path.relative_to_cwd()
+  end
+
   defp dependent_modules(modules, mod_deps, result \\ MapSet.new())
 
   defp dependent_modules([], _, result) do

apps/language_server/test/dialyzer_test.exs

@@ -234,6 +234,50 @@ defmodule ElixirLS.LanguageServer.DialyzerTest do
     end)
   end
 
+  test "reports dialyxir_short error in umbrella", %{server: server} do
+    in_fixture(__DIR__, "umbrella_dialyzer", fn ->
+      file_a = SourceFile.path_to_uri(Path.absname("apps/app1/lib/app1.ex"))
+
+      capture_log(fn ->
+        root_uri = SourceFile.path_to_uri(File.cwd!())
+        Server.receive_packet(server, initialize_req(1, root_uri, %{}))
+
+        Server.receive_packet(
+          server,
+          did_change_configuration(%{
+            "elixirLS" => %{"dialyzerEnabled" => true, "dialyzerFormat" => "dialyxir_short"}
+          })
+        )
+
+        message = assert_receive %{"method" => "textDocument/publishDiagnostics"}, 20000
+
+        assert publish_diagnostics_notif(^file_a, [
+                 %{
+                   "message" => error_message1,
+                   "range" => %{
+                     "end" => %{"character" => 0, "line" => 1},
+                     "start" => %{"character" => 0, "line" => 1}
+                   },
+                   "severity" => 2,
+                   "source" => "ElixirLS Dialyzer"
+                 },
+                 %{
+                   "message" => error_message2,
+                   "range" => %{
+                     "end" => %{"character" => 0, "line" => 2},
+                     "start" => %{"character" => 0, "line" => 2}
+                   },
+                   "severity" => 2,
+                   "source" => "ElixirLS Dialyzer"
+                 }
+               ]) = message
+
+        assert error_message1 == "Function check_error/0 has no local return."
+        assert error_message2 == "The pattern can never match the type :error."
+      end)
+    end)
+  end
+
   # Failing and extremely slow (~3s)
   @tag :pending
   test "clears diagnostics when source files are deleted", %{server: server} do

apps/language_server/test/fixtures/umbrella_dialyzer/apps/app1/lib/app1.ex

@@ -0,0 +1,5 @@
+defmodule App1 do
+  def check_error() do
+    :ok = App2.error()
+  end
+end

apps/language_server/test/fixtures/umbrella_dialyzer/apps/app1/mix.exs

@@ -0,0 +1,15 @@
+defmodule App1.Mixfile do
+  use Mix.Project
+
+  def project do
+    [app: :app1, version: "0.1.0", deps: deps()]
+  end
+
+  def application do
+    []
+  end
+
+  defp deps do
+    [{:app2, in_umbrella: true}]
+  end
+end

apps/language_server/test/fixtures/umbrella_dialyzer/apps/app2/lib/app2.ex

@@ -0,0 +1,5 @@
+defmodule App2 do
+  def error do
+    :error
+  end
+end

apps/language_server/test/fixtures/umbrella_dialyzer/apps/app2/mix.exs

@@ -0,0 +1,11 @@
+defmodule App2.Mixfile do
+  use Mix.Project
+
+  def project do
+    [app: :app2, version: "0.1.0"]
+  end
+
+  def application do
+    []
+  end
+end

apps/language_server/test/fixtures/umbrella_dialyzer/mix.exs

@@ -0,0 +1,7 @@
+defmodule UmbrellaDialyzer.Mixfile do
+  use Mix.Project
+
+  def project do
+    [apps_path: "apps"]
+  end
+end