Using multiple WebQuery in a Rule.

[peteDDD]

I am using "Version":"15.0.1(release-tasmota)","BuildDateTime":"2025-06-14T10:30:42"
I am building a watchdog on a smart plug. For this I want to do two web queries, one to my Home Assistant and one to my router. I then do different things if only HA is down or if the router is also down. Sounds simple enough. Two days later.. I am running out of things to try...

The command documentation indicates that one can number the WebQuery instances to separate them, ie WebQuery1 and WebQuery2.

This also implies that one can test the WebQuery results for each numbered query separately. What I am finding though is that all queries return only
RESULT = {"WebQuery":"Connect failed"}
or
RESULT = {"WebQuery":"Done"}

but not what I would expect...
RESULT = {"WebQuery1":"Connect failed"}
or
RESULT = {"WebQuery2":"Done"}

Here is my code... (Power2 and Power3 are LEDs using relay_i instead of led_1 because that works whereas led_i is not working for two LEDs for some reason... but that is another discussion)

Rule1
  ON system#boot DO backlog Power1 1; Power3 1; Var1 1; BlinkTime 6; BlinkCount 32000; Power2 Blink ENDON
  ON Var1#State>16 DO Var1 16 ENDON

  ON Time#Minute|%var1% DO backlog BlinkTime 3; BlinkCount 32000; Power2 Blink; WebQuery1 http://192.168.1.220:8123/ GET 100; WebQuery2 http://192.168.1.1/ GET 100 ENDON

  ON WebQuery1#Data=Done DO backlog Var1 1; Power2 BlinkOff; Power2 0; Power1 1; Power3 1 ENDON
  ON WebQuery1#Data$!Done DO backlog BlinkTime 1 ENDON

  ON WebQuery2#Data=Done DO backlog Mult1 2; Power1 0; Power3 0; Delay 30; Power1 1; Power3 1 ENDON
  ON WebQuery2#Data$!Done DO backlog BlinkTime 1 ENDON

What am I missing here?

I could do this with one WebQuery and one Ping instead but 1) I would have to have a build of Tasmota with Ping and I can't seem to flash a new version of Tasmota to the smart plug without getting a insufficient memory error and I don't want to open up the plug to do a clean, hardware flash. 2) I prefer WebQuery since it is higher in the stack than a ping so it actually confirms that the webpage is responding which is a more complete test than a ping could provide (the NIC can still give a ping response while the HA code has hung).

[sfromis]

In the driver code, I see no signs of the WebQuery command supporting an index, meaning that it looks like any value will simply be ignored. I suspect that the docs for the command (which you quote) was based on copying from some other command, without cleaning up this detail.

Additionally, as Tasmota is not multi-threaded, I'd not expect multiple WebQuery commands to be processed successfully unless you delay command number two till number 1 was completed. This will of course make the rule a bit more complicated, especially as the command processing is not immediate, but with the response coming later.

BTW. As commands like BlinkCount are configuration commands to update persistent settings, they are not meant to be part of the sequence every time. Once is enough, even without repeating for every boot.

When it comes to upgrading firmware, it should work find if you upgrade via the http url (not https), and make sure to select a binary file name ending with .gz. Tasmota will unpack as needed, and will do a two-step upgrade process to deal with the limited memory.

[peteDDD]

@sfromis Thanks for the timely comments. Indeed I have found lots of typos in the doc, so I guess this must just be one more...

Regarding the BlinkCount, thanks. I set now to 0, once, and that works as I need it to.

I have been testing a two-step approach where Var2 is a flag for which WebQuery is being tested, but having difficulty with the BlinkOff and Power2 0 actually working. Here is a version of what I am testing now (with comments that I remove for the one-line entry into the console).

// Var1 interval
// Var2 0 = Testing Home Assistant  1 = Testing Router

// Power1 Outlet
// Power2 Red LED
// Power3 Blue LED

Rule1
  ON system#boot DO backlog Power1 1; Power3 1; Var1 1; BlinkTime 10; BlinkCount 0; Power2 Blink; Var2 0 ENDON  // Outlet on, Blue LED on, Red LED slow flash (appears purple)
  ON Var1#State>16 DO Var1 16 ENDON  // limit interval to 16 minutes

  ON Time#Minute|%var1% DO backlog Var2 0; BlinkTime 5; Power2 Blink; WebQuery http://192.168.1.220:8123/ GET 100 ENDON // clear flags, check Home Assistant, more rapid Red LED flash (flashes purple)

  // Step 2: Handle Home Assistant result and if down, test Router
  ON WebQuery#Data=Done DO IF %var2%==0 backlog Var1 1; Power2 BlinkOff; Delay 1; Power1 1; Power2 0; Power3 1 ENDON  // HA connected, no need to test Router
  ON WebQuery#Data$!Done DO IF %var2%==0 backlog Var2 1; WebQuery http://192.168.1.1/ GET 100 ENDIF ENDON // HA not connected, test Router

  // Step 3: Handle Router result 
  ON WebQuery#Data=Done DO IF %var2%!=0 backlog Mult1 2; Power1 0; Power3 0; Delay 30; Power1 1; Power3 1 ENDIF ENDON  // // HA down, Router Up: double interval, cycle outlet off then on
  ON WebQuery#Data$!Done DO IF %var2%!=0 backlog BlinkTime 1 //HA Down, Router down: Flash more rapidly

I added the delay after the BlinkOff in hopes that would let that command "settle" but the red LED continues to flash.

The log at 20:52:13.215 shows 0==0 so I would understand that the following commands would execute. But shouldn't the log then show the states that change, for example showing something like RESULT = {"POWER2":"Blink OFF"]? I am gathering that the commands after the IF is satisfied are not being executed. Do you see what I might be doing wrong here?

20:52:12.257 RUL: TIME#MINUTE|%VAR1% performs 'backlog Var2 0; BlinkTime 5; Power2 Blink; WebQuery http://192.168.1.220:8123/ GET 100'
20:52:12.284 RSL: RESULT = {"Var2":"0"}
20:52:12.533 RSL: RESULT = {"BlinkTime":5}
20:52:12.940 RSL: RESULT = {"POWER2":"Blink ON"}
20:52:13.187 RSL: RESULT = {"WebQuery":"Done"}
20:52:13.215 RUL: WEBQUERY#DATA=DONE performs 'IF 0==0 backlog Var1 1; Power2 BlinkOff; Delay 1; Power1 1; Power2 0; Power3 1'
20:52:13.221 RSL: RESULT = {"If":"Done"}
20:52:13.244 RUL: WEBQUERY#DATA=DONE performs 'IF 0!=0 backlog Mult1 2; Power1 0; Power3 0; Delay 30; Power1 1; Power3 1 ENDIF'
20:52:13.249 RSL: RESULT = {"If":"Done"}

[sfromis]

What I said about BlinkCount was not about "forever" or not, but only that it is a persistent setting, where it does not make sense to issue the command again and again the way you do. Makes no difference. Each time you start a blink, the full value is used again.

It still counts down, where reissuing the BlinkCount command makes no sense when you are already also issuing the Power blink command to start blinking. OTOH, I think that you could extend an active blink by reissuing the BlinkCount without also issuing the Power blink command again. IIRC, BlinkCount 0 is meant as highest value, basically the same as 32000.

If what you want is "forever", you do need to restart the blinking before it counts down to zero.

You should not use the command Backlog inside if/endif, multiple commands is already the default here. But you have to stay very close to the the prescribed syntax, and remember to have () around the if condition, otherwise it won't work. Hence your logic breaks totally down. In the condition you can also just use var2 instead of %var2%.

And your BlinkTime 1 is invalid, as the docs (you should have read) says, the minimum is 2.

[peteDDD]

Thanks @sfromis Brain fade on the parens missed that... still in my first 24 hours of learning Tasmota.... and yes, I read the doc on BlinkCount but later lowered the value and forgot that limit. Thank you again. Here is what I ended up with. This is my first Tasmota project so I am very pleased and learned a lot.

in commented form:

// Var1 interval
// Var2 0 = Testing Home Assistant  1 = Testing Router

// Power1 Outlet
// Power2 Red LED
// Power3 Blue LED

Rule1
  ON system#boot DO backlog Power1 1; Power3 1; Var1 1; BlinkTime 10; BlinkCount 0; Power2 Blink; Var2 0 ENDON  // Outlet on, Blue LED on, Red LED slow flash (appears purple)
  ON Var1#State>16 DO Var1 16 ENDON  // limit interval to 16 minutes

  ON Time#Minute|%var1% DO backlog Var2 0; BlinkTime 5; Power2 Blink; WebQuery http://192.168.1.220:8123/ GET 100 ENDON // clear flags, check Home Assistant, more rapid Red LED flash (flashes purple)

  // Step 2: Handle Home Assistant result and if down, test Router
  ON WebQuery#Data=Done DO IF (%var2%==0)  Var1 1; Power2 BlinkOff; Power1 1; Power2 0; Power3 1 ENDON  // HA connected, no need to test Router
  ON WebQuery#Data$!Done DO IF (%var2%==0) Var2 1; WebQuery http://192.168.1.1/ GET 100 ENDIF ENDON // HA not connected, test Router

  // Step 3: Handle Router result 
  ON WebQuery#Data=Done DO IF (%var2%!=0) RuleTimer1 1 ENDIF ENDON  // HA down, Router Up: trigger RuleTimer 1  Use RuleTimer since we need to use backlog to sequence the delay
  ON WebQuery#Data$!Done DO IF (%var2%!=0) BlinkTime 2 // (HA Down), Router down: Flash more rapidly  (minimum BlinkTime value is 2)
  ON Rules#Timer=1 DO backlog Mult1 2; Power1 0; Power3 0; Delay 30; Power1 1; Power3 1 ENDON

In one line:
Rule1 ON system#boot DO backlog Power1 1; Power3 1; Var1 1; BlinkTime 10; BlinkCount 0; Power2 Blink; Var2 0 ENDON ON Var1#State>16 DO Var1 16 ENDON ON Time#Minute|%var1% DO backlog Var2 0; BlinkTime 5; Power2 Blink; WebQuery http://192.168.1.220:8123/ GET 100 ENDON ON WebQuery#Data=Done DO IF (%var2%==0) Var1 1; Power2 BlinkOff; Power1 1; Power2 0; Power3 1 ENDIF ENDON ON WebQuery#Data$!Done DO IF (%var2%==0) Var2 1; WebQuery http://192.168.1.1/ GET 100 ENDIF ENDON ON WebQuery#Data=Done DO IF (%var2%!=0) RuleTimer1 1 ENDIF ENDON ON WebQuery#Data$!Done DO IF (%var2%!=0) BlinkTime 2 ENDIF ENDON ON Rules#Timer=1 DO backlog Mult1 2; Power1 0; Power3 0; Delay 30; Power1 1; Power3 1 ENDON