initial ant support

extending `build.xml` file with target that print classpath. trying to
guess classpath variable.

related #391

Author: artur-shaik

autoload/javacomplete/classpath/ant.vim

@@ -0,0 +1,74 @@
+let s:antXmlTemplate = [
+      \ '  <target name="vjc-test-conditions">',
+      \ '      <condition property="vjc-netbeans-condition">',
+      \ '          <isset property="javac.classpath" />',
+      \ '      </condition>',
+      \ '      <condition property="vjc-project-condition">',
+      \ '          <isreference refid="project.classpath"/>',
+      \ '      </condition>',
+      \ '  </target>',
+      \ '  <target name="vjc-netbeans-classpath" depends="vjc-test-conditions" if="vjc-netbeans-condition">',
+      \ '      <property name="javavi.classpath" value="${javac.classpath}" />',
+      \ '  </target>',
+      \ '  <target name="vjc-project-classpath" depends="vjc-test-conditions" if="vjc-project-condition">',
+      \ '      <property name="javavi.classpath" refid="project.classpath"/>',
+      \ '  </target>',
+      \ '  <target name="vjc-printclasspath" depends="vjc-project-classpath,vjc-netbeans-classpath">',
+      \ '      <echo message="${javavi.classpath}"/>',
+      \ '  </target>']
+
+function! s:Log(log)
+  let log = type(a:log) == type("") ? a:log : string(a:log)
+  call javacomplete#logger#Log("[classpath.ant] ". log)
+endfunction
+
+function! javacomplete#classpath#ant#IfAnt()
+  if executable('ant') && g:JavaComplete_AntPath != ""
+    return 1
+  endif
+  return 0
+endfunction
+
+function! javacomplete#classpath#ant#Generate(force) abort
+  let g:JavaComplete_ProjectKey = substitute(g:JavaComplete_AntPath, '[\\/:;.]', '_', 'g')
+  let path = javacomplete#util#GetBase("classpath". g:FILE_SEP). g:JavaComplete_ProjectKey
+
+  call s:Log(path)
+  if filereadable(path)
+    if a:force == 0 && getftime(path) >= getftime(g:JavaComplete_AntPath)
+      call s:Log("get libs from cache file")
+      return join(readfile(path), '')
+    endif
+    call javacomplete#util#RemoveFile(javacomplete#util#GetBase('cache'). g:FILE_SEP. 'class_packages_'. g:JavaComplete_ProjectKey. '.dat')
+  endif
+
+  let hasInitTarget = !empty(system("ant -projecthelp -v | grep '^ init\\>'"))
+  let tmpFile = []
+  for line in readfile(g:JavaComplete_AntPath)
+    if stridx(line, '</project>') >= 0
+      if hasInitTarget
+        let xmlTemplate = s:antXmlTemplate
+        let xmlTemplate[0] = xmlTemplate[0][:-2]. ' depends="init">'
+        call extend(tmpFile, xmlTemplate)
+      else
+        call extend(tmpFile, s:antXmlTemplate)
+      endif
+    endif
+    call add(tmpFile, line)
+  endfor
+  let s:temporaryAntFile = "vjc-ant-build.xml"
+  call writefile(tmpFile, s:temporaryAntFile)
+
+  let antCmd = ['ant', '-f', s:temporaryAntFile, '-q', 'vjc-printclasspath']
+  call delete(s:temporaryAntFile)
+  let result = system(join(antCmd, " "))
+  for line in split(result, '\n')
+    let matches = matchlist(line, '\m^\s\+\[echo\]\s\+\(.*\)')
+    if !empty(matches)
+      return matches[1]
+    endif
+  endfor
+  return '.'
+endfunction
+
+" vim:set fdm=marker sw=2 nowrap:

autoload/javacomplete/classpath/classpath.vim

@@ -1,3 +1,8 @@
+function! s:Log(log)
+  let log = type(a:log) == type("") ? a:log : string(a:log)
+  call javacomplete#logger#Log("[classpath] ". log)
+endfunction
+
 function! javacomplete#classpath#classpath#BuildClassPath()
   call s:BuildClassPath(0)
 endfunction
@@ -12,6 +17,7 @@ function! s:BuildClassPath(force)
       let g:JavaComplete_PomPath = javacomplete#util#FindFile('pom.xml')
       if g:JavaComplete_PomPath != ""
         let g:JavaComplete_PomPath = fnamemodify(g:JavaComplete_PomPath, ':p')
+        call s:Log("found maven file: ". g:JavaComplete_PomPath)
       endif
     endif
   endif
@@ -25,11 +31,28 @@ function! s:BuildClassPath(force)
       endif
       if g:JavaComplete_GradlePath != ""
         let g:JavaComplete_GradlePath = fnamemodify(g:JavaComplete_GradlePath, ':p')
+        call s:Log("found gradle file: ". g:JavaComplete_GradlePath)
+      endif
+    endif
+  endif
+
+  if !get(g:, 'JavaComplete_AntRepositoryDisabled', 0)
+    if !exists('g:JavaComplete_AntPath')
+      if filereadable(getcwd(). g:FILE_SEP. "build.xml")
+        let g:JavaComplete_AntPath = getcwd(). g:FILE_SEP. "build.xml"
+      else
+        let g:JavaComplete_AntPath = javacomplete#util#FindFile('build.xml', '**3')
+      endif
+      if g:JavaComplete_AntPath != ""
+        let g:JavaComplete_AntPath = fnamemodify(g:JavaComplete_AntPath, ':p')
+        call s:Log("found ant file: ". g:JavaComplete_AntPath)
       endif
     endif
   endif
 
   let g:JavaComplete_LibsPath .= s:FindClassPath(a:force)
+
+  call s:Log("libs found: ". g:JavaComplete_LibsPath)
 endfunction
 
 function! s:ReadClassPathFile(classpathFile)
@@ -68,12 +91,21 @@ function! s:UseGradle(force)
   return ""
 endf
 
+function! s:UseAnt(force)
+  if javacomplete#classpath#ant#IfAnt()
+    return javacomplete#classpath#ant#Generate(a:force)
+  endif
+
+  return ""
+endf
+
 function! s:FindClassPath(force) abort
   for classpathSourceType in g:JavaComplete_ClasspathGenerationOrder
     try
       let cp = ''
       exec "let cp .= s:Use". classpathSourceType. "(". a:force. ")"
       if !empty(cp)
+        call s:Log("found ". classpathSourceType. " project")
         return '.' . g:PATH_SEP . cp
       endif
     catch

plugin/javacomplete.vim

@@ -30,7 +30,7 @@ let g:JavaComplete_ShowExternalCommandsOutput =
       \ get(g:, 'JavaComplete_ShowExternalCommandsOutput', 0)
 
 let g:JavaComplete_ClasspathGenerationOrder =
-      \ get(g:, 'g:JavaComplete_ClasspathGenerationOrder', ['Eclipse', 'Maven', 'Gradle'])
+      \ get(g:, 'g:JavaComplete_ClasspathGenerationOrder', ['Eclipse', 'Maven', 'Gradle', 'Ant'])
 
 let g:JavaComplete_ImportSortType =
       \ get(g:, 'JavaComplete_ImportSortType', 'jarName')