Support go to definition in experimental project

Author: scottming

apps/language_server/lib/language_server/experimental/protocol/requests.ex

@@ -27,6 +27,14 @@ defmodule ElixirLS.LanguageServer.Experimental.Protocol.Requests do
       position: Types.Position
   end
 
+  defmodule GotoDefinition do
+    use Proto
+
+    defrequest "textDocument/definition", :exclusive,
+      text_document: Types.TextDocument.Identifier,
+      position: Types.Position
+  end
+
   defmodule Formatting do
     use Proto
 

apps/language_server/lib/language_server/experimental/protocol/responses.ex

@@ -8,6 +8,12 @@ defmodule ElixirLS.LanguageServer.Experimental.Protocol.Responses do
     defresponse optional(list_of(Types.Location))
   end
 
+  defmodule GotoDefinition do
+    use Proto
+
+    defresponse optional(Types.Location)
+  end
+
   defmodule Formatting do
     use Proto
 

apps/language_server/lib/language_server/experimental/provider/handlers/goto_definition.ex

@@ -0,0 +1,49 @@
+defmodule ElixirLS.LanguageServer.Experimental.Provider.Handlers.GotoDefinition do
+  alias ElixirLS.LanguageServer.Experimental.Protocol.Requests.GotoDefinition
+  alias ElixirLS.LanguageServer.Experimental.Protocol.Responses
+  alias ElixirLS.LanguageServer.Experimental.Protocol.Types.Location
+  alias ElixirLS.LanguageServer.Experimental.Protocol.Types.Range, as: LSRange
+  alias ElixirLS.LanguageServer.Experimental.SourceFile
+  alias ElixirLS.LanguageServer.Experimental.SourceFile.Conversions
+
+  def handle(%GotoDefinition{} = request, _) do
+    source_file = request.source_file
+    pos = request.position
+
+    source_file_string = source_file |> SourceFile.to_string()
+
+    with %ElixirSense.Location{} = location <-
+           ElixirSense.definition(source_file_string, pos.line, pos.character + 1),
+         {:ok, definition} <- build_definition(location, source_file) do
+      {:reply, Responses.GotoDefinition.new(request.id, definition)}
+    else
+      nil ->
+        {:reply, nil}
+
+      {:error, reason} ->
+        {:error, Responses.GotoDefinition.error(request.id, :request_failed, reason)}
+    end
+  end
+
+  defp build_definition(
+         %{line: line, column: column} = elixir_sense_definition,
+         current_source_file
+       ) do
+    position = SourceFile.Position.new(line, column - 1)
+
+    with {:ok, source_file} <- get_source_file(elixir_sense_definition, current_source_file),
+         {:ok, ls_position} <- Conversions.to_lsp(position, source_file) do
+      ls_range = %LSRange{start: ls_position, end: ls_position}
+      {:ok, Location.new(uri: source_file.uri, range: ls_range)}
+    end
+  end
+
+  defp get_source_file(%{file: nil}, current_source_file) do
+    {:ok, current_source_file}
+  end
+
+  defp get_source_file(%{file: path}, _) do
+    uri = Conversions.ensure_uri(path)
+    SourceFile.Store.open_temporary(uri)
+  end
+end

apps/language_server/test/language_server/experimental/provider/handlers/goto_definition_test.exs

@@ -0,0 +1,215 @@
+defmodule ElixirLS.LanguageServer.Experimental.Provider.Handlers.GotoDefinitionTest do
+  use ExUnit.Case, async: true
+
+  alias ElixirLS.LanguageServer.Experimental.Protocol.Requests.GotoDefinition
+  alias ElixirLS.LanguageServer.Experimental.Protocol.Responses
+  alias ElixirLS.LanguageServer.Experimental.Provider.Env
+  alias ElixirLS.LanguageServer.Experimental.Provider.Handlers
+  alias ElixirLS.LanguageServer.Experimental.SourceFile
+  alias ElixirLS.LanguageServer.Experimental.SourceFile.Conversions
+
+  alias ElixirLS.LanguageServer.Fixtures.LspProtocol
+  alias ElixirLS.LanguageServer.Test.FixtureHelpers
+
+  import LspProtocol
+  import ElixirLS.Test.TextLoc, only: [annotate_assert: 4]
+
+  setup do
+    {:ok, _} = start_supervised(SourceFile.Store)
+    :ok
+  end
+
+  def request(file_path, line, char) do
+    uri = Conversions.ensure_uri(file_path)
+
+    params = [
+      text_document: [uri: uri],
+      position: [line: line, character: char]
+    ]
+
+    with {:ok, contents} <- File.read(file_path),
+         :ok <- SourceFile.Store.open(uri, contents, 1),
+         {:ok, _source_file} <- SourceFile.Store.fetch(uri),
+         {:ok, req} <- build(GotoDefinition, params) do
+      GotoDefinition.to_elixir(req)
+    end
+  end
+
+  def handle(request) do
+    Handlers.GotoDefinition.handle(request, Env.new())
+  end
+
+  defp arrange_referenced_file do
+    file_path = FixtureHelpers.get_path("references_referenced.ex")
+    uri = Conversions.ensure_uri(file_path)
+    %{uri: uri}
+  end
+
+  test "find definition remote function call" do
+    b_file = arrange_referenced_file()
+    file_path = FixtureHelpers.get_path("references_remote.ex")
+    {line, char} = {4, 28}
+
+    {:ok, request} = request(file_path, line, char)
+
+    annotate_assert(file_path, line, char, """
+        ReferencesReferenced.referenced_fun()
+                                ^
+    """)
+
+    {:reply, %Responses.GotoDefinition{result: definition}} = handle(request)
+
+    assert definition.uri == b_file.uri
+    assert definition.range.start.line == 1
+    assert definition.range.start.character == 6
+    assert definition.range.end.line == 1
+    assert definition.range.end.character == 6
+  end
+
+  test "find definition remote macro call" do
+    b_file = arrange_referenced_file()
+    file_path = FixtureHelpers.get_path("references_remote.ex")
+    {line, char} = {8, 28}
+
+    {:ok, request} = request(file_path, line, char)
+
+    annotate_assert(file_path, line, char, """
+        ReferencesReferenced.referenced_macro a do
+                                ^
+    """)
+
+    {:reply, %Responses.GotoDefinition{result: definition}} = handle(request)
+
+    assert definition.uri == b_file.uri
+    assert definition.range.start.line == 8
+    assert definition.range.start.character == 11
+    assert definition.range.end.line == 8
+    assert definition.range.end.character == 11
+  end
+
+  test "find definition imported function call" do
+    b_file = arrange_referenced_file()
+    file_path = FixtureHelpers.get_path("references_imported.ex")
+    {line, char} = {4, 5}
+
+    {:ok, request} = request(file_path, line, char)
+
+    annotate_assert(file_path, line, char, """
+        referenced_fun()
+         ^
+    """)
+
+    {:reply, %Responses.GotoDefinition{result: definition}} = handle(request)
+
+    assert definition.uri == b_file.uri
+    assert definition.range.start.line == 1
+    assert definition.range.start.character == 6
+    assert definition.range.end.line == 1
+    assert definition.range.end.character == 6
+  end
+
+  test "find definition imported macro call" do
+    b_file = arrange_referenced_file()
+    file_path = FixtureHelpers.get_path("references_imported.ex")
+    {line, char} = {8, 5}
+
+    {:ok, request} = request(file_path, line, char)
+
+    annotate_assert(file_path, line, char, """
+        referenced_macro a do
+         ^
+    """)
+
+    {:reply, %Responses.GotoDefinition{result: definition}} = handle(request)
+
+    assert definition.uri == b_file.uri
+    assert definition.range.start.line == 8
+    assert definition.range.start.character == 11
+    assert definition.range.end.line == 8
+    assert definition.range.end.character == 11
+  end
+
+  test "find definition local function call" do
+    b_file = arrange_referenced_file()
+    file_path = FixtureHelpers.get_path("references_referenced.ex")
+    {line, char} = {15, 5}
+
+    {:ok, request} = request(file_path, line, char)
+
+    annotate_assert(file_path, line, char, """
+        referenced_fun()
+         ^
+    """)
+
+    {:reply, %Responses.GotoDefinition{result: definition}} = handle(request)
+
+    assert definition.uri == b_file.uri
+    assert definition.range.start.line == 1
+    assert definition.range.start.character == 6
+    assert definition.range.end.line == 1
+    assert definition.range.end.character == 6
+  end
+
+  test "find definition local macro call" do
+    b_file = arrange_referenced_file()
+    file_path = FixtureHelpers.get_path("references_referenced.ex")
+    {line, char} = {19, 5}
+
+    {:ok, request} = request(file_path, line, char)
+
+    annotate_assert(file_path, line, char, """
+        referenced_macro a do
+         ^
+    """)
+
+    {:reply, %Responses.GotoDefinition{result: definition}} = handle(request)
+
+    assert definition.uri == b_file.uri
+    assert definition.range.start.line == 8
+    assert definition.range.start.character == 11
+    assert definition.range.end.line == 8
+    assert definition.range.end.character == 11
+  end
+
+  test "find definition variable" do
+    b_file = arrange_referenced_file()
+    file_path = FixtureHelpers.get_path("references_referenced.ex")
+    {line, char} = {4, 13}
+
+    {:ok, request} = request(file_path, line, char)
+
+    annotate_assert(file_path, line, char, """
+        IO.puts(referenced_variable + 1)
+                 ^
+    """)
+
+    {:reply, %Responses.GotoDefinition{result: definition}} = handle(request)
+
+    assert definition.uri == b_file.uri
+    assert definition.range.start.line == 2
+    assert definition.range.start.character == 4
+    assert definition.range.end.line == 2
+    assert definition.range.end.character == 4
+  end
+
+  test "find definition attribute" do
+    b_file = arrange_referenced_file()
+    file_path = FixtureHelpers.get_path("references_referenced.ex")
+    {line, char} = {27, 5}
+
+    {:ok, request} = request(file_path, line, char)
+
+    annotate_assert(file_path, line, char, """
+        @referenced_attribute
+         ^
+    """)
+
+    {:reply, %Responses.GotoDefinition{result: definition}} = handle(request)
+
+    assert definition.uri == b_file.uri
+    assert definition.range.start.line == 24
+    assert definition.range.start.character == 2
+    assert definition.range.end.line == 24
+    assert definition.range.end.character == 2
+  end
+end