Get basic exports working

Author: jonnydgreen

addons/parley/main_panel.gd

@@ -4,9 +4,12 @@
 class_name ParleyMainPanel extends VBoxContainer
 
 
+const ParleyExport = preload("./parley_export.gd")
+
+
 const new_file_icon: CompressedTexture2D = preload("./assets/New.svg")
 const load_file_icon: CompressedTexture2D = preload("./assets/Load.svg")
-const export_to_csv_icon: CompressedTexture2D = preload("./assets/Export.svg")
+const export_icon: CompressedTexture2D = preload("./assets/Export.svg")
 const insert_after_icon: CompressedTexture2D = preload("./assets/InsertAfter.svg")
 const dialogue_icon: CompressedTexture2D = preload("./assets/Dialogue.svg")
 const dialogue_option_icon: CompressedTexture2D = preload("./assets/DialogueOption.svg")
@@ -38,10 +41,11 @@ var parley_manager: ParleyManager
 
 @onready var file_menu: MenuButton = %FileMenu
 @onready var insert_menu: MenuButton = %InsertMenu
+@onready var translations_menu: MenuButton = %TranslationMenu
 @onready var docs_button: Button = %DocsButton
 @onready var new_dialogue_sequence_modal: ParleyNewDialogueSequenceModal = %NewDialogueSequenceModal
 @onready var edit_dialogue_sequence_modal: ParleyEditDialogueSequenceModal = %EditDialogueSequenceModal
-@onready var export_to_csv_modal: ParleyExportToCsvModal = %ExportToCsvModal
+@onready var export_modal: ParleyExportModal = %ExportModal
 @onready var select_locale_modal: Window = %SelectLocaleModal
 @onready var editor: HSplitContainer = %EditorView
 @onready var sidebar: ParleySidebar = %Sidebar
@@ -218,6 +222,7 @@ func _render_test_locale_editor(on_ready: bool = false) -> void:
 func _setup(on_ready: bool = false) -> void:
 	_setup_file_menu()
 	_setup_insert_menu()
+	_render_translations_menu()
 	_render_toolbar()
 	_render_bottom_panel()
 	_render_test_locale_editor(on_ready)
@@ -230,7 +235,7 @@ func _setup_file_menu() -> void:
 	popup.add_icon_item(new_file_icon, "New Dialogue Sequence...", 0)
 	popup.add_icon_item(load_file_icon, "Open Dialogue Sequence...", 1)
 	popup.add_separator("Export")
-	popup.add_icon_item(export_to_csv_icon, "Export to CSV...", 2)
+	popup.add_icon_item(export_icon, "Export to CSV...", 2)
 	ParleyUtils.signals.safe_connect(popup.id_pressed, _on_file_id_pressed)
 
 
@@ -252,6 +257,22 @@ func _setup_insert_menu() -> void:
 	popup.add_icon_item(end_node_icon, ParleyDialogueSequenceAst.get_type_name(ParleyDialogueSequenceAst.Type.END), ParleyDialogueSequenceAst.Type.END)
 	popup.add_icon_item(group_node_icon, ParleyDialogueSequenceAst.get_type_name(ParleyDialogueSequenceAst.Type.GROUP), ParleyDialogueSequenceAst.Type.GROUP)
 	ParleyUtils.signals.safe_connect(popup.id_pressed, _on_insert_id_pressed)
+
+
+func _render_translations_menu() -> void:
+	var popup: PopupMenu = translations_menu.get_popup()
+	popup.clear()
+
+	popup.add_icon_item(export_icon, "Export Dialogue to CSV...", 0)
+	popup.set_item_tooltip(0, "Export Dialogue Text Translations to CSV")
+
+	popup.add_icon_item(export_icon, "Export Characters to CSV...", 1)
+	popup.set_item_tooltip(1, "Export Character Translations to CSV")
+
+	popup.add_icon_item(export_icon, "Import Dialogue from CSV...", 2)
+	popup.set_item_tooltip(2, "Import Dialogue Text Translations from CSV")
+
+	ParleyUtils.signals.safe_connect(popup.id_pressed, _on_translations_menu_id_pressed)
 #endregion
 
 
@@ -265,8 +286,7 @@ func _on_file_id_pressed(id: int) -> void:
 			# TODO: get this from config (note, see the Node inspector as well)
 			open_file_dialogue.current_dir = "res://dialogue_sequences"
 		2:
-			export_to_csv_modal.dialogue_ast = dialogue_ast
-			export_to_csv_modal.render()
+			export_modal.render(ParleyExportModal.ExportType.Node, ParleyExportModal.FileType.Csv, dialogue_ast)
 		_:
 			print_rich(ParleyUtils.log.info_msg("Unknown option ID pressed: {id}".format({'id': id})))
 
@@ -320,6 +340,19 @@ func _on_insert_id_pressed(type: ParleyDialogueSequenceAst.Type) -> void:
 		await refresh()
 
 
+func _on_translations_menu_id_pressed(id: int) -> void:
+	match id:
+		0:
+			export_modal.render(ParleyExportModal.ExportType.DialogueTextTranslation, ParleyExportModal.FileType.Csv, dialogue_ast)
+		1:
+			export_modal.render(ParleyExportModal.ExportType.CharacterNameTranslation, ParleyExportModal.FileType.Csv, dialogue_ast)
+		1:
+			# IMPORT
+			return
+		_:
+			print_rich(ParleyUtils.log.info_msg("Unknown option ID pressed: {id}".format({'id': id})))
+
+
 func _on_save_pressed() -> void:
 	var result: int = _save_dialogue()
 	if result != OK:
@@ -697,6 +730,21 @@ func _on_docs_button_pressed() -> void:
 	var result: int = OS.shell_open(href)
 	if result != OK:
 		push_error(ParleyUtils.log.error_msg("Unable to navigate to Parley Documentation at %s: %s" % [href, result]))
+
+
+func _on_export_requested(export_type: ParleyExportModal.ExportType, file_type: ParleyExportModal.FileType, dialogue_sequence_ast: ParleyDialogueSequenceAst, path: String) -> void:
+	var file_type_name: String = ParleyUtils.string.get_enum_key_name(ParleyExportModal.FileType, file_type)
+	var export_type_name: String = ParleyUtils.string.get_enum_key_name(ParleyExportModal.ExportType, export_type)
+	match export_type:
+		ParleyExportModal.ExportType.Node:
+			ParleyExport.export_node(file_type, dialogue_sequence_ast, path)
+		ParleyExportModal.ExportType.DialogueTextTranslation:
+			ParleyExport.export_dialogue_text_translation(file_type, dialogue_sequence_ast, path)
+		ParleyExportModal.ExportType.CharacterNameTranslation:
+			ParleyExport.export_character_name_translation(file_type, dialogue_sequence_ast, path)
+		_:
+			push_error(ParleyUtils.log.error_msg("Unable to export data: unknown export type (file_type:%s, export_type:%s)" % [file_type_name, export_type_name]))
+			return
 #endregion
 
 

addons/parley/main_panel.tscn

@@ -26,7 +26,7 @@
 [ext_resource type="Script" uid="uid://b3tj6amhgmct6" path="res://addons/parley/stores/action/action_store.gd" id="26_anq7l"]
 [ext_resource type="Texture2D" uid="uid://es7k6io6r0lm" path="res://addons/parley/assets/Translation.svg" id="27_owjo5"]
 [ext_resource type="Script" uid="uid://cbi8x2vk7bku1" path="res://addons/parley/stores/character/character_store.gd" id="28_anq7l"]
-[ext_resource type="PackedScene" uid="uid://c6cagjh7y5wn4" path="res://addons/parley/modals/export_to_csv_modal.tscn" id="29_wngpy"]
+[ext_resource type="PackedScene" uid="uid://c6cagjh7y5wn4" path="res://addons/parley/modals/export_modal.tscn" id="29_wngpy"]
 [ext_resource type="PackedScene" uid="uid://cjgxxvotxhj1g" path="res://addons/parley/components/bottom_panel.tscn" id="29_xxhvx"]
 [ext_resource type="Script" uid="uid://ob0am6au6mmt" path="res://addons/parley/stores/fact/fact_store.gd" id="30_7jaih"]
 [ext_resource type="Script" uid="uid://cjo7uxv32sr14" path="res://addons/parley/models/edge_ast.gd" id="30_rspbv"]
@@ -181,6 +181,21 @@ popup/item_12/text = "Group"
 popup/item_12/icon = ExtResource("10_h0et1")
 popup/item_12/id = 6
 
+[node name="TranslationMenu" type="MenuButton" parent="MarginContainer/MainContainer/HSplitContainer/MainViewPanel/MainViewContainer/Toolbar/MenuBar"]
+unique_name_in_owner = true
+layout_mode = 2
+text = "Translations"
+item_count = 3
+popup/item_0/text = "Export Dialogue to CSV..."
+popup/item_0/icon = ExtResource("12_242yd")
+popup/item_0/id = 0
+popup/item_1/text = "Export Characters to CSV..."
+popup/item_1/icon = ExtResource("12_242yd")
+popup/item_1/id = 1
+popup/item_2/text = "Import Dialogue from CSV..."
+popup/item_2/icon = ExtResource("12_242yd")
+popup/item_2/id = 2
+
 [node name="VSeparator" type="VSeparator" parent="MarginContainer/MainContainer/HSplitContainer/MainViewPanel/MainViewContainer/Toolbar"]
 layout_mode = 2
 
@@ -296,7 +311,7 @@ filters = PackedStringArray("*.ds")
 unique_name_in_owner = true
 visible = false
 
-[node name="ExportToCsvModal" parent="." instance=ExtResource("29_wngpy")]
+[node name="ExportModal" parent="." instance=ExtResource("29_wngpy")]
 unique_name_in_owner = true
 visible = false
 dialogue_ast = SubResource("Resource_7hjis")
@@ -328,5 +343,6 @@ visible = false
 [connection signal="sidebar_toggled" from="MarginContainer/MainContainer/HSplitContainer/MainViewPanel/MainViewContainer/EditorView/GraphContainer/BottomPanel" to="." method="_on_bottom_panel_sidebar_toggled"]
 [connection signal="file_selected" from="OpenFileDialog" to="." method="_on_open_dialog_file_selected"]
 [connection signal="dialogue_ast_created" from="NewDialogueSequenceModal" to="." method="_on_new_dialogue_sequence_modal_dialogue_ast_created"]
+[connection signal="export_requested" from="ExportModal" to="." method="_on_export_requested"]
 [connection signal="dialogue_ast_edited" from="EditDialogueSequenceModal" to="." method="_on_edit_dialogue_sequence_modal_dialogue_ast_edited"]
 [connection signal="locale_changed" from="SelectLocaleModal" to="." method="_on_select_locale_modal_locale_changed"]

addons/parley/modals/export_modal.gd

@@ -0,0 +1,162 @@
+# Copyright 2024-2025 the Bisterix Studio authors. All rights reserved. MIT license.
+
+@tool
+class_name ParleyExportModal extends Window
+
+
+#region DEFS
+@onready var path_editor: LineEdit = %PathEdit
+@onready var choose_path_modal: FileDialog = %ChoosePathModal
+@onready var status_label: RichTextLabel = %Status
+
+
+# TODO: rename
+@export var dialogue_ast: ParleyDialogueSequenceAst
+
+
+# TODO: get from config
+var base_path: String
+var export_path: String
+var file_type: FileType = FileType.Csv
+var export_type: ExportType = ExportType.DialogueTextTranslation : set = _set_export_type
+
+
+enum FileType {
+	Csv,
+}
+
+
+enum ExportType {
+	Node,
+	DialogueTextTranslation,
+	CharacterNameTranslation,
+}
+
+
+signal export_requested(export_type: ExportType, file_type: FileType, dialogue_sequence_ast: ParleyDialogueSequenceAst, path: String)
+#endregion
+
+
+#region SETTERS
+func _set_export_type(new_export_type: ExportType) -> void:
+	export_type = new_export_type
+	_render_title()
+	_render_status()
+
+
+func _set_file_type(new_file_type: FileType) -> void:
+	file_type = new_file_type
+	_render_title()
+	_render_status()
+#endregion
+
+
+#region LIFECYCLE
+# TODO: check where this is called
+func render(p_export_type: ExportType, p_file_type: FileType, p_dialogue_sequence_ast: ParleyDialogueSequenceAst) -> void:
+	file_type = p_file_type
+	export_type = p_export_type
+	dialogue_ast = p_dialogue_sequence_ast
+
+	if not path_editor:
+		return
+	base_path = "res://exports"
+
+	export_path = base_path.path_join(_generate_file_name())
+	path_editor.text = export_path
+	show()
+
+
+func _render_title() -> void:
+	title = "Export %s to %s" % [_get_export_type_name(), _get_file_type_name()]
+
+
+func _render_status() -> void:
+	var text: String = """[color=#19e34f]
+[ul]%s path name is valid[/ul][/color][color=#19e34f]
+[ul]Will export the %s to %s[/ul][/color]
+""" % [_get_file_type_name(), _get_export_type_name(), _get_file_type_name()]
+	if status_label:
+		status_label.text = text
+#endregion
+
+
+#region SIGNALS
+func _on_export_button_pressed() -> void:
+	if not dialogue_ast:
+		push_error(ParleyUtils.log.error_msg("No Dialogue AST associated with export."))
+		return
+	export_requested.emit(export_type, file_type, dialogue_ast, export_path)
+	hide()
+
+
+func _on_choose_path_modal_file_selected(path: String) -> void:
+	if path_editor:
+		path_editor.text = path
+		base_path = path.get_base_dir()
+		export_path = path
+
+
+func _on_cancel_button_pressed() -> void:
+	hide()
+
+
+func _on_close_requested() -> void:
+	hide()
+
+
+func _on_choose_path_button_pressed() -> void:
+	if choose_path_modal:
+		choose_path_modal.show()
+		choose_path_modal.current_dir = base_path
+		choose_path_modal.current_file = export_path
+#endregion
+
+
+#region CRUD
+func _generate_file_name() -> String:
+	var timestamp: String = str(int(Time.get_unix_time_from_system()))
+	var dialogue_sequence_ast_path: String = dialogue_ast.resource_path if dialogue_ast.resource_path else "dialogue.ds"
+	var dialogue_sequence_ast_path_parts: PackedStringArray = dialogue_sequence_ast_path.split('/')
+	var dialogue_sequence_name: String = dialogue_sequence_ast_path_parts[dialogue_sequence_ast_path_parts.size() - 1].to_snake_case().replace('.ds', '')
+	var file_context: String = ""
+	match export_type:
+		ExportType.DialogueTextTranslation:
+			file_context = "dialogue_text_translations"
+		ExportType.CharacterNameTranslation:
+			file_context = "character_name_translations"
+		ExportType.Node:
+			file_context = dialogue_sequence_name
+	return "export_%s_%s%s" % [file_context, timestamp, _get_file_type_extension()]
+
+
+func _get_file_type_name() -> String:
+	match file_type:
+		FileType.Csv:
+			return "CSV"
+		_:
+			push_warning(ParleyUtils.log.warn_msg("Unknown File Type: %s, defaulting to CSV" % ParleyUtils.string.get_enum_key_name(FileType, file_type)))
+			return "CSV"
+
+
+func _get_file_type_extension() -> String:
+	match file_type:
+		FileType.Csv:
+			return ".csv"
+		_:
+			push_warning(ParleyUtils.log.warn_msg("Unknown File Type: %s, defaulting to CSV" % ParleyUtils.string.get_enum_key_name(FileType, file_type)))
+			return ".csv"
+
+
+func _get_export_type_name() -> String:
+	match export_type:
+		ExportType.Node:
+			return "Dialogue Sequence"
+		ExportType.DialogueTextTranslation:
+			return "Dialogue Text Translations"
+		ExportType.CharacterNameTranslation:
+			return "Character Name Translations"
+		_:
+			push_warning(ParleyUtils.log.warn_msg("Unknown Export Type: %s, defaulting to Dialogue Text Translations" % ParleyUtils.string.get_enum_key_name(ExportType, export_type)))
+			return "Dialogue Text Translations"
+#endregion