Added UDA for GC config memory values

Author: denizzzka

src/core/gc/config.d

@@ -12,16 +12,19 @@ import core.internal.parseoptions;
 
 __gshared Config config;
 
+/// UDA for field treated as memory value
+struct MemVal {}
+
 struct Config
 {
     bool disable;            // start disabled
     ubyte profile;           // enable profiling with summary when terminating program
     string gc = "conservative"; // select gc implementation conservative|precise|manual
 
-    size_t initReserve;      // initial reserve (bytes)
-    size_t minPoolSize = 1  << 20;  // initial and minimum pool size (bytes)
-    size_t maxPoolSize = 64 << 20;  // maximum pool size (bytes)
-    size_t incPoolSize = 3  << 20;  // pool size increment (bytes)
+    @MemVal size_t initReserve;      // initial reserve (bytes)
+    @MemVal size_t minPoolSize = 1  << 20;  // initial and minimum pool size (bytes)
+    @MemVal size_t maxPoolSize = 64 << 20;  // maximum pool size (bytes)
+    @MemVal size_t incPoolSize = 3  << 20;  // pool size increment (bytes)
     uint parallel = 99;      // number of additional threads for marking (limited by cpuid.threadsPerCPU-1)
     float heapSizeFactor = 2.0; // heap size to used memory ratio
     string cleanup = "collect"; // select gc cleanup method none|collect|finalize

src/core/internal/parseoptions.d

@@ -14,7 +14,8 @@ import core.stdc.stdio;
 import core.stdc.ctype;
 import core.stdc.string;
 import core.vararg;
-import core.internal.traits : externDFunc;
+import core.internal.traits : externDFunc, hasUDA;
+import core.gc.config : MemVal;
 
 
 @nogc nothrow:
@@ -87,36 +88,27 @@ bool parseOptions(CFG)(ref CFG cfg, string opt)
             return optError("Missing argument for", name, errName);
         tail = tail[1 .. $];
 
+        NAMES_SWITCH:
         switch (name)
         {
-            foreach (field; __traits(allMembers, CFG))
+            static foreach (field; __traits(allMembers, CFG))
             {
                 static if (!is(typeof(__traits(getMember, cfg, field)) == function))
                 {
                     case field:
-                        alias fieldT = typeof(__traits(getMember, cfg, field));
-
-                        static if (is(fieldT == size_t))
-                        {
-                             // names of field what can contain B/K/M suffixes
-                            bool isSuffValue = (
-                                name == "initReserve" ||
-                                name == "minPoolSize" ||
-                                name == "maxPoolSize" ||
-                                name == "incPoolSize"
-                            );
-
-                            bool r = parseSuff(name, tail, __traits(getMember, cfg, field), errName, true);
-                        }
+                        bool r;
+
+                        static if (hasUDA!(__traits(getMember, cfg, field), MemVal))
+                            r = parseSuff(name, tail, __traits(getMember, cfg, field), errName, true);
                         else
-                            bool r = parse(name, tail, __traits(getMember, cfg, field), errName);
+                            r = parse(name, tail, __traits(getMember, cfg, field), errName);
 
                         if (!r)
                             return false;
-                        break;
+
+                        break NAMES_SWITCH;
                 }
             }
-            break;
 
             default:
                 return optError("Unknown", name, errName);
@@ -336,8 +328,8 @@ unittest
         ubyte profile;           // enable profiling with summary when terminating program
         string gc = "conservative"; // select gc implementation conservative|manual
 
-        size_t initReserve;      // initial reserve (bytes)
-        size_t minPoolSize = 1 << 20;  // initial and minimum pool size (bytes)
+        @MemVal size_t initReserve;      // initial reserve (bytes)
+        @MemVal size_t minPoolSize = 1 << 20;  // initial and minimum pool size (bytes)
         float heapSizeFactor = 2.0; // heap size to used memory ratio
 
         @nogc nothrow:

src/core/internal/traits.d

@@ -743,3 +743,33 @@ unittest
     static assert(!isTrue!(T, "g"));
     static assert(!isTrue!(T, "h"));
 }
+
+template hasUDA(alias symbol, alias attribute)
+{
+    alias attrs = __traits(getAttributes, symbol);
+
+    static foreach (a; attrs)
+    {
+        static if (is(a == attribute))
+        {
+            enum hasUDA = true;
+        }
+    }
+
+    static if (!__traits(compiles, (hasUDA == true)))
+        enum hasUDA = false;
+}
+
+unittest
+{
+    struct SomeUDA{}
+
+    struct Test
+    {
+        int woUDA;
+        @SomeUDA int withUDA;
+    }
+
+    static assert(hasUDA!(Test.withUDA, SomeUDA));
+    static assert(!hasUDA!(Test.woUDA, SomeUDA));
+}