How to create multiple coins?

[0x-j]

Asked by ranahardik on discord dev-discussion

i want to create multiple coin from one structure is this possible if it's not so how we can do this ?

like i have one structure for coin once we create coin and use that structure for initialize that so can't use that structure because thats already on recourse account so what we do in this situation ?

    struct Bitcoin {}
    
    struct StoreCap has key{
        mint_capability:MintCapability<Bitcoin>,
        burn_capability:BurnCapability<Bitcoin>,
        freeze_capability:FreezeCapability<Bitcoin>,
        // resource_signer_cap:account::SignerCapability
    }

    public entry fun create_coin(owner:&signer){
        let (burn_cap,freeze_cap,mint_cap) = coin::initialize<Bitcoin>(owner,string::utf8(b"Bitcoin"),string::utf8(b"BTC"),8,false);
        move_to(owner,StoreCap{mint_capability:mint_cap, burn_capability:burn_cap,freeze_capability:freeze_cap});
        // coin::register<Bitcoin>(owner);
    }

so here when we create token first time it will already move Bitcoin structure in to resource account now if i want to create another coin so we can do this ?

[0x-j]

You are right each account can only hold one instance of a resource of the same type. You need to create a new resource for every coin you create. You can also use object instead of resource account. Object is a successor to resource account.

[MD-RanaHardik]

Do you have any reference that creates coins using this method?

[0x-j]

Calling @gregnazario for help, when i run the unit test in below, it triggers ECOIN_INFO_ADDRESS_MISMATCH, description is

Address of account which is used to initialize a coin `CoinType` doesn't match the deployer of module

The only way initialize can work is I call it with deployer account and pass deployer signer. I don't understand why we have this restriction, how do we support apps like launchpad where we need one contract as the entry point for people to create coin?

module playgrouund_addr::coin_playground {
    use std::string;
    use aptos_framework::account;
    use aptos_framework::coin;

    struct TestCoin has key {}

    struct CoinCap has key {
        mint_capability: coin::MintCapability<TestCoin>,
        burn_capability: coin::BurnCapability<TestCoin>,
        freeze_capability: coin::FreezeCapability<TestCoin>,
    }

    public entry fun create_coin(sender: &signer) {
        let (resource_signer, _signer_cap) = account::create_resource_account(sender, b"token_account");
        let (burn_cap, freeze_cap, mint_cap) = coin::initialize<TestCoin>(
            &resource_signer,
            string::utf8(b"Test"),
            string::utf8(b"symbol"),
            8,
            true
        );

        move_to(
            &resource_signer,
            CoinCap {
                burn_capability: burn_cap,
                freeze_capability: freeze_cap,
                mint_capability: mint_cap
            }
        );
    }

    #[test(sender = @playgrouund_addr, user1 = @0x100, user2 = @0x101)]
    fun test_happy_path(sender: &signer, user1: &signer, user2: &signer) {
        // this will trigger ECOIN_INFO_ADDRESS_MISMATCH in 0x1::coin
        create_coin(sender);
    }
}

[gregnazario]

Only the publisher of the struct can create a coin with that struct, and they can only do so once.

To create multiple coins, deploy more structs and use the publisher's account to create the coins

[gregnazario]

In test cases you have to use the test coin functions

[0x-j]

To create multiple coins, deploy more structs and use the publisher's account to create the coins

I don't really understand this part, I have to upgrade the module (so i can add new struct) to create new coin?

Also, is this only the case for coin? I'm looking at this fungible asset example, it seems like i can move the logic inside initialize to a function called create_new_fa and use a counter as seed , then I can keep calling it to create new FAs? This would do what I expected.

[0x-j]

Here's my modified version and it works fine, I can call create_fa as many times as i want.

    fun init_module(sender: &signer) {
        move_to(sender, Counter { count: 0 })
    }
    
    public entry fun create_fa(sender: &signer) acquires Counter {
        let counter = borrow_global_mut<Counter>(@playgrouund_addr);
        let symbol = to_bytes(&string_utils::format2(&b"{}_{}", ASSET_SYMBOL, counter.count));
        let constructor_ref = &object::create_named_object(sender, symbol);
        managed_fungible_asset::initialize(
            constructor_ref,
            0, /* maximum_supply. 0 means no maximum */
            utf8(b"You only live once"), /* name */
            utf8(symbol), /* symbol */
            8, /* decimals */
            utf8(b"http://example.com/favicon.ico"), /* icon */
            utf8(b"http://example.com"), /* project */
            vector[true, true, true], /* mint_ref, transfer_ref, burn_ref */
        );
        counter.count = counter.count + 1;
    }

[MD-RanaHardik]

did this work as a normal coin? if yes so how we can see this coin in to patra wallet