Acceptance test: override immutable bit with delete

Added acceptance test to test that the delete attribute of the files
promise can override the immutable bit of the destination file.

Ticket: ENT-10961, CFE-1840
Signed-off-by: Lars Erik Wik <lars.erik.wik@northern.tech>

Author: larsewi

tests/acceptance/10_files/14_immutable/immutable_04.cf

@@ -0,0 +1,71 @@
+##############################################################################
+#
+# Test that agent can override the immutable bit when using delete
+# attribute
+#
+##############################################################################
+
+body common control
+{
+  inputs => { "../../default.cf.sub" };
+  bundlesequence  => { default("$(this.promise_filename)") };
+  version => "1.0";
+}
+
+body fsattrs set_immutable
+{
+  immutable => "true";
+}
+
+bundle agent init
+{
+  files:
+    "/tmp/immutable_04.txt"
+      content => "I'm immutable";
+
+  commands:
+    "chattr +i /tmp/immutable_04.txt"
+      contain => in_shell;
+}
+
+bundle agent test
+{
+  meta:
+    "description" -> { "CFE-1840", "ENT-10961" }
+      string => "Test that agent can override the immutable bit on a file while using the delete attribute";
+
+    "test_soft_fail"
+      string => "hpux|aix|windows",
+      meta => { "CFE-1840", "ENT-10961" };
+
+  files:
+    "/tmp/immutable_04.txt"
+      fsattrs => set_immutable,
+      delete => tidy;
+}
+
+bundle agent check
+{
+  classes:
+    "ok"
+      expression => not(fileexists("/tmp/immutable_04.txt"));
+
+  reports:
+    ok::
+      "$(this.promise_filename) Pass";
+    !ok::
+      "$(this.promise_filename) FAIL";
+}
+
+bundle agent destroy
+{
+  commands:
+    "chattr -i /tmp/immutable_04.txt"
+      contain => in_shell,
+      handle => "is mutable";
+
+  files:
+    "/tmp/immutable_04.txt"
+      delete => tidy,
+      depends_on => { "is mutable" };
+}