Acceptance test: override immutable bit with edit_xml

Added acceptance test to test that the edit_xml attribute of the files
promise can override the immutable bit of the destination file.

Ticket: ENT-10961, CFE-1840
Signed-off-by: Lars Erik Wik <lars.erik.wik@northern.tech>

Author: larsewi

tests/acceptance/10_files/14_immutable/immutable_06.cf

@@ -0,0 +1,87 @@
+##############################################################################
+#
+# Test that agent can override the immutable bit when using edit_xml attribute
+#
+##############################################################################
+
+body common control
+{
+  inputs => { "../../default.cf.sub" };
+  bundlesequence  => { default("$(this.promise_filename)") };
+  version => "1.0";
+}
+
+body fsattrs set_immutable
+{
+  immutable => "true";
+}
+
+bundle agent init
+{
+  files:
+    "/tmp/immutable_06.txt"
+      content => '<foo>I\'m immutable</foo>';
+
+  commands:
+    "chattr +i /tmp/immutable_06.txt"
+      contain => in_shell;
+}
+
+bundle edit_xml edit_foo
+{
+  set_text:
+    "But agent can override"
+      select_xpath => "/foo";
+}
+
+bundle agent test
+{
+  meta:
+    "description" -> { "CFE-1840", "ENT-10961" }
+      string => "Test that agent can override the immutable bit on a file while using the edit_xml attribute";
+
+    "test_soft_fail"
+      string => "hpux|aix|windows",
+      meta => { "CFE-1840", "ENT-10961" };
+
+  files:
+    "/tmp/immutable_06.txt"
+      fsattrs => set_immutable,
+      edit_xml => edit_foo;
+}
+
+bundle agent check
+{
+  vars:
+    "expected"
+      string => '<?xml version="1.0"?>$(const.n)<foo>But agent can override</foo>$(const.n)';
+    "actual"
+      string => readfile("/tmp/immutable_06.txt");
+
+  classes:
+    "ok"
+      expression => strcmp("$(actual)", "$(expected)");
+
+  reports:
+    ok::
+      "$(this.promise_filename) Pass";
+    !ok::
+      "$(this.promise_filename) FAIL";
+    any::
+      "Expected: '$(expected)', actual: '$(actual)'";
+}
+
+bundle agent destroy
+{
+  commands:
+    "chattr -i /tmp/immutable_06.txt"
+      contain => in_shell,
+      handle => "is mutable";
+
+  files:
+    "/tmp/immutable_06.txt"
+      delete => tidy,
+      depends_on => { "is mutable" };
+    "/tmp/immutable_06.txt.cf-before-edit"
+      delete => tidy;
+}