Acceptance test: override immutable bit with content

Added acceptance test to test that the content attribute of the files
promise can override the immutable bit.

Ticket: ENT-10961, CFE-1840
Changelog: Commit
Signed-off-by: Lars Erik Wik <lars.erik.wik@northern.tech>

Author: larsewi

tests/acceptance/10_files/14_immutable/immutable_02.cf

@@ -0,0 +1,79 @@
+##############################################################################
+#
+# Test that agent can override the immutable bit on a file while using the
+# content attribute
+#
+##############################################################################
+
+body common control
+{
+  inputs => { "../../default.cf.sub" };
+  bundlesequence  => { default("$(this.promise_filename)") };
+  version => "1.0";
+}
+
+body fsattrs set_immutable
+{
+  immutable => "true";
+}
+
+bundle agent init
+{
+  files:
+    "/tmp/immutable_02.txt"
+      content => "I'm immutable";
+
+  commands:
+    "chattr +i /tmp/immutable_02.txt"
+      contain => in_shell;
+}
+
+bundle agent test
+{
+  meta:
+    "description" -> { "CFE-1840", "ENT-10961" }
+      string => "Test that agent can override the immutable bit on a file while using the content attribute";
+
+    "test_soft_fail"
+      string => "hpux|aix|windows",
+      meta => { "CFE-1840", "ENT-10961" };
+
+  files:
+    "/tmp/immutable_02.txt"
+      fsattrs => set_immutable,
+      content => "But agent can override";
+}
+
+bundle agent check
+{
+  vars:
+    "expected"
+      string => "But agent can override";
+    "actual"
+      string => readfile("/tmp/immutable_02.txt");
+
+  classes:
+    "ok"
+      expression => strcmp("$(actual)", "$(expected)");
+
+  reports:
+    ok::
+      "$(this.promise_filename) Pass";
+    !ok::
+      "$(this.promise_filename) FAIL";
+    any::
+      "Expected: '$(expected)', actual: '$(actual)'";
+}
+
+bundle agent destroy
+{
+  commands:
+    "chattr -i /tmp/immutable_02.txt"
+      contain => in_shell,
+      handle => "is mutable";
+
+  files:
+    "/tmp/immutable_02.txt"
+      delete => tidy,
+      depends_on => { "is mutable" };
+}