Automated helper scripts

[Bonfra04]

Proxmox helper scripts are an awesome tool to speed up the manual setup of services. Sadly if you want to put together a more automated approach to your infrastructure you'd have to manually write a full script that does all the heavy lifting, and cannot rely on the awesome work done by these scripts.
The main obstacle is whiptail, the fancy tty/ui thing that lets you select things.
I've put together a simple tcl script to use with the package expect (installable via apt) to run on Proxmox and easily fill those forms.
The exit code of this script (that'll definitely smash the stdout stream) is going to be the container id.
It's just a small POC and should be expanded upon to match everyone's need, but its fine for what i need :)

#!/usr/bin/expect
set timeout 5

# Setup arguments
set arguments {
    --script-name ""
    --root-password ""
    --container-id ""
    --hostname ""
    --disk-size ""
    --cpu-cores ""
    --ram ""
    --bridge ""
    --ipv4 ""
    --vlan ""
}
set mandatory_arguments { --script-name --root-password }
set usage "Usage: $argv0 --script-name=<script_name> --root-password=<password> \[--container-id=<id>] \[--hostname=<hostname>] \[--disk-size=<size>] \[--cpu-cores=<cores>] \[--ram=<ram>] \[--bridge=<bridge>] \[--ipv4=<ipv4>] \[--vlan=<vlan>]"

set argsDict $arguments
set invalid_arg 0

# Validate arguments
for {set i 0} {$i < [llength $argv]} {incr i} {
    set arg [lindex $argv $i]
    
    if {[regexp {^(--[^=]+)=(.*)$} $arg -> key value]} {
        # Handle --key=value format
        if {[dict exists $arguments $key]} {
            dict set argsDict $key $value
        } else {
            puts "Error: Unknown argument \"$key\""
            set invalid_arg 1
        }
    } elseif {[dict exists $arguments $arg]} {
        # Handle --key value format
        if {$i+1 < [llength $argv]} {
            set value [lindex $argv [incr i]]
            dict set argsDict $arg $value
        } else {
            puts "Error: Missing value for \"$arg\""
            set invalid_arg 1
        }
    } else {
        puts "Error: Unknown argument \"$arg\""
        set invalid_arg 1
    }
}

# Check for mandatory parameters
foreach key $mandatory_arguments {
    if {[dict get $argsDict $key] == ""} {
        puts "Error: Mandatory parameter \"$key\" is missing!"
        set invalid_arg 1
    }
}

# Fail if any invalid argument was found
if {$invalid_arg} {
    puts $usage
    exit 1
}


# Extract values
set script_name [dict get $argsDict --script-name]
set root_password [dict get $argsDict --root-password]
set container_id [dict get $argsDict --container-id]
set hostname [dict get $argsDict --hostname]
set disk_size [dict get $argsDict --disk-size]
set cpu_cores [dict get $argsDict --cpu-cores]
set ram [dict get $argsDict --ram]
set bridge [dict get $argsDict --bridge]
set ipv4 [dict get $argsDict --ipv4]
set vlan [dict get $argsDict --vlan]

# Start the Bash script
spawn bash -c "wget -qLO - https://github.com/community-scripts/ProxmoxVE/raw/main/ct/$script_name.sh | bash"

# ┌───────────────────────┤ .* LXC ├───────────────────────┐
# │                                                        │
# │ This will create a New .* LXC. Proceed?                │
# │                                                        │
# │                                                        │
# │                                                        │
# │                                                        │
# │              <Yes>                 <No>                │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ <Yes> ]
expect {
    -re "This will create a New .* LXC. Proceed?" {
        send "\r"
    }
}
# Enter

# ┌───────────────────────────┤ SSH DETECTED ├───────────────────────────┐
# │                                                                      │
# │ It's advisable to utilize the Proxmox shell rather than SSH, as      │
# │ there may be potential complications with variable retrieval.        │
# │ Proceed using SSH?                                                   │
# │                                                                      │
# │                                                                      │
# │                   <Yes>                      <No>                    │
# │                                                                      │
# └──────────────────────────────────────────────────────────────────────┘
# Cursor starts on [ <No> ]
expect {
    "Proceed using SSH?" {
        send "\x1B\[D\r"


# ┌────────────────────────┤ Proceed using SSH ├─────────────────────────┐
# │                                                                      │
# │ You've chosen to proceed using SSH. If any issues arise, please run  │
# │ the script in the Proxmox shell before creating a repository issue.  │
# │                                                                      │
# │                                                                      │
# │                                                                      │
# │                                <Ok>                                  │
# │                                                                      │
# └──────────────────────────────────────────────────────────────────────┘
# Cursor starts on [ <Ok> ]
        expect "before creating a repository issue."
        send "\r"

        
    }
    timeout {
    }
}


# ┌────────────────────┤ DIAGNOSTICS ├─────────────────────┐
# │                                                        │
# │ Send Diagnostics of LXC Installation?                  │
# │                                                        │
# │ (This only transmits data without user data, just RAM, │
# │ CPU, LXC name, ...)                                    │
# │                                                        │
# │              <Yes>                 <No>                │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ <Yes> ]
expect {
    "Send Diagnostics of LXC Installation?" {
        send "\x1B\[C\r"
    }
    timeout {
    }
}


# ┌──────────────────┤ SETTINGS ├──────────────────┐
# │ Choose an option:                              │
# │                                                │
# │       1 Default Settings                       │
# │       2 Default Settings (with verbose)        │
# │       3 Advanced Settings                      │
# │       4 Exit                                   │
# │                                                │
# │                                                │
# │                     <Ok>                       │
# │                                                │
# └────────────────────────────────────────────────┘
# Cursor starts on [ 1 Default Settings ]
expect "Choose an option:"
send "\x1B\[B\x1B\[B\r"
# Down Arrow, Down Arrow, Enter


# ┌───────────┤ Here is an instructional tip: ├────────────┐
# │                                                        │
# │ To make a selection, use the Spacebar.                 │
# │                                                        │
# │                                                        │
# │                         <Ok>                           │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ <Ok> ]
expect "To make a selection, use the Spacebar."
send "\r"


# ┌────────────┤ Default distribution for .*  ├────────────┐
# │                                                        │
# │ Default is: debian 12                                  │
# │                                                        │
# │ If the default Linux distribution is not adhered to,   │
# │ script support will be discontinued.                   │
# │                                                        │
# │                         <Ok>                           │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ <Ok> ]
expect "If the default Linux distribution is not adhered to, script support will be discontinued."
send "\r"


# ┌────────────────────┤ DISTRIBUTION ├────────────────────┐
# │ Choose Distribution                                    │
# │                                                        │
# │  (*) debian                                            │
# │  ( ) ubuntu                                            │
# │                                                        │
# │                                                        │
# │             <Ok>                 <Cancel>              │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ (*) debian ]
expect "Choose Distribution"
send "\r"


# ┌───────────────────┤ DEBIAN VERSION ├───────────────────┐
# │ Choose Version                                         │
# │                                                        │
# │  ( ) 11  Bullseye                                      │
# │  (*) 12  Bookworm                                      │
# │                                                        │
# │                                                        │
# │             <Ok>                 <Cancel>              │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ ( ) 11  Bullseye ]
expect "Choose Version"
send "\r"


# ┌───────────────────┤ CONTAINER TYPE ├───────────────────┐
# │ Choose Type                                            │
# │                                                        │
# │  (*) 1  Unprivileged                                   │
# │  ( ) 0  Privileged                                     │
# │                                                        │
# │                                                        │
# │             <Ok>                 <Cancel>              │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ (*) 1  Unprivileged ]
expect "Choose Type"
send "\r"

# ┌─────┤ PASSWORD (leave blank for automatic login) ├─────┐
# │                                                        │
# │ Set Root Password (needed for root ssh access)         │
# │                                                        │
# │ ______________________________________________________ │
# │                                                        │
# │             <Ok>                 <Cancel>              │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ Text Field ]
expect "Set Root Password (needed for root ssh access)"
send "$root_password\r"

# ┌───────────────┤ PASSWORD VERIFICATION ├────────────────┐
# │                                                        │
# │ Verify Root Password                                   │
# │                                                        │
# │ ______________________________________________________ │
# │                                                        │
# │             <Ok>                 <Cancel>              │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ Text Field ]
expect "Verify Root Password"
send "$root_password\r"


# ┌────────────────────┤ CONTAINER ID ├────────────────────┐
# │ Set Container ID                                       │
# │                                                        │
# │ ______________________________________________________ │
# │                                                        │
# │             <Ok>                 <Cancel>              │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ Text Field ]
expect "Set Container ID"
if {$container_id == ""} {
    send "\r"
} else {
    for {set i 0} {$i < 50} {incr i} {
        send "\x08"
    }
    send "$container_id\r"
}
send "\r"

expect {
    -re "Container ID:" {
    }
}

expect {
    -re "(\[0-9]{3,})" {
        set container_id $expect_out(1,string)
    }
}


# ┌──────────────────────┤ HOSTNAME ├──────────────────────┐
# │ Set Hostname                                           │
# │                                                        │
# │ ______________________________________________________ │
# │                                                        │
# │             <Ok>                 <Cancel>              │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ Text Field ]
expect "Set Hostname"
if {$hostname == ""} {
    send "\r"
} else {
    for {set i 0} {$i < 50} {incr i} {
        send "\x08"
    }
    send "$hostname\r"
}

# ┌─────────────────────┤ DISK SIZE ├──────────────────────┐
# │ Set Disk Size in GB                                    │
# │                                                        │
# │ ______________________________________________________ │
# │                                                        │
# │             <Ok>                 <Cancel>              │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ Text Field ]
expect "Set Disk Size in GB"
if {$disk_size == ""} {
    send "\r"
} else {
    for {set i 0} {$i < 50} {incr i} {
        send "\x08"
    }
    send "$disk_size\r"
}


# ┌─────────────────────┤ CORE COUNT ├─────────────────────┐
# │ Allocate CPU Cores                                     │
# │                                                        │
# │ ______________________________________________________ │
# │                                                        │
# │             <Ok>                 <Cancel>              │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ Text Field ]
expect "Allocate CPU Cores"
if {$cpu_cores == ""} {
    send "\r"
} else {
    for {set i 0} {$i < 50} {incr i} {
        send "\x08"
    }
    send "$cpu_cores\r"
}


# ┌────────────────────────┤ RAM ├─────────────────────────┐
# │ Allocate RAM in MiB                                    │
# │                                                        │
# │ ______________________________________________________ │
# │                                                        │
# │             <Ok>                 <Cancel>              │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ Text Field ]
expect "Allocate RAM in MiB"
if {$ram == ""} {
    send "\r"
} else {
    for {set i 0} {$i < 50} {incr i} {
        send "\x08"
    }
    send "$ram\r"
}


# ┌───────────────────────┤ BRIDGE ├───────────────────────┐
# │ Set a Bridge                                           │
# │                                                        │
# │ ______________________________________________________ │
# │                                                        │
# │             <Ok>                 <Cancel>              │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ Text Field ]
expect "Set a Bridge"
if {$bridge == ""} {
    send "\r"
} else {
    for {set i 0} {$i < 50} {incr i} {
        send "\x08"
    }
    send "$bridge\r"
}


# ┌─────────────────────┤ IP ADDRESS ├─────────────────────┐
# │ Set a Static IPv4 CIDR Address (/24)                   │
# │                                                        │
# │ ______________________________________________________ │
# │                                                        │
# │             <Ok>                 <Cancel>              │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ Text Field ]
expect "Set a Static IPv4 CIDR Address (/24)"
if {$ipv4 == ""} {
    send "\r"
} else {
    for {set i 0} {$i < 50} {incr i} {
        send "\x08"
    }
    send "$ipv4\r"
}


# ┌───────────────────┤ APT-Cacher IP ├────────────────────┐
# │ Set APT-Cacher IP (leave blank for none)               │
# │                                                        │
# │ ______________________________________________________ │
# │                                                        │
# │             <Ok>                 <Cancel>              │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ Text Field ]
expect "Set APT-Cacher IP (leave blank for none)"
send "\r"


# ┌────────────────────────┤ IPv6 ├────────────────────────┐
# │                                                        │
# │ Disable IPv6?                                          │
# │                                                        │
# │                                                        │
# │                                                        │
# │                                                        │
# │              <Yes>                 <No>                │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ <No> ]
expect "Disable IPv6?"
send "\x1B\[D\r"


# ┌──────────────────────┤ MTU SIZE ├──────────────────────┐
# │ Set Interface MTU Size (leave blank for default        │
# │ [1500])                                                │
# │                                                        │
# │ ______________________________________________________ │
# │             <Ok>                 <Cancel>              │
# │                                                        │
# └────────────────────────────────────────────────────────┘ù
# Cursor starts on [ Text Field ]
expect "Set Interface MTU Size (leave blank for default \[1500])"
send "\r"


# ┌─────────────────┤ DNS Search Domain ├──────────────────┐
# │ Set a DNS Search Domain (leave blank for HOST)         │
# │                                                        │
# │ ______________________________________________________ │
# │                                                        │
# │             <Ok>                 <Cancel>              │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ Text Field ]
expect "Set a DNS Search Domain (leave blank for HOST)"
send "\r"


# ┌───────────────────┤ DNS SERVER IP ├────────────────────┐
# │ Set a DNS Server IP (leave blank for HOST)             │
# │                                                        │
# │ ______________________________________________________ │
# │                                                        │
# │             <Ok>                 <Cancel>              │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ Text Field ]
expect "Set a DNS Server IP (leave blank for HOST)"
send "\r"


# ┌────────────────────┤ MAC ADDRESS ├─────────────────────┐
# │ Set a MAC Address(leave blank for generated MAC)       │
# │                                                        │
# │ ______________________________________________________ │
# │                                                        │
# │             <Ok>                 <Cancel>              │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ Text Field ]
expect "Set a MAC Address(leave blank for generated MAC)"
send "\r"

# ┌────────────────────────┤ VLAN ├────────────────────────┐
# │ Set a Vlan(leave blank for no VLAN)                    │
# │                                                        │
# │ ______________________________________________________ │
# │                                                        │
# │             <Ok>                 <Cancel>              │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ Text Field ]
expect "Set a Vlan(leave blank for no VLAN)"
if {$vlan == ""} {
    send "\r"
} else {
    for {set i 0} {$i < 50} {incr i} {
        send "\x08"
    }
    send "$vlan\r"
}


# ┌───────────────────┤ Advanced Tags ├────────────────────┐
# │ Set Custom Tags?[If you remove all, there will be no   │
# │ tags!]                                                 │
# │                                                        │
# │ community-script;dashboard____________________________ │
# │             <Ok>                 <Cancel>              │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ Text Field ]
expect "Set Custom Tags?\[If you remove all, there will be no tags!]"
send "\r"


# ┌─────────────────────┤ SSH ACCESS ├─────────────────────┐
# │                                                        │
# │ Enable Root SSH Access?                                │
# │                                                        │
# │                                                        │
# │                                                        │
# │                                                        │
# │              <Yes>                 <No>                │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ <No> ]
expect "Enable Root SSH Access?"
send "\x1B\[D\r"


# ┌──────────────────────┤ SSH Key ├───────────────────────┐
# │ SSH Authorized key for root (leave empty for none)     │
# │                                                        │
# │ ______________________________________________________ │
# │                                                        │
# │             <Ok>                 <Cancel>              │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ Text Field ]
expect "SSH Authorized key for root (leave empty for none)"
send "\r"


# ┌────────────────────┤ VERBOSE MODE ├────────────────────┐
# │                                                        │
# │ Enable Verbose Mode?                                   │
# │                                                        │
# │                                                        │
# │                                                        │
# │                                                        │
# │              <Yes>                 <No>                │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ <No> ]
expect "Enable Verbose Mode?"
send "\r"


# ┌─────────────┤ ADVANCED SETTINGS COMPLETE ├─────────────┐
# │                                                        │
# │ Ready to create .* LXC?                                │
# │                                                        │
# │                                                        │
# │                                                        │
# │                                                        │
# │              <Yes>                 <No>                │
# │                                                        │
# └────────────────────────────────────────────────────────┘
# Cursor starts on [ <Yes> ]
expect {
    -re "Ready to create .* LXC?" {
        send "\r"
    }
}
send "\r"

set timeout -1
expect {
    -re ".* setup has been successfully initialized!" {
        expect eof
        exit $container_id
    }
    timeout {
        puts "Error: Setup did not complete within the expected time."
        exit 1
    }
}

[michelroegl-brunner]

This breaks with PR #1801, the whiptails have changed a bit,, just FYI

[Bonfra04]

Ah yes, I've seen that popup once in my testings, but it never showed again so I just ignored it... ups :)
yea probably I'm going to update the above code as soon as it pops to me again
Thanks for the advice

[michelroegl-brunner]

It only pops once when the file /usr/local/community-scripts/diagnostics is not created. mybe this info helps you :)

[Bonfra04]

Yes, it was precious to know the existence of that file to debug the automation more easily. I've just updated the template above to include that section, it may be in need of some parameters to fully customize it but at least now it is aware of that.
Thanks again

[fjbravo]

Looks like they are working on something to address this -> #1637?
It provides the option of providing the script with a config file containing the desired answers.