Make CMake install files relocatable (#77)

Author: an-tao

CMakeLists.txt

@@ -1,9 +1,8 @@
 cmake_minimum_required(VERSION 3.5)
 project(trantor)
 add_library(${PROJECT_NAME} STATIC)
-# if(MSVC) target_compile_options(${PROJECT_NAME} PRIVATE /W4 /WX) else()
-# target_compile_options(${PROJECT_NAME} PRIVATE -Wall -Wextra -pedantic)
-# endif()
+
+set(CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake_modules/)
 
 set(TRANTOR_MAJOR_VERSION 1)
 set(TRANTOR_MINOR_VERSION 0)
@@ -21,17 +20,6 @@ set(INSTALL_TRANTOR_CMAKE_DIR
     ${DEF_INSTALL_TRANTOR_CMAKE_DIR}
     CACHE PATH "Installation directory for cmake files")
 
-# Make relative paths absolute (needed later on)
-foreach(p
-        LIB
-        INCLUDE
-        TRANTOR_CMAKE)
-  set(var INSTALL_${p}_DIR)
-  if(NOT IS_ABSOLUTE "${${var}}")
-    set(${var} "${CMAKE_INSTALL_PREFIX}/${${var}}")
-  endif()
-endforeach()
-
 # include directories
 target_include_directories(
   ${PROJECT_NAME}
@@ -76,16 +64,14 @@ endif(WIN32)
 
 find_package(OpenSSL)
 if(OpenSSL_FOUND)
-  target_include_directories(${PROJECT_NAME} PRIVATE ${OPENSSL_INCLUDE_DIR})
-  target_link_libraries(${PROJECT_NAME} PRIVATE ${OPENSSL_LIBRARIES})
-  add_definitions(-DUSE_OPENSSL)
+  target_link_libraries(${PROJECT_NAME} PRIVATE OpenSSL::SSL OpenSSL::Crypto)
+  target_compile_definitions(${PROJECT_NAME} PRIVATE USE_OPENSSL)
 endif()
 
-find_path(CARES_INCLUDE_DIR ares.h)
-find_library(CARES_LIBRARY NAMES cares)
-if(CARES_INCLUDE_DIR AND CARES_LIBRARY)
-  target_include_directories(${PROJECT_NAME} PRIVATE ${CARES_INCLUDE_DIR})
-  target_link_libraries(${PROJECT_NAME} PRIVATE ${CARES_LIBRARY})
+find_package(c-ares)
+if(c-ares_FOUND)
+  message(STATUS "c-ares found!")
+  target_link_libraries(${PROJECT_NAME} PRIVATE c-ares_lib)
   set(TRANTOR_SOURCES ${TRANTOR_SOURCES} trantor/net/inner/AresResolver.cc)
 else()
   set(TRANTOR_SOURCES ${TRANTOR_SOURCES} trantor/net/inner/NormalResolver.cc)
@@ -172,6 +158,7 @@ install(
   FILES
     "${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/TrantorConfig.cmake"
     "${CMAKE_CURRENT_BINARY_DIR}/TrantorConfigVersion.cmake"
+    "${CMAKE_CURRENT_SOURCE_DIR}/cmake_modules/Findc-ares.cmake"
   DESTINATION "${INSTALL_TRANTOR_CMAKE_DIR}"
   COMPONENT dev)
 

cmake/templates/TrantorConfig.cmake.in

@@ -8,6 +8,14 @@
 
 @PACKAGE_INIT@
 
+include(CMakeFindDependencyMacro)
+list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_LIST_DIR})
+if(@OpenSSL_FOUND@)
+  find_dependency(OpenSSL)
+endif()
+if(@c-ares_FOUND@)
+  find_dependency(c-ares)
+endif()
 # Compute paths
 
 # Our library dependencies (contains definitions for IMPORTED targets)
@@ -17,4 +25,4 @@ if(NOT TARGET Trantor::Trantor)
 endif()
 
 get_target_property(TRANTOR_INCLUDE_DIRS Trantor::Trantor INTERFACE_INCLUDE_DIRECTORIES)
-set(TRANTOR_LIBRARIES Trantor::Trantor)
+set(TRANTOR_LIBRARIES Trantor::Trantor)

cmake_modules/Findc-ares.cmake

@@ -0,0 +1,27 @@
+# Try to find c-ares library Once done this will define
+#
+# c-ares_FOUND - system has c-ares 
+# C-ARES_INCLUDE_DIRS - The c-ares include directory 
+# C-ARES_LIBRARIES - Link these to use c-ares
+# c-ares_lib - Imported Targets
+#
+# Copyright (c) 2020 antao <antao2002@gmail.com>
+#
+
+find_path(C-ARES_INCLUDE_DIRS ares.h)
+find_library(C-ARES_LIBRARIES NAMES cares)
+if(C-ARES_INCLUDE_DIRS AND C-ARES_LIBRARIES)
+  add_library(c-ares_lib INTERFACE IMPORTED)
+  set_target_properties(c-ares_lib
+                        PROPERTIES INTERFACE_INCLUDE_DIRECTORIES
+                                   "${C-ARES_INCLUDE_DIRS}"
+                                   INTERFACE_LINK_LIBRARIES
+                                   "${C-ARES_LIBRARIES}")
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(c-ares
+                                  DEFAULT_MSG
+                                  C-ARES_INCLUDE_DIRS
+                                  C-ARES_LIBRARIES)
+mark_as_advanced(C-ARES_INCLUDE_DIRS C-ARES_LIBRARIES)