Add support for automatically adding candidates for POT file generation

Author: jonnydgreen

addons/parley/constants.gd

@@ -4,8 +4,8 @@
 
 #region General
 # TODO: figure out better way of getting this version as it is duplicated
-const VERSION: String = "2.0.0"
-const AST_VERSION: String = "1.0.0"
+const VERSION: String = "2.1.0"
+const AST_VERSION: String = "1.1.0"
 const USER_CONFIG_PATH: String = "user://parley_user_config.json"
 #endregion
 
@@ -27,12 +27,16 @@ const EDITOR_CURRENT_DIALOGUE_SEQUENCE_PATH: String = "parley/editor/current_dia
 const DIALOGUE_BALLOON_PATH: String = "parley/dialogue/dialogue_balloon_path"
 #endregion
 
+#region Internationalisation
+# Project settings
+const TRANSLATION_MODE: String = "parley/translations/mode"
+const TRANSLATIONS_POT_FILES: String = "internationalization/locale/translations_pot_files"
+#endregion
+
 #region Stores
 # Project settings
 const ACTION_STORE_PATH: String = "parley/stores/action_store_path"
 const CHARACTER_STORE_PATH: String = "parley/stores/character_store_path"
-const CHARACTER_STORE_PATHS: String = "parley/stores/character_store_paths"
-const FACT_STORE_PATHS: String = "parley/stores/fact_store_paths"
 const FACT_STORE_PATH: String = "parley/stores/fact_store_path"
 #endregion
 

addons/parley/import_plugin.gd

@@ -10,11 +10,16 @@ const ParleyConstants = preload('./constants.gd')
 
 
 const ast_version: String = ParleyConstants.AST_VERSION
+var parley_manager: ParleyManager
 
 
 enum Presets {DEFAULT}
 
 
+func _init(p_parley_manager: ParleyManager) -> void:
+	parley_manager = p_parley_manager
+
+
 func _get_importer_name() -> String:
 	# NOTE: A change to this forces a re-import of all Dialogue Sequences
 	return "parley_dialogue_sequence_ast_%s" % ast_version
@@ -69,9 +74,9 @@ func _get_option_visibility(_path: String, _option_name: StringName, _options: D
 	return true
 
 
-func _import(source_file: String, save_path: String, _options: Dictionary, _platform_variants: Array[String], _gen_files: Array[String]) -> int:
+func _import(source_file_path: String, save_path: String, _options: Dictionary, _platform_variants: Array[String], _gen_files: Array[String]) -> int:
 	# Serialisation
-	var file: FileAccess = FileAccess.open(source_file, FileAccess.READ)
+	var file: FileAccess = FileAccess.open(source_file_path, FileAccess.READ)
 	if file == null:
 		return FileAccess.get_open_error()
 	var raw_text: String = file.get_as_text()
@@ -100,4 +105,8 @@ func _import(source_file: String, save_path: String, _options: Dictionary, _plat
 
 	# Compilation
 	var dialogue_ast: ParleyDialogueSequenceAst = ParleyDialogueSequenceAst.new(title, nodes, edges)
-	return ResourceSaver.save(dialogue_ast, "%s.%s" % [save_path, _get_save_extension()])
+	var save_result: int = ResourceSaver.save(dialogue_ast, "%s.%s" % [save_path, _get_save_extension()])
+	if save_result == OK:
+		if parley_manager and not source_file_path.begins_with("res://.godot"):
+			return parley_manager.register_localisation_path(source_file_path)
+	return save_result

addons/parley/main_panel.gd

@@ -175,12 +175,6 @@ func _set_node_ast(new_node_ast: ParleyNodeAst) -> void:
 		_:
 			push_error(ParleyUtils.log.error_msg("Unsupported Node type: %s for Node with ID: %s" % [ParleyDialogueSequenceAst.get_type_name(selected_node_ast.type), selected_node_ast.id]))
 			return
-
-
-# TODO: move to the correct region in this file
-func _on_dialogue_ast_changed(new_dialogue_ast: ParleyDialogueSequenceAst) -> void:
-	if sidebar:
-		sidebar.current_dialogue_ast = new_dialogue_ast
 #endregion
 
 
@@ -294,10 +288,15 @@ func _on_new_dialogue_sequence_modal_dialogue_ast_created(new_dialogue_ast: Parl
 	dialogue_ast = new_dialogue_ast
 	# TODO: emit as a signal and handle in the plugin
 	if parley_manager:
-		var current: Variant = null
+		var current_path: Variant = null
 		if dialogue_ast and dialogue_ast.resource_path:
-			current = dialogue_ast.resource_path
-		parley_manager.set_current_dialogue_sequence(current)
+			current_path = dialogue_ast.resource_path
+		parley_manager.set_current_dialogue_sequence(current_path)
+		# This is needed to correctly reload upon file saves
+		if dialogue_ast:
+			var update_result: int = parley_manager.update_localisations([dialogue_ast])
+			if update_result != OK:
+				push_warning(ParleyUtils.log.warn_msg("Unable to update localisations for new Dialogue Sequence (ds:%s): %s" % [dialogue_ast, error_string(update_result)]))
 	refresh(true)
 
 
@@ -317,6 +316,10 @@ func _on_save_pressed() -> void:
 	# This is needed to reset the Graph and ensure
 	# that no weirdness is going to happen. For example
 	# move the group nodes after a save when refresh isn't present
+	if parley_manager and dialogue_ast:
+		var update_result: int = parley_manager.update_localisations([dialogue_ast])
+		if update_result != OK:
+			push_warning(ParleyUtils.log.warn_msg("Unable to update localisations when saving Dialogue Sequence (ds:%s): %s" % [dialogue_ast, error_string(update_result)]))
 	await refresh()
 
 
@@ -363,6 +366,11 @@ func _on_test_dialogue_from_selected_button_pressed() -> void:
 
 
 #region SIGNALS
+func _on_dialogue_ast_changed(new_dialogue_ast: ParleyDialogueSequenceAst) -> void:
+	if sidebar:
+		sidebar.current_dialogue_ast = new_dialogue_ast
+
+
 func _on_action_store_changed() -> void:
 	if action_store and dialogue_ast:
 		var nodes: Array[ParleyNodeAst] = dialogue_ast.find_nodes_by_types([ParleyDialogueSequenceAst.Type.ACTION])

addons/parley/parley_manager.gd

@@ -154,6 +154,58 @@ func get_plugin_version() -> String:
 	return plugin.get_plugin_version()
 
 
+## Update localisation for all known Dialogue Sequences
+func register_localisation_path(path: String) -> int:
+	var pot_generation_candidates: PackedStringArray = ProjectSettings.get_setting(ParleyConstants.TRANSLATIONS_POT_FILES, [])
+	var changed: bool = false
+
+	if not pot_generation_candidates.has(path):
+		var _result: bool = pot_generation_candidates.append(path)
+		changed = true
+
+	if changed:
+		ProjectSettings.set_setting(ParleyConstants.TRANSLATIONS_POT_FILES, pot_generation_candidates)
+		var project_settings_save_result: int = ProjectSettings.save()
+		if project_settings_save_result != OK:
+			push_error(ParleyUtils.log.error_msg("Unable to save project settings: %d" % [project_settings_save_result]))
+		return project_settings_save_result
+	return OK
+
+
+## Update localisation for all known Dialogue Sequences
+func update_localisations(dialogue_sequences_to_register: Array[ParleyDialogueSequenceAst] = [], clean: bool = true) -> int:
+	var pot_generation_candidates: PackedStringArray = ProjectSettings.get_setting(ParleyConstants.TRANSLATIONS_POT_FILES, [])
+	var changed: bool = false
+
+	# Perform registrations
+	for dialogue_sequence_to_register: ParleyDialogueSequenceAst in dialogue_sequences_to_register:
+		if not dialogue_sequence_to_register.resource_path or (clean and not ResourceLoader.exists(dialogue_sequence_to_register.resource_path)):
+			push_warning(ParleyUtils.log.warn_msg("Unable to register localisation for Dialogue Sequence because it does not exist within the file system (ds:%s)" % dialogue_sequence_to_register))
+			return ERR_DOES_NOT_EXIST
+		else:
+			if not pot_generation_candidates.has(dialogue_sequence_to_register.resource_path):
+				var _result: bool = pot_generation_candidates.append(dialogue_sequence_to_register.resource_path)
+				changed = true
+
+	# Clean-up any candidates that no longer exist
+	# Reverse array so that elements are removed from the end and the indices are correct for any subsequence removals
+	if clean:
+		for i: int in range(pot_generation_candidates.size() - 1, -1, -1):
+			var candidate: String = pot_generation_candidates[i]
+			if candidate.get_extension() == "ds" and not ResourceLoader.exists(candidate):
+				pot_generation_candidates.remove_at(i)
+				changed = true
+
+	# Update project settings if POT candidates have been changed in any way
+	if changed:
+		ProjectSettings.set_setting(ParleyConstants.TRANSLATIONS_POT_FILES, pot_generation_candidates)
+		var project_settings_save_result: int = ProjectSettings.save()
+		if project_settings_save_result != OK:
+			push_error(ParleyUtils.log.error_msg("Unable to save project settings: %d" % [project_settings_save_result]))
+		return project_settings_save_result
+	return OK
+
+
 func set_current_dialogue_sequence(path: Variant) -> void:
 	if not Engine.is_editor_hint():
 		return

addons/parley/parley_plugin.gd

@@ -38,7 +38,7 @@ func _enter_tree() -> void:
 		var parley_manager: ParleyManager = ParleyManager.get_instance()
 
 		# Import plugin setup
-		import_plugin = ParleyImportPlugin.new()
+		import_plugin = ParleyImportPlugin.new(parley_manager)
 		add_import_plugin(import_plugin)
 
 		# Translation plugin setup

addons/parley/plugin.cfg

@@ -3,5 +3,5 @@
 name="Parley Dialogue Manager"
 description="The easy-to-use, writer-first, scalable dialogue management system."
 author="Bisterix Studio"
-version="2.0.0"
+version="2.1.0"
 script="parley_plugin.gd"

addons/parley/settings.gd

@@ -14,36 +14,63 @@ static var DEFAULT_SETTINGS: Dictionary = {
 	ParleyConstants.CHARACTER_STORE_PATH: "res://characters/character_store.tres",
 	ParleyConstants.ACTION_STORE_PATH: "res://actions/action_store.tres",
 	ParleyConstants.FACT_STORE_PATH: "res://facts/fact_store.tres",
+	# Internationalisation
+	ParleyConstants.TRANSLATION_MODE: TranslationMode.keys()[TranslationMode.PO],
 	# Test Dialogue Sequence
 	# We can't preload this because of circular deps so let's
 	# hardcode it for now but allow people to edit it in settings
 	ParleyConstants.TEST_DIALOGUE_SEQUENCE_TEST_SCENE_PATH: "res://addons/parley/views/test_dialogue_sequence_scene.tscn",
 }
 
 
+enum TranslationMode {
+	PO,
+	# TODO: add CSV
+	# CSV,
+	# TODO: add None
+	# None,
+}
+
+
 static var TYPES: Dictionary = {
+	# Dialogue
 	ParleyConstants.DIALOGUE_BALLOON_PATH: {
 		"name": ParleyConstants.DIALOGUE_BALLOON_PATH,
+		"description": "Defines the path to the default Dialogue balloon that is used to render the dialogue when testing and running Dialogue Sequences.",
 		"type": TYPE_STRING,
 		"hint": PROPERTY_HINT_FILE,
 	},
+	# Stores
 	ParleyConstants.ACTION_STORE_PATH: {
 		"name": ParleyConstants.ACTION_STORE_PATH,
+		"description": "Defines the path to the Action Store resource that is used to store actions.",
 		"type": TYPE_STRING,
 		"hint": PROPERTY_HINT_FILE,
 	},
 	ParleyConstants.CHARACTER_STORE_PATH: {
 		"name": ParleyConstants.CHARACTER_STORE_PATH,
+		"description": "Defines the path to the Character Store resource that is used to store characters.",
 		"type": TYPE_STRING,
 		"hint": PROPERTY_HINT_FILE,
 	},
 	ParleyConstants.FACT_STORE_PATH: {
 		"name": ParleyConstants.FACT_STORE_PATH,
+		"description": "Defines the path to the Fact Store resource that is used to store facts.",
 		"type": TYPE_STRING,
 		"hint": PROPERTY_HINT_FILE,
 	},
+	# Internationalisation
+	ParleyConstants.TRANSLATION_MODE: {
+		"name": ParleyConstants.TRANSLATION_MODE,
+		"description": "Defines the translation mode to determine how to find and interpret translations.",
+		"type": TYPE_STRING,
+		"hint": PROPERTY_HINT_ENUM,
+		"hint_string": ",".join(TranslationMode.keys())
+	},
+	# Testing
 	ParleyConstants.TEST_DIALOGUE_SEQUENCE_TEST_SCENE_PATH: {
 		"name": ParleyConstants.TEST_DIALOGUE_SEQUENCE_TEST_SCENE_PATH,
+		"description": "Defines the path to the default test scene that is rendered when testing Dialogue Sequences.",
 		"type": TYPE_STRING,
 		"hint": PROPERTY_HINT_FILE,
 	}
@@ -58,9 +85,9 @@ static func prepare(save: bool = true) -> void:
 		if not ProjectSettings.has_setting(setting_name):
 			set_setting(setting_name, DEFAULT_SETTINGS[setting_name])
 		ProjectSettings.set_initial_value(setting_name, DEFAULT_SETTINGS[setting_name])
-		var _info: Variant = TYPES.get(setting_name)
-		if is_instance_of(_info, TYPE_DICTIONARY):
-			var info: Dictionary = _info
+		var info_variant: Variant = TYPES.get(setting_name)
+		if is_instance_of(info_variant, TYPE_DICTIONARY):
+			var info: Dictionary = info_variant
 			ProjectSettings.add_property_info(info)
 
 	# Reset some user values upon load that might cause weirdness:

dialogue_sequences/all.ds.import

@@ -1,6 +1,6 @@
 [remap]
 
-importer="parley_dialogue_sequence_ast_1.0.0"
+importer="parley_dialogue_sequence_ast_1.1.0"
 type="Resource"
 uid="uid://d2883lul36r1d"
 path="res://.godot/imported/all.ds-d8506930102030864fdc0be22ee21873.tres"

dialogue_sequences/next_dialogue.ds.import

@@ -1,6 +1,6 @@
 [remap]
 
-importer="parley_dialogue_sequence_ast_1.0.0"
+importer="parley_dialogue_sequence_ast_1.1.0"
 type="Resource"
 uid="uid://cfaambg2fkgnh"
 path="res://.godot/imported/next_dialogue.ds-1f2d2ca9751962b670972e838b0d73c3.tres"