Specifying Population Criteria

To encourage consistency among measures, the following guidelines for specifying population criteria within a measure are proposed.

Criteria Names

The name of an expression specifying a population criteria within a measure should always be the name of the population type:

• "Initial Population"
• "Denominator"
• "Denominator Exclusion"
• "Denominator Exception"
• "Numerator"
• "Numerator Exclusion"
• "Measure Population"
• "Measure Population Exclusion"
• "Measure Observation" (Note that this is the name of a function, see the Continuous Variable section for more)

Measures with Multiple Populations

When a measure has multiple populations, the criteria names will follow the convention above, adding the number of the population group to each criteria, e.g. "Initial Population 1", "Denominator 1", etc.

Population Criteria Result Types

For each type of measure, the set of applicable criteria are defined by the Health Quality Measure Format (HQMF) specification. In addition, the formula for calculating the measure score is implied by the type of the measure. The following sections describe the expected result type for population criteria for each type of measure, as well as explicitly defining the measure score calculation formula.

In addition to the measure type, measures generally fall into two categories, patient-based, and others, such as episode-of-care-based. In general, patient-based measures count the number of patients in each population, while episode-of-care-based measures count the number of encounters in each population. Although the calculation formulas are conceptually the same for both categories, for ease of expression, population criteria for patient-based measures return true or false, while non-patient-based measures return the item to be counted such as an encounter or procedure.

Proportion Measures

The following population criteria types apply to proportion measures:

• Initial Population
• Denominator
• Denominator Exclusion
• Denominator Exception
• Numerator
• Numerator Exclusion

The following sample measure defines the measure score for a patient-based proportion measure:

library PatientBasedProportionMeasure version '1'

using QDM

parameter "Measurement Period" Interval<DateTime>

context Patient

define "Initial Population": AgeAt(start of "Measurement Period") >= 18
define "Denominator": 
  exists (
    ["Encounter, Performed": "Inpatient"] Encounter 
      where Encounter.startDateTime during "Measurement Period"
  )

define "Denominator Exclusion": false
define "Denominator Exception": false
define "Numerator":
  exists (
    ["Procedure, Performed": "Depression Assessment"] Procedure
      where Procedure.startDateTime during "Measurement Period"
  )

define "Numerator Exclusion": false

define "Denominator Membership":
  "Initial Population"
    and "Denominator"
    and not "Denominator Exclusion"
    and not ("Denominator Exception" and not "Numerator")

define "Numerator Membership":
  "Initial Population"
    and "Denominator"
    and not "Denominator Exclusion"
    and "Numerator"
    and not "Numerator Exclusion"

context Population

define "Measure Score":
  Count("Numerator Membership" IsMember where IsMember is true)
    / Count("Denominator Membership" IsMember where IsMember is true)