Grammar railroad diagram

[mingodad]

If you use an EBNF understood by https://github.com/GuntherRademacher/rr then you can generate a nice navigable railroad diagram (see bellow with instructions at the top).

//
// EBNF to be viewd at
//    (IPV6) https://www.bottlecaps.de/rr/ui
//    (IPV4) https://rr.red-dove.com/ui
//
// Copy and paste this at one of the urls shown above in the 'Edit Grammar' tab
// then click the 'View Diagram' tab.
//

recipe ::= ( metadata | step | note )+

/* not sure how to show that, but two below should start from a new line */
metadata ::= ">>" text_item_no_colon+ ":" ( text_item )+ new_line_character
step     ::= ( text_item | ingredient | cookware | timer )+ new_line_character blank_line 

note_marker ::= ">" 
note ::= ( note_marker ( text_item )* blank_line )+ blank_line 

ingredient           ::= one_word_ingredient | multiword_ingredient 
one_word_ingredient  ::= "@" one_word_component 
multiword_ingredient ::= "@" multiword_component 

cookware             ::= one_word_cookware | multiword_cookware 
one_word_cookware    ::= "#" one_word_component 
multiword_cookware   ::= "#" multiword_component 

timer                ::= no_name_timer | one_word_timer | multiword_timer 
no_name_timer        ::= "~" no_name_component 
one_word_timer       ::= "~" one_word_component 
multiword_timer      ::= "~" multiword_component 

no_name_component    ::=                             "{" amount? "}" 
one_word_component   ::= word                     ( "{" amount? "}" )?
multiword_component  ::= word text_item_no_lcurly+ "{" amount? "}" 

amount   ::= quantity | ( quantity "%" units ) 
quantity ::= ( text_item_no_pct_rcurly )+
units    ::= text_item_no_rcurly+

word      ::=  [A-Za-z][A-Za-z0-9]* //( text_item - white_space - punctuation_character )+
text_item ::= [^#x10] //? any character except new_line_character ? 
text_item_no_colon ::= [^:#x0A]
text_item_no_lcurly ::= [^{#x0A]
text_item_no_rcurly ::= [^}#x0A]
text_item_no_pct_rcurly ::= [^%}#x0A]

/* https://en.wikipedia.org/wiki/Template:General_Category_(Unicode) */
new_line_character    ::=  [#x0a#x0D] //? newline characters (U+000A ~ U+000D, U+0085, U+2028, and U+2029) ? ;
white_space           ::= [ #x09] //? Unicode General Category Zs and CHARACTER TABULATION (U+0009) ? ;
//punctuation_character ::= ? Unicode General Category P* ? ;
blank_line ::= ( white_space )* new_line_character 

comments       ::= "--" text_item* new_line_character
block comments ::=  "[-" [^-]+ "-]" //"[-" ? any character except "-" followed by "]" ? "-]"

[dubadub]

That's pretty cool, I wanted to paste here the result, but for some reason it doesn't render embedded images properly here.

[mingodad]

I usually download the xhtml and use it through github pages/io like in https://github.com/mingodad/cpp-grammars example: https://mingodad.github.io/cpp-grammars/c++14.ebnf.xhtml