Use line from missing terminator hint (#588)

* Use line from missing terminator hint

* Fix formatter error

* Remove mix files

Co-authored-by: Jason Axelson <jason.axelson@gmail.com>

Author: sabiwara

apps/language_server/.formatter.exs

@@ -1,6 +1,12 @@
+impossible_to_format = ["test/fixtures/token_missing_error/lib/has_error.ex"]
+
 [
-  inputs: [
-    "*.exs",
-    "{lib,test,config}/**/*.{ex,exs}"
-  ]
+  inputs:
+    Enum.flat_map(
+      [
+        "*.exs",
+        "{lib,test,config}/**/*.{ex,exs}"
+      ],
+      &Path.wildcard(&1, match_dot: true)
+    ) -- impossible_to_format
 ]

apps/language_server/lib/language_server/diagnostics.ex

@@ -9,7 +9,7 @@ defmodule ElixirLS.LanguageServer.Diagnostics do
       diagnostic
       |> update_message(type, description, stacktrace)
       |> maybe_update_file(file)
-      |> maybe_update_position(line, stacktrace)
+      |> maybe_update_position(type, line, stacktrace)
     end
   end
 
@@ -67,7 +67,21 @@ defmodule ElixirLS.LanguageServer.Diagnostics do
     end
   end
 
-  defp maybe_update_position(diagnostic, line, stacktrace) do
+  defp maybe_update_position(diagnostic, "TokenMissingError", line, stacktrace) do
+    case extract_line_from_missing_hint(diagnostic.message) do
+      line when is_integer(line) ->
+        %{diagnostic | position: line}
+
+      _ ->
+        do_maybe_update_position(diagnostic, line, stacktrace)
+    end
+  end
+
+  defp maybe_update_position(diagnostic, _type, line, stacktrace) do
+    do_maybe_update_position(diagnostic, line, stacktrace)
+  end
+
+  defp do_maybe_update_position(diagnostic, line, stacktrace) do
     cond do
       line ->
         %{diagnostic | position: line}
@@ -142,6 +156,16 @@ defmodule ElixirLS.LanguageServer.Diagnostics do
     false
   end
 
+  defp extract_line_from_missing_hint(message) do
+    case Regex.run(
+           ~r/HINT: it looks like the .+ on line (\d+) does not have a matching /,
+           message
+         ) do
+      [_, line] -> String.to_integer(line)
+      _ -> nil
+    end
+  end
+
   defp extract_line_from_stacktrace(file, stacktrace) do
     Enum.find_value(stacktrace, fn stack_item ->
       with [_, _, file_relative, line] <-

apps/language_server/test/diagnostics_test.exs

@@ -133,6 +133,26 @@ defmodule ElixirLS.LanguageServer.DiagnosticsTest do
       assert diagnostic.position == 13
     end
 
+    test "if position is nil and error is TokenMissingError, try to retrieve from the hint" do
+      root_path = Path.join(__DIR__, "fixtures/token_missing_error")
+      file = Path.join(root_path, "lib/has_error.ex")
+      position = nil
+
+      message = """
+      ** (TokenMissingError) lib/has_error.ex:16:1: missing terminator: end (for "do" starting at line 1)
+
+          HINT: it looks like the "do" on line 6 does not have a matching "end"
+
+          (elixir 1.12.1) lib/kernel/parallel_compiler.ex:319: anonymous fn/4 in Kernel.ParallelCompiler.spawn_workers/7
+      """
+
+      [diagnostic | _] =
+        [build_diagnostic(message, file, position)]
+        |> Diagnostics.normalize(root_path)
+
+      assert diagnostic.position == 6
+    end
+
     defp build_diagnostic(message, file, position) do
       %Mix.Task.Compiler.Diagnostic{
         compiler_name: "Elixir",

apps/language_server/test/fixtures/build_errors/lib/has_error.ex

@@ -1,4 +1,4 @@
-defmodule ElixirLS.LanguageServer.Fixtures.BuildErrors.HasWarning do
+defmodule ElixirLS.LanguageServer.Fixtures.BuildErrors.HasError do
   def my_fn2 do
     # Should cause build error
     does_not_exist()

apps/language_server/test/fixtures/token_missing_error/lib/has_error.ex

@@ -0,0 +1,15 @@
+defmodule ElixirLS.LanguageServer.Fixtures.TokenMissingError.HasError do
+  def my_fn1 do
+    "no problem here"
+  end
+
+  def my_fn2 do
+    for i <- 1..100 do
+      i + 1
+    # missing terminator: end
+  end
+
+  def my_fn3 do
+    :ok_too
+  end
+end

apps/language_server/test/fixtures/token_missing_error/mix.exs

@@ -0,0 +1,11 @@
+defmodule ElixirLS.LanguageServer.Fixtures.TokenMissingError.Mixfile do
+  use Mix.Project
+
+  def project do
+    [app: :els_token_missing_error_test, version: "0.1.0"]
+  end
+
+  def application do
+    []
+  end
+end

apps/language_server/test/server_test.exs

@@ -1025,6 +1025,29 @@ defmodule ElixirLS.LanguageServer.ServerTest do
     end)
   end
 
+  @tag :fixture
+  test "reports token missing error diagnostics", %{server: server} do
+    in_fixture(__DIR__, "token_missing_error", fn ->
+      error_file = SourceFile.path_to_uri("lib/has_error.ex")
+
+      initialize(server)
+
+      assert_receive notification("textDocument/publishDiagnostics", %{
+                       "uri" => ^error_file,
+                       "diagnostics" => [
+                         %{
+                           "message" => "(TokenMissingError) missing terminator: end" <> _,
+                           "range" => %{"end" => %{"line" => 5}, "start" => %{"line" => 5}},
+                           "severity" => 1
+                         }
+                       ]
+                     }),
+                     1000
+
+      wait_until_compiled(server)
+    end)
+  end
+
   @tag :fixture
   test "reports build diagnostics on external resources", %{server: server} do
     in_fixture(__DIR__, "build_errors_on_external_resource", fn ->