addpkg: yes-rs

Signed-off-by: Roald Clark <roaldclark@gmail.com>

Author: roaldclark

archlinuxcn/yes-rs/PKGBUILD

@@ -0,0 +1,44 @@
+# Maintainer: Roald Clark <roaldclark@gmail.com>
+
+_name=yes-rs
+pkgname="${_name}"
+pkgver=0.1.0
+pkgrel=1
+pkgdesc="A blazingly fast, memory-safe rewrite of the classic Unix 'yes' command"
+arch=(
+    'aarch64'
+    'x86_64'
+)
+url="https://github.com/jedisct1/${_name}"
+license=(
+    'Apache-2.0'
+    'MIT'
+)
+depends=(
+    'gcc-libs'
+    'glibc'
+)
+makedepends=(
+    'cargo'
+)
+source=("${_name}-${pkgver}.tar.gz::${url}/archive/${pkgver}.tar.gz")
+b2sums=('e51509a2467ce43fa6f79dc1ab1a202f0c5e23ee252e1d14387b619c6ae5ba1ee58ad27b90071e35e6506ffdd9cee60f2f40ca4fa6564e94b6a4f74ac0656b9d')
+
+prepare() {
+    cd "${srcdir}/${_name}-${pkgver}"
+    export RUSTUP_TOOLCHAIN=stable
+    [[ ! -f "Cargo.lock" ]] && cargo update
+    cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
+}
+
+build() {
+    cd "${srcdir}/${_name}-${pkgver}"
+    export RUSTUP_TOOLCHAIN=stable
+    export CARGO_TARGET_DIR=target
+    cargo build --release --frozen --all-features
+}
+
+package() {
+    cd "${srcdir}/${_name}-${pkgver}"
+    install -Dm0755 "target/release/${_name}" -t "${pkgdir}/usr/bin/"
+}

archlinuxcn/yes-rs/lilac.yaml

@@ -0,0 +1,11 @@
+build_prefix: extra-x86_64
+pre_build_script: update_pkgver_and_pkgrel(_G.newver)
+post_build: git_pkgbuild_commit
+update_on:
+  - source: github
+    github: jedisct1/yes-rs
+    use_latest_release: true
+    include_regex: '^\d+\.\d+\.\d+$'
+
+maintainers:
+  - github: roaldclark