How do we save some APT in a Pool? (having errors)

[NaDasai]

Discord user ID

ibuidl

Describe your question in detail.

Is there a way to save some Aptos in a pool?
use aptos_framework::aptos_coin::AptosCoin;

    struct Pool has key, store {
        fees: u64,
        participants: vector<address>,
        coins : coin::Coin<AptosCoin>,
    }

Is it like this (with coin)?
Because when I do:

        let coin = coin::extract(&mut pool.coins, 1);
        move_to(account, coin);

I have no errors but when I compile I get:

error[E05001]: ability constraint not satisfied
┌─ move/sources/module.move:69:9
│
69 │ move_to(account, coin);
│ ^^^^^^^^^^^^^^^^^^^^^^ Invalid call of 'move_to'
│
┌─ /Users/nad/Aptos/aptos-core-main/aptos-move/framework/aptos-framework/sources/coin.move:120:12
│
120 │ struct Coin has store {
│ ---- To satisfy the constraint, the 'key' ability would need to be added here
·
970 │ public fun extract(coin: &mut Coin, amount: u64): Coin {
│ -------------- The type '(aptos_framework=0x1)::coin::Coin<(aptos_framework=0x1)::aptos_coin::AptosCoin>' does not have the ability 'key'

What error, if any, are you getting?

No response

What have you tried or looked at? Or how can we reproduce the error?

No response

Which operating system are you using?

macOS

Which SDK or tool are you using? (if any)

Aptos CLI

Describe your environment or tooling in detail

No response

[MoonShiesty]

you're storing the coins in the Pool resource, you first need to create the resource:

fun init() {
  move_to(account, Pool{
    fees: 0,
    participants: vector::empty(),
    coins: coin::zero<AptosCoin>()
  });
)

then you can borrow that resource and deposit coin_to_add:

fun deposit(coins_to_add: Coin<AptosCoin>) {
  let pool = borrow_global_mut<Pool>(signer::address_of(account))
  coin::merge(&mut pool.coins, coins_to_add);
}

or extract amount_to_withdraw:

fun deposit(amount_to_withdraw: u64): Coin<AptosCoin>) {
  let pool = borrow_global_mut<Pool>(signer::address_of(account))
  coin::extract(&mut pool.coins, amount_to_withdraw)
)

[NaDasai]

@MoonShiesty Right I already have that here:

fun init_module(account: &signer) {
    create_raffle_collection(account);
    // Initialize the pool with zero funds and zero earnings.
    move_to(account, Pool {
        fees: 0,
        participants: vector::empty<address>(),
        coins : coin::zero(),
    });
}

For deposit, that's not an issue since, like you did, we use merge between the pool and the coins.

The problem is in the move_to here in the withdraw. I need to get the coins from the pool and send it to a specific address.

let pool = borrow_global_mut<Pool>(@module_addr);
    let coin = coin::extract(&mut pool.coins, 1);
    move_to(account, coin);

But here I have the error above when I compile.

[MoonShiesty]

you want the final line to be:

coin::deposit(account, coin);

you can store coins in structs using Coin but the coin package also has a standardized way to deposit/withdraw coins to/from users accounts using CoinStore

move_to adds a struct to global storage. coin::deposit, deposits the coins into that account's CoinStore

[MoonShiesty]

you also might need to call coin::register if the signer hasn't already registered to receive AptosCoin. with AptosCoin this should only really be the case if the caller is not an EOA

[NaDasai]

@MoonShiesty Sorry didn't get you..

• When should I call coin::register? And why?
• What's an EOA?
  (context: It's a lottery so after the draw, I need to send the rewards to the address that was picked.)

[MoonShiesty]

When should I call coin::register? And why?

you need to call coin::register with the user as a signer the first time you deposit into a users account, aptos probably added this feature to prevent spam

aptos_account::deposit_coins will do both register and deposit as long as the user has new_allow_direct_transfers enabled. but since you already have the signature of the user you're depositing into, you can just always call coin::register before depositing and the deposit will never abort

aptos accounts automatically register users to receive aptos, but the caller could be a module which doesn't have an account, and therefore isn't registered to receive aptos

i should've written

this should only really be the case if the caller is not an EOA

in the ethereum world an EOA is an externally-owned-account (ie a wallet managed by private key) vs a CA (contract-address) where the account is managed by a smart-contract

similarly on aptos, EOAs have an Account object which automatically registers users to receive aptos (among other things)

however CA's won't necessarily have an Account and be registered to receive AptosCoin

your signer could either be a CA or EOA

[NaDasai]

@MoonShiesty Well I still have the error in compilation even if I added the register.
Here is the code maybe I missed something:

    public entry fun buy_ticket (account: &signer, coin: coin::Coin<AptosCoin>) acquires Pool {
        assert!(coin::value(&coin) == 1, ETICKET_COSTS_ONE_APT);
        coin::register<coin::Coin<AptosCoin>>(account);
        let pool = borrow_global_mut<Pool>(@module_addr);
        coin::merge(&mut pool.coins, coin);
        move_to(account, Ticket {amount : 1}); // add if exist later
        vector::push_back(&mut pool.participants, signer::address_of(account));

    }

    public entry fun repay_ticket (account: &signer) acquires Ticket, Pool {
        let ticket = borrow_global_mut<Ticket>(signer::address_of(account));
        let pool = borrow_global_mut<Pool>(@module_addr);
        let coin = coin::extract(&mut pool.coins, 1);
        move_to(account, coin);
        vector::remove_value(&mut pool.participants, &signer::address_of(account));
    }

So the issue is in move_to(account, coin); :

error[E05001]: ability constraint not satisfied
┌─ move/sources/module.move:65:9
│
65 │ move_to(account, coin);
│ ^^^^^^^^^^^^^^^^^^^^^^ Invalid call of 'move_to'
│
┌─ /Users/nadhir/Documents/Procyon/Aptos/aptos-core-main/aptos-move/framework/aptos-framework/sources/coin.move:120:12
│
120 │ struct Coin has store {
│ ---- To satisfy the constraint, the 'key' ability would need to be added here
·
970 │ public fun extract(coin: &mut Coin, amount: u64): Coin {
│ -------------- The type '(aptos_framework=0x1)::coin::Coin<(aptos_framework=0x1)::aptos_coin::AptosCoin>' does not have the ability 'key'

I don't get why it's saying that AptosCoin doesn't have the 'key' ability.

[MoonShiesty]

on aptos structs that can be stored in global storage (ie can be move_to) need the key attribute. structs that are stored as member of other structs have store attribute.

Coin doesn't have the key attribute, it has the store attribute, while CoinStore has a key attribute

register will create a CoinStore for the account which allows you to deposit Coin into it

you should call coin::deposit(account, coins) to deposit the coins, into the CoinStore in the users account

failing to call register first should only cause issues at runtime, it will compile

tbh its often easier for me to just read the source code instead of the aptos docs to see whats going on: https://github.com/aptos-labs/aptos-core/blob/main/aptos-move/framework/aptos-framework/sources/coin.move

[MoonShiesty]

i found the issue, it should be coin::register<AptosCoin>, rather than coin::register<coin::Coin<AptosCoin>>

[NaDasai]

@MoonShiesty That was the issue indeed! :) Thanks a lot!! (0x72a4be08d1d7af1e3f74ca987c36edeee353774413638ef4298629ef24d69516 if you want play around with it 👍 juste tested but_ticket for now)
(Weird how this happens even after the compilation.)

[MoonShiesty]

(Weird how this happens even after the compilation.)

indeed weird but i believe its because coin<AptosCoin> is a legitimate type just not a coin type

glad its working for you now!

[NaDasai]

Btw looks like the amount in my Wallet doesn't change (tried buy and repay ticket).
And when I try to interact with it again I can't:

[NaDasai]

Ah I see it's not that it's not changing 1 APT like I thought.. It's just changing +-0.00000001 APT. lol (at first thought that was fees).
And now I get why I can't interact again with it, it's because I didn't delete Ticket and I didn't handle yet the fact that we can have a Ticket when we buy again.
All good!