Merge pull request #2 from danschultzer/vkontakte

Add vkontakte support

Author: danschultzer

README.md

@@ -2,14 +2,14 @@
 
 [![Build Status](https://travis-ci.org/danschultzer/coherence_assent.svg?branch=master)](https://travis-ci.org/danschultzer/coherence_assent)
 
-Use Google, Github, Twitter, Facebook, Basecamp, or add your own strategy for authorization to your Coherence Phoenix app.
+Use Google, Github, Twitter, Facebook, Basecamp, VK or add your own strategy for authorization to your Coherence Phoenix app.
 
 ## Features
 
 * Collects required login field if missing verified email from provider
 * Multiple providers can be used for accounts
   * When removing auth: Validates user has password or another provider authentication
-* Github, Google, Twitter, Facebook and Basecamp strategies included
+* Github, Google, Twitter, Facebook, Basecamp and VK strategies included
 * Updates Coherence templates automatically
 * You can add your custom strategy with ease
 

lib/coherence_assent/strategies/vk.ex

@@ -0,0 +1,78 @@
+defmodule CoherenceAssent.Strategy.VK do
+  @moduledoc """
+  VK.com OAuth 2.0 strategy.
+  """
+
+  alias CoherenceAssent.Strategy.Helpers
+  alias CoherenceAssent.Strategies.OAuth2, as: OAuth2Helper
+
+  def authorize_url(conn, config) do
+    OAuth2Helper.authorize_url(conn, set_config(config))
+  end
+
+  def callback(conn, config, params) do
+    config = set_config(config)
+    client = OAuth2.Client.new(config)
+
+    conn
+    |> OAuth2Helper.check_conn(client, params)
+    |> OAuth2Helper.get_access_token(config, params)
+    |> get_user(config)
+    |> get_response()
+    |> normalize()
+  end
+
+  defp set_config(config) do
+    profile_fields = ["uid", "first_name", "last_name",
+                      "photo_200", "screen_name", "verified"]
+
+    user_url_params = %{
+      "fields" => Enum.join(profile_fields, ","),
+      "v" => "5.69",
+      "https" => "1"
+    } |> Map.merge(config[:user_url_params] || %{})
+
+    [
+      site: "https://api.vk.com",
+      authorize_url: "https://oauth.vk.com/authorize",
+      token_url: "https://oauth.vk.com/access_token",
+      user_url: "/method/users.get",
+      authorization_params: [scope: "email"],
+      user_url_params: user_url_params
+    ]
+    |> Keyword.merge(config)
+    |> Keyword.put(:strategy, OAuth2.Strategy.AuthCode)
+  end
+
+  defp get_user({:ok, %{conn: conn, client: client}}, config) do
+    user_url_params = config[:user_url_params] |> Map.put("access_token", client.token.access_token)
+    user_url = config[:user_url] <> "?" <> URI.encode_query(user_url_params)
+
+    OAuth2Helper.get_user({:ok, %{conn: conn, client: client}}, user_url)
+  end
+  defp get_user({:error, _} = error, _config), do: error
+
+  defp get_response({:ok, %{client: client, user: %{"response" => [user]}} = resp}) do
+    email = Map.get(client.token.other_params, "email")
+    user = Map.put_new(user, "email", email)
+
+    {:ok, Map.put(resp, :user, user)}
+  end
+  defp get_response({:ok, resp}), do: {:error, %{error: "Retrieved invalid response: #{inspect resp.user}"}}
+  defp get_response(resp), do: resp
+
+  defp normalize({:ok, %{conn: conn, client: client, user: user}}) do
+    user = %{"uid"         => user["id"] |> to_string,
+             "nickname"    => user["screen_name"],
+             "first_name"  => user["first_name"],
+             "last_name"   => user["last_name"],
+             "name"        => [user["first_name"], user["last_name"]] |> Enum.join(" "),
+             "email"       => user["email"],
+             "image"       => user["photo_200"],
+             "verified"    => user["verified"] > 0}
+           |> Helpers.prune
+
+    {:ok, %{conn: conn, client: client, user: user}}
+  end
+  defp normalize({:error, _} = error), do: error
+end

test/coherence_assent/strategies/vk_test.exs

@@ -0,0 +1,66 @@
+defmodule CoherenceAssent.VKTest do
+  use CoherenceAssent.Test.ConnCase
+
+  import OAuth2.TestHelpers
+  alias CoherenceAssent.Strategy.VK
+
+  setup %{conn: conn} do
+    conn = session_conn(conn)
+
+    bypass = Bypass.open
+    config = [site: bypass_server(bypass),
+              authorize_url: "/authorize",
+              token_url: "/access_token"]
+    params = %{"code" => "test", "redirect_uri" => "test"}
+
+    {:ok, conn: conn, config: config, params: params, bypass: bypass}
+  end
+
+  test "authorize_url/2", %{conn: conn, config: config} do
+    assert {:ok, %{conn: _conn, url: url}} = VK.authorize_url(conn, config)
+    assert url =~ "/authorize"
+  end
+
+  describe "callback/2" do
+    test "normalizes data", %{conn: conn, config: config, params: params, bypass: bypass} do
+      users = [%{"id" => 210700286,
+                 "first_name" => "Lindsay",
+                 "last_name" => "Stirling",
+                 "screen_name" => "lindseystirling",
+                 "verified" => 1}]
+
+      Bypass.expect_once bypass, "POST", "/access_token", fn conn ->
+        send_resp(conn, 200, Poison.encode!(%{"access_token" => "access_token", "email" => "lindsay.stirling@example.com"}))
+      end
+
+      Bypass.expect_once bypass, "GET", "/method/users.get", fn conn ->
+        query = Plug.Conn.fetch_query_params(conn)
+
+        assert query.params["fields"] == "uid,first_name,last_name,photo_200,screen_name,verified"
+        assert query.params["v"] == "5.69"
+        assert query.params["access_token"] == "access_token"
+
+        users = [%{"id" => 210700286,
+                   "first_name" => "Lindsay",
+                   "last_name" => "Stirling",
+                   "screen_name" => "lindseystirling",
+                   "photo_200" => "https://pp.userapi.com/c840637/v840637830/2d20e/wMuAZn-RFak.jpg",
+                   "verified" => 1}]
+
+        Plug.Conn.resp(conn, 200, Poison.encode!(%{"response" => users}))
+      end
+
+      expected = %{"email" => "lindsay.stirling@example.com",
+                   "first_name" => "Lindsay",
+                   "last_name" => "Stirling",
+                   "name" => "Lindsay Stirling",
+                   "nickname" => "lindseystirling",
+                   "uid" => "210700286",
+                   "image" => "https://pp.userapi.com/c840637/v840637830/2d20e/wMuAZn-RFak.jpg",
+                   "verified" => true}
+
+      {:ok, %{user: user}} = VK.callback(conn, config, params)
+      assert expected == user
+    end
+  end
+end