Acceptance test: override immutable bit with perms

Added acceptance test to test that the perms attribute of the files
promise can override the immutable bit of the destination file.

Ticket: ENT-10961, CFE-1840
Changelog: The perms attribute of the files promise can now override the immutable bit.
Signed-off-by: Lars Erik Wik <lars.erik.wik@northern.tech>

Author: larsewi

tests/acceptance/10_files/14_immutable/immutable_07.cf

@@ -0,0 +1,79 @@
+##############################################################################
+#
+# Test that agent can override the immutable bit when using perms attribute
+#
+##############################################################################
+
+body common control
+{
+  inputs => { "../../default.cf.sub" };
+  bundlesequence  => { default("$(this.promise_filename)") };
+  version => "1.0";
+}
+
+body fsattrs set_immutable
+{
+  immutable => "true";
+}
+
+bundle agent init
+{
+  files:
+    "/tmp/immutable_07.txt"
+      create => "true",
+      perms => m("600");
+
+  commands:
+    "chattr +i /tmp/immutable_07.txt"
+      contain => in_shell;
+}
+
+bundle agent test
+{
+  meta:
+    "description" -> { "CFE-1840", "ENT-10961" }
+      string => "Test that agent can override the immutable bit on a file while using the perms attribute";
+
+    "test_soft_fail"
+      string => "hpux|aix|windows",
+      meta => { "CFE-1840", "ENT-10961" };
+
+  files:
+    "/tmp/immutable_07.txt"
+      fsattrs => set_immutable,
+      perms => m("644");
+}
+
+bundle agent check
+{
+  vars:
+    "expected"
+      string => "644";
+    "actual"
+      string => string_tail(filestat("/tmp/immutable_07.txt", "modeoct"), "3");
+
+  classes:
+    "ok"
+      expression => strcmp("$(actual)", "$(expected)");
+
+  reports:
+    ok::
+      "$(this.promise_filename) Pass";
+    !ok::
+      "$(this.promise_filename) FAIL";
+    any::
+      "Expected: '$(expected)', actual: '$(actual)'";
+}
+
+bundle agent destroy
+{
+  commands:
+    "chattr -i /tmp/immutable_07.txt"
+      contain => in_shell,
+      handle => "is mutable";
+
+  files:
+    "/tmp/immutable_07.txt"
+      delete => tidy,
+      depends_on => { "is mutable" };
+}