Acceptance test: override immutable bit with rename

Added acceptance test to test that the rename attribute of the files
promise can override the immutable bit of the destination file.

Ticket: ENT-10961, CFE-1840
Signed-off-by: Lars Erik Wik <lars.erik.wik@northern.tech>

Author: larsewi

tests/acceptance/10_files/14_immutable/immutable_12.cf

@@ -0,0 +1,89 @@
+##############################################################################
+#
+# Test that agent can override the immutable bit when using rename attribute
+#
+##############################################################################
+
+body common control
+{
+  inputs => { "../../default.cf.sub" };
+  bundlesequence  => { default("$(this.promise_filename)") };
+  version => "1.0";
+}
+
+body fsattrs set_immutable
+{
+  immutable => "true";
+}
+
+bundle agent init
+{
+  files:
+    "/tmp/immutable_12.txt"
+      create => "true";
+
+  commands:
+    "chattr +i /tmp/immutable_12.txt"
+      contain => in_shell;
+}
+
+body rename nuke
+{
+  disable => "true";
+  disable_suffix => ".nuked";
+}
+
+bundle agent test
+{
+  meta:
+    "description" -> { "CFE-1840", "ENT-10961" }
+      string => "Test that agent can override the immutable bit on a file while using the rename attribute";
+
+    "test_soft_fail"
+      string => "hpux|aix|windows",
+      meta => { "CFE-1840", "ENT-10961" };
+
+  files:
+    "/tmp/immutable_12.txt"
+      fsattrs => set_immutable,
+      rename => nuke;
+}
+
+bundle agent check
+{
+  classes:
+    "original_exists"
+      expression => fileexists("/tmp/immutable_12.txt");
+    "nuked_exists"
+      expression => fileexists("/tmp/immutable_12.txt.nuked");
+    "ok"
+      expression => "!original_exists&nuked_exists";
+
+  reports:
+    ok::
+      "$(this.promise_filename) Pass";
+    !ok::
+      "$(this.promise_filename) FAIL";
+    any::
+      "Expected file '/tmp/immutable_12.txt' to not exists $(with)"
+        with => ifelse("!original_exists", "and it does not", "but it does");
+      "Expected file '/tmp/immutable_12.txt.nuked' to exists $(with)"
+        with => ifelse("nuked_exists", "and it does", "but it does not");
+}
+
+bundle agent destroy
+{
+  commands:
+    "chattr -i /tmp/immutable_12.txt"
+      contain => in_shell,
+      handle => "is mutable",
+      if => fileexists("/tmp/immutable_12.txt");
+
+  files:
+    "/tmp/immutable_12.txt"
+      delete => tidy,
+      depends_on => { "is mutable" };
+  files:
+    "/tmp/immutable_12.txt.nuked"
+      delete => tidy;
+}