Works with ESP-32-DevKitM-1

[sugarpines]

Thanks for the library.

I was able to get it running with an ESP32-C3-DevKitM-1 using the following code:

/*
 * Publishes device "Bogus", sensor "bogus1", "bogus2" to Home Assistant 2022.3.5 from ESP32-C3-DevKitM-1
 * https://docs.espressif.com/projects/esp-idf/en/latest/esp32c3/hw-reference/esp32c3/user-guide-devkitm-1.html
 */
#include <WiFi.h>
#include <ArduinoHA.h>
#include "secrets.h"  // contains defines for WIFI & MQTT

#define DEVICE_ID "Bogus"
#define CHECK_INTERVAL 10000

WiFiClient espClient;
HADevice device(DEVICE_ID);
HAMqtt mqtt(espClient, device);
HASensor sensor1("bogus1");
HASensor sensor2("bogus2");

unsigned long currentMillis;
unsigned long lastCheckMillis = 0;


void setupWifi() {
  WiFi.mode(WIFI_STA);
  WiFi.begin(WIFI_SSID, WIFI_PW);
  Serial.print("Connecting to WiFi ");
  while (WiFi.status() != WL_CONNECTED) {
    Serial.print('.');
    delay(1000);
  }
  Serial.print("IP: ");
  Serial.println(WiFi.localIP());
  Serial.print("RRSI: ");
  Serial.println(WiFi.RSSI());
}


void checkWifi() {
  if (WiFi.status() != WL_CONNECTED) {
    Serial.println("WiFi no longer connected.");
    WiFi.disconnect();
    setupWifi();
  }
}


void setupHAMqtt () {
  device.setName(DEVICE_ID);
  //  device.setManufacturer("Acme");
  //  device.setModel("Bogus 100");
  //  device.setSoftwareVersion("1.0.0");
  //  device.enableSharedAvailability();
  //  device.enableLastWill();

  sensor1.setName("Bogus 1");
  sensor1.setIcon("mdi:test-tube");
  //  sensor1.setDeviceClass("temperature");
  //  sensor1.setUnitOfMeasurement("°C");
  
  sensor2.setName("Bogus 2");
  sensor2.setIcon("mdi:test-tube");
  //  sensor1.setDeviceClass("temperature");
  //  sensor1.setUnitOfMeasurement("°C");

  mqtt.begin(MQTT_BROKER, MQTT_PORT, MQTT_UNAME, MQTT_PW);
}


void setup() {
  Serial.begin(115200);
  setupWifi();
  setupHAMqtt();

  Serial.println("Setup Complete.");
}

void loop() {
  currentMillis = millis();
  if (currentMillis - lastCheckMillis >= CHECK_INTERVAL) {
    checkWifi();
    sensor1.setValue(currentMillis);
    sensor2.setValue(lastCheckMillis);
    Serial.print(currentMillis);
    Serial.print(" - ");
    Serial.println(lastCheckMillis);
    lastCheckMillis = currentMillis;
  }
  delay(567);  // simulate sensor activity
  mqtt.loop();
}