Acceptance test: override immutable bit with touch

Added acceptance test to test that the touch attribute of the files
promise can override the immutable bit of the destination file.

Ticket: ENT-10961, CFE-1840
Signed-off-by: Lars Erik Wik <lars.erik.wik@northern.tech>

Author: larsewi

tests/acceptance/10_files/14_immutable/immutable_08.cf

@@ -0,0 +1,76 @@
+##############################################################################
+#
+# Test that agent can override the immutable bit when using stat attribute
+#
+##############################################################################
+
+body common control
+{
+  inputs => { "../../default.cf.sub" };
+  bundlesequence  => { default("$(this.promise_filename)") };
+  version => "1.0";
+}
+
+body fsattrs set_immutable
+{
+  immutable => "true";
+}
+
+bundle agent init
+{
+  commands:
+    "touch -t 0001010100 /tmp/immutable_08.txt"
+      contain => in_shell;
+    "chattr +i /tmp/immutable_08.txt"
+      contain => in_shell;
+}
+
+bundle agent test
+{
+  meta:
+    "description" -> { "CFE-1840", "ENT-10961" }
+      string => "Test that agent can override the immutable bit on a file while using the stat attribute";
+
+    "test_soft_fail"
+      string => "hpux|aix|windows",
+      meta => { "CFE-1840", "ENT-10961" };
+
+  files:
+    "/tmp/immutable_08.txt"
+      fsattrs => set_immutable,
+      touch => "true";
+}
+
+bundle agent check
+{
+  vars:
+    "expected"
+      string => "946688400";
+    "actual"
+      string => filestat("/tmp/immutable_08.txt", "mtime");
+
+  classes:
+    "ok"
+      expression => not(strcmp("$(actual)", "$(expected)"));
+
+  reports:
+    ok::
+      "$(this.promise_filename) Pass";
+    !ok::
+      "$(this.promise_filename) FAIL";
+    any::
+      "$(expected) != $(actual)";
+}
+
+bundle agent destroy
+{
+  commands:
+    "chattr -i /tmp/immutable_08.txt"
+      contain => in_shell,
+      handle => "is mutable";
+
+  files:
+    "/tmp/immutable_08.txt"
+      delete => tidy,
+      depends_on => { "is mutable" };
+}