Different echo?... variants

[andry81]

Here is different echo?... variants to call with pros and cons from a script.

Note

The following results may vary behind other aspects like:

• Where you run the code, from the console or from a script.
• What extensions or replacements are installed or enabled to the cmd.exe, like clink, TCC, etc.
• Accessibility of the current directory.
• The PATH variable existence or it's altered (not default) value.

Note

The cmd.exe may skip query a path from the PATH variable if it begins by the %SystemRoot% as a raw prefix. So you have to alter the PATH variable to trigger the cmd.exe query logic.

Note

To reset the environment variables to a default state you can use reset-env.bat script.

Note

To trigger the cmd.exe to query the PATH variable you can evaluate the PATH variable: call set PATH=%PATH%

echo <text> or echo<tab><text>

Pros:

• Documented way of usage (with space).
• Auto completion works in case of type in a console window.
• Does not query PATH variable or current directory to open the echo <text> file.

Cons:

• <text> must be not empty, otherwise ECHO is on. will be printed. So it can not print empty string.
• <text> must not start by /?, otherwise the usage help will be printed.

echo;<text> or echo,<text> or echo=<text>

Note

The ;, ,, = characters treated as separator characters and replaced by a space character in a batch script command line.

Pros:

• Can print empty string.
• Auto completion works in case of type in a console window.
• Does not query PATH variable or current directory to open the echo <text> file.

Cons:

• <text> must not start by /?, otherwise the usage help will be printed.

echo.<text>

Pros:

• Can print empty string.
• Prints /? as is.

Cons:

• Queries current directory and PATH (including PATHEXT) variable to open the echo.<text> file.
• Can not handle delayed variable expansion with value substitution: `echo` value delayed expansion #8
• Suppresses auto completion in case of type in a console window.
• Slower than others. See bench tests.

echo:<text>

Pros:

• Can print empty string.
• Prints /? as is.
• Does not query PATH variable to open the echo:<text> file.

Cons:

• Tries to open echo:<text> file (does not exist).
• Suppresses auto completion in case of type in a console window.
• Still slower than others. See bench tests.

echo/<text>

Pros:

• Can print empty string.
• Prints /? as is.
• Auto completion works in case of type in a console window.
• Does not query current directory or PATH variable to open the echo/<text> file (not a valid file or path).

Cons:

• <text> must not start by ?, otherwise the usage help will be printed.

echo\<text>

Pros:

• Can print empty string.
• Prints /? as is.
• Auto completion works in case of type in a console window.
• Does not query PATH variable to open the echo\<text> file.

Cons:

• Tries to query and open echo\<text> path (can exist), but does nothing.
• Most slowest. See bench tests.

echo+<text>

Pros:

• Can print empty string.
• Prints /? as is.
• Auto completion works in case of type in a console window.

Cons:

• Queries current directory and PATH (including PATHEXT) variable to open the echo+<text> file.

echo(<text>

Pros:

• Can print empty string.
• Prints /? as is.
• Auto completion works in case of type in a console window.
• Does not query current directory or PATH variable to open the echo(<text> file.

Cons:

• Does not evaluate in for variable context. See issues.

Bench tests:

https://github.com/andry81/contools/tree/HEAD/Scripts/Tests/bench/batscripts

>test__echo__01_space.bat
Time spent: 0.020 msecs

>test__echo__02_semicolon.bat
Time spent: 0.020 msecs

>test__echo__03_period.bat
Time spent: 0.035 msecs

>test__echo__04_colon.bat
Time spent: 0.036 msecs

>test__echo__05_slash.bat
Time spent: 0.022 msecs

>test__echo__06_backslash.bat
Time spent: 0.038 msecs

>test__echo__07_plus.bat
Time spent: 0.020 msecs

>test__echo__08_parenthesis.bat
Time spent: 0.020 msecs

Issues:

echo( does not evaluate in for variable context:

@echo off

setlocal DISABLEDELAYEDEXPANSION

for %%i in ("echo " "echo 	" "echo;" "echo," "echo=" "echo." "echo:" "echo/" "echo\" "echo+" "echo(" ) do (echo ^>%%~i) & %%~i

Result:

>echo
ECHO is off.
>echo
ECHO is off.
>echo;

>echo,

>echo=

>echo.

>echo:

>echo/

>echo\

>echo+

>echo(
'echo(' is not recognized as an internal or external command,
operable program or batch file.

[A-Mofi]

That is an excellent summary of the Windows command echo and which character to use as separator between the command and the text to output.

There could be added to section echo;<text> or echo,<text> or echo=<text> that echo <text> with an OEM encoded no-break space with decimal code point value 255 between the command echo and the text to output would result in same behavior as with using a semicolon, comma or equal sign as separator but only if the active code page is an OEM code page like OEM 437 or OEM 850. There should be never used an OEM encoded no-break space in a batch file for that reason as separator between the command echo and the text to output.

Interesting is the behavior of echo\<text> which is not only the slowest but can result in running an executable or script instead of the output of text.

Example: A batch file named EchoTest.cmd contains the following two lines:

@echo\test.cmd text
@echo\/?

There is in the current working directory a subdirectory with the name echo which has a batch file with the name test.cmd with the following single command line:

@echo Arguments: %*

The execution of EchoTest.cmd in a command prompt window in the directory with the subdirectory echo with the batch file test.cmd results in the output of Arguments: text instead of test.cmd text and the next command line @echo\/? in EchoTest.cmd is not executed anymore because of cmd.exe finished the batch file processing with the last line of echo\test.cmd because of this batch file is not called with the command call.

Conclusion: There should never be used \ or . as delimiter between the command echo and the text to output.