Merge pull request #70 from adafruit/io-garage

Adding IO:Garage example

Author: brentru

examples/io_home_series/io_garage/config.h

@@ -0,0 +1,44 @@
+/************************ Adafruit IO Config *******************************/
+
+// visit io.adafruit.com if you need to create an account,
+// or if you need your Adafruit IO key.
+#define IO_USERNAME    "YOUR_AIO_USERNAME"
+#define IO_KEY         "YOUR_AIO_KEY"
+
+/******************************* WIFI **************************************/
+
+// the AdafruitIO_WiFi client will work with the following boards:
+//   - HUZZAH ESP8266 Breakout -> https://www.adafruit.com/products/2471
+//   - Feather HUZZAH ESP8266 -> https://www.adafruit.com/products/2821
+//   - Feather HUZZAH ESP32 -> https://www.adafruit.com/product/3405
+//   - Feather M0 WiFi -> https://www.adafruit.com/products/3010
+//   - Feather WICED -> https://www.adafruit.com/products/3056
+
+#define WIFI_SSID       "YOUR_WIFI_SSID"
+#define WIFI_PASS       "YOUR_WIFI_PASSWORD"
+
+// comment out the following two lines if you are using fona or ethernet
+#include "AdafruitIO_WiFi.h"
+AdafruitIO_WiFi io(IO_USERNAME, IO_KEY, WIFI_SSID, WIFI_PASS);
+
+
+/******************************* FONA **************************************/
+
+// the AdafruitIO_FONA client will work with the following boards:
+//   - Feather 32u4 FONA -> https://www.adafruit.com/product/3027
+
+// uncomment the following two lines for 32u4 FONA,
+// and comment out the AdafruitIO_WiFi client in the WIFI section
+// #include "AdafruitIO_FONA.h"
+// AdafruitIO_FONA io(IO_USERNAME, IO_KEY);
+
+
+/**************************** ETHERNET ************************************/
+
+// the AdafruitIO_Ethernet client will work with the following boards:
+//   - Ethernet FeatherWing -> https://www.adafruit.com/products/3201
+
+// uncomment the following two lines for ethernet,
+// and comment out the AdafruitIO_WiFi client in the WIFI section
+// #include "AdafruitIO_Ethernet.h"
+// AdafruitIO_Ethernet io(IO_USERNAME, IO_KEY);

examples/io_home_series/io_garage/io_garage.ino

@@ -0,0 +1,128 @@
+// Adafruit IO Garage
+// Tutorial Link: https://learn.adafruit.com/adafruit-io-home-garage
+//
+// Adafruit invests time and resources providing this open source code.
+// Please support Adafruit and open source hardware by purchasing
+// products from Adafruit!
+//
+// Written by Brent Rubell for Adafruit Industries
+// Copyright (c) 2018 Adafruit Industries
+// Licensed under the MIT license.
+//
+// All text above must be included in any redistribution.
+
+/************************** Configuration ***********************************/
+
+// edit the config.h tab and enter your Adafruit IO credentials
+// and any additional configuration needed for WiFi, cellular,
+// or ethernet clients.
+#include "config.h"
+
+// include the servo library
+#include <Servo.h> 
+
+// include the ultrasonic library 
+#include <Ultrasonic.h>
+
+/************************ Example Starts Here *******************************/
+
+#define SERVOPIN        15
+#define DOORPIN          0
+
+// servo (garage door opener) angle presets
+#define DOORCLOSE_POS   30
+#define DOOROPEN_POS   130
+
+// sketch starts assuming the the door is closed
+int doorState = LOW;
+
+// ultrasonic sensor distance
+int ultrasonicRead;
+
+// set up the ultrasonic object (trigger, echo)
+Ultrasonic ultrasonic(12, 13);
+// create servo object
+Servo doorServo;
+
+// set up the Adafruit IO Feeds
+AdafruitIO_Feed *openGarage_feed = io.feed("garage-opener");
+AdafruitIO_Feed *closeGarage_feed = io.feed("garage-closer");
+AdafruitIO_Feed *carDistance_feed = io.feed("carDistance");
+AdafruitIO_Feed *doorStatus_feed = io.feed("doorStatus");
+
+void setup() {
+
+  // start the serial connection
+  Serial.begin(115200);
+
+  // wait for serial monitor to open
+  while(! Serial);
+
+  // connect to io.adafruit.com
+  Serial.print("Connecting to Adafruit IO");
+  io.connect();
+
+  // set up message handlers
+  openGarage_feed->onMessage(handleGarageOpener);
+  closeGarage_feed->onMessage(handleGarageCloser);
+
+
+  // wait for a connection
+  while(io.status() < AIO_CONNECTED) {
+    Serial.print(".");
+    delay(500);
+  }
+
+  // we are connected
+  Serial.println();
+  Serial.println(io.statusText());
+
+  // attach the servo object to pin 16
+  doorServo.attach(SERVOPIN);
+  // start with the door closed
+  doorServo.write(DOORCLOSE_POS);
+}
+
+void loop() {
+  // io.run(); is required for all sketches.
+  // it should always be present at the top of your loop
+  // function. it keeps the client connected to
+  // io.adafruit.com, and processes any incoming data.
+  io.run();
+  
+  // read the door sensor
+  readDoorSensor();
+  
+  // read the ultrasonic sensor
+  ultrasonicRead = ultrasonic.distanceRead(INC);
+  delay(1000);
+  Serial.print("Distance from car (inches):"); Serial.println(ultrasonicRead);
+  carDistance_feed->save(ultrasonicRead);
+}
+
+// reads the status of the garage door and sends to adafruit io
+void readDoorSensor() {
+  doorState = digitalRead(DOORPIN);
+  if (doorState == LOW) {
+    Serial.println("* Door Closed");
+    doorStatus_feed->save(0);
+  } else {
+    Serial.println("* Door Open");
+    doorStatus_feed->save(1);
+  }
+  delay(2000);
+}
+
+// 'open garage' button handler
+void handleGarageOpener(AdafruitIO_Data *data) {
+    Serial.println("Door Opened!");
+    doorServo.write(DOOROPEN_POS);
+}
+
+// 'close garage' button handler
+void handleGarageCloser(AdafruitIO_Data *data) {
+     Serial.println("Door Closed!");
+    doorServo.write(DOORCLOSE_POS);
+}
+
+