How Can I Retrieve Tender Value and Deadline from the TED SPARQL Endpoint?

[collinstechwrite]

Hello can anyone help?

I'm working with the TED (Tenders Electronic Daily) SPARQL endpoint (https://publications.europa.eu/webapi/rdf/sparql) to extract public procurement tender information. I have the following query based on a keyword. My query successfully returns fields like publication number, legal name, publication date, title, and description.

I have been searching for online resources for SPARQL queries but I am unable to find the fields for tender value or tender deadline data.

PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX epo: <http://data.europa.eu/a4g/ontology#>
PREFIX cccev: <http://data.europa.eu/m8g/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

SELECT DISTINCT ?publicationNumber ?legalName ?publicationDate ?title ?description
WHERE {
  GRAPH ?g {
    ?notice a epo:Notice ;
            epo:hasPublicationDate ?publicationDate ;
            epo:hasNoticePublicationNumber ?publicationNumber ;
            epo:announcesRole [
                a epo:Buyer ;
                epo:playedBy [
                    epo:hasLegalName ?legalName ;
                    cccev:registeredAddress [
                        epo:hasCountryCode ?countryUri
                    ]
                ]
            ] ;
            epo:refersToProcedure [
                dcterms:title ?title ;
                dcterms:description ?description
            ] .
  }
  ?countryUri skos:prefLabel "Ireland"@en .
  FILTER (
    CONTAINS(LCASE(STR(?title)), "construction") ||
    CONTAINS(LCASE(STR(?description)), "construction")
  )
}
ORDER BY ?publicationDate

Is there a source that has all the fields available for TED Tenders?

https://stackoverflow.com/questions/79412195/how-can-i-retrieve-tender-value-and-deadline-from-the-ted-sparql-endpoint

I'd consider other solutions outside of SPARQL that I can run.

[collinstechwrite]

[cristianvasquez]

Hello @collinstechwrite, I understand you're looking for information on the tender value and deadlines, but which ones?

If you're interested in querying awarded amounts for specific lots, you can refer to this example query: https://docs.ted.europa.eu/ODS/latest/samples/query-3.html

Regarding available fields:

Most fields related to epo:Tender are defined in the SHACL shapes, which serve as the schema for the data model.

Additionally, you can explore the following resources for further context:

• Conceptual Model: This includes UML diagrams illustrating the relationships between entities like epo:Tender and other related concepts
• ePO Glossary: A glossary that defines terms used within the TED data model

For example, here’s how epo:Tender relations are represented in ePO v4.0:

I hope this helps, if you have any more questions or need further help, don't hesitate.

[collinstechwrite]

Thank you @cristianvasquez I was looking to add

Deadline Date - which I see on an XML download is called TenderSubmissionDeadlinePeriod
Value - which I see on an XML download is called RequestedTenderTotal

In an XML file I would find the submission deadline date here

cac:TenderSubmissionDeadlinePeriod
cbc:EndDate2024-10-17+01:00</cbc:EndDate>
cbc:EndTime14:00:00+01:00</cbc:EndTime>
</cac:TenderSubmissionDeadlinePeriod>

this is what is need for Value

cac:RequestedTenderTotal
<cbc:EstimatedOverallContractAmount currencyID="EUR">0</cbc:EstimatedOverallContractAmount>
</cac:RequestedTenderTotal>

I can do a work around using downloaded xml files from https://ted.europa.eu/

But would really love to export those values using SPARQL and incorporate into my query below

PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX epo: <http://data.europa.eu/a4g/ontology#>
PREFIX cccev: <http://data.europa.eu/m8g/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

SELECT DISTINCT ?publicationNumber ?legalName ?publicationDate ?title ?description
WHERE {
  GRAPH ?g {
    ?notice a epo:Notice ;
            epo:hasPublicationDate ?publicationDate ;
            epo:hasNoticePublicationNumber ?publicationNumber ;
            epo:announcesRole [
                a epo:Buyer ;
                epo:playedBy [
                    epo:hasLegalName ?legalName ;
                    cccev:registeredAddress [
                        epo:hasCountryCode ?countryUri
                    ]
                ]
            ] ;
            epo:refersToProcedure [
                dcterms:title ?title ;
                dcterms:description ?description
            ] .
  }
  ?countryUri skos:prefLabel "Ireland"@en .
  FILTER (
    CONTAINS(LCASE(STR(?title)), "construction") ||
    CONTAINS(LCASE(STR(?description)), "construction")
  )
}
ORDER BY ?publicationDate

I think it is a fairly basic thing any company would like to have, is know value and deadline date for exported tenders.

Hopefully you can help?

[collinstechwrite]

@cristianvasquez Thank you very much for your answer above, it is very detailed, it will take me a bit of time to go through the schema. I really appreciate your efforts.

[leobroom]

Hey,

I have the same issues as @collinstechwrite (I am looking for a way to automate filtering TED notices with the help of Sparql Queries.)

I was able to retrieve the tender value but not the tender deadline. I tried to follow the document you provided, @cristianvasquez - thank you”

My query:

`
PREFIX dc: http://purl.org/dc/elements/1.1/
PREFIX epo: http://data.europa.eu/a4g/ontology#
PREFIX cccev: http://data.europa.eu/m8g/
PREFIX org: http://www.w3.org/ns/org#
PREFIX xsd: http://www.w3.org/2001/XMLSchema#
PREFIX skos: http://www.w3.org/2004/02/skos/core#
PREFIX dcterms: http://purl.org/dc/terms/

SELECT DISTINCT ?publicationDate ?publicationNumber ?legalName ?procedureType ?country ?mainClassification ?estimatedValue ?currency ?title ?description
WHERE {
  FILTER (?publicationDate = "2024-04-05"^^xsd:date)
  FILTER (?formType = <http://publications.europa.eu/resource/authority/form-type/competition>)

   GRAPH ?g 
  {
    ?notice
        epo:hasPublicationDate ?publicationDate ;
        epo:refersToProcedure 
        [
          dcterms:title ?title ;
          dcterms:description ?description;

          epo:hasPurpose 
          [
            epo:hasMainClassification ?mainClassification
          ];
          epo:hasProcedureType ?procedureTypeUri ;
          epo:hasEstimatedValue  
          [
            epo:hasAmountValue ?estimatedValue ;
            epo:hasCurrency ?currency;
          ];
          a epo:Procedure
        ] ;
        epo:hasNoticePublicationNumber ?publicationNumber ;
        epo:hasFormType ?formType ;
        epo:announcesRole 
        [
            a epo:Buyer ;
            epo:playedBy 
            [
                epo:hasLegalName ?legalName ;
                cccev:registeredAddress 
                [
                    epo:hasCountryCode ?countryUri
                ]
            ]
        ]     
    }

    ?procedureTypeUri a skos:Concept ;
        skos:prefLabel ?procedureType.
    FILTER (lang(?procedureType) = "en")
  
    # Ensure currency is EUR
    #FILTER(?currency = <http://publications.europa.eu/resource/authority/currency/EUR>)

    # Ensure only the specific CPV codes are included
    FILTER (?mainClassification IN (
      <http://data.europa.eu/cpv/cpv/71000000>))

    ?countryUri dc:identifier ?country.
} LIMIT 20

`
As @collinstechwrite stated similarly, from a user perspective I started to check a random downloaded xml.

For example: https://ted.europa.eu/en/notice/-/detail/109199-2025

The structure of the notice of the website is:

• Notice:
• 5. Lot
• 5.1.12. Terms of procurement
• Deadline for receipt of tenders: 25/03/2025 12:00:00 (UTC+1)

From the downloaded xml i can find the part here:

<ContractNotice>
<cac:ProcurementProjectLot>
	<cac:TenderingProcess>
    	<cac:TenderSubmissionDeadlinePeriod>
        	<cbc:EndDate>2025-03-25+01:00</cbc:EndDate>
        	<cbc:EndTime>12:00:00+01:00</cbc:EndTime>
    	</cac:TenderSubmissionDeadlinePeriod>
	</cac:TenderingProcess>
</cac:ProcurementProjectLot>
</ContractNotice>

In the conceptual Datamodel of the eProcurementontology: i found this:

https://eprocurementontology.github.io/#procurement-terms

From the Model glossary i just found this property:

The conceptual datamodel, the glossary and the xml structure - all using slightly different names. That the tendering process can be part of a notice or of a projectLot is also confusing.

So how do I query for a tender submission deadline from ted notices?

I tried novicely to add variants like this one, which is obviously wrong:
epo:SubmissionTerm [ epo:hasReceiptDeadline ?deadline; ];

I think I am misunderstanding here something fundamental about the Public Procurement Ontology in combination with sparql. Especially about the relationship between entities and sparql queries
If there are good papers/document to the topic, please let me know. Information are plenty out there but I really do not know how to continue in this regard.

I am thankful for every comment.

Greetings,
Leon

[cristianvasquez]

Hello @collinstechwrite

It appears that the property epo:hasReceiptDeadline was superseded by epo:hasReceiptTenderDeadline

For a more up-to-date glossary, you can refer to:
https://docs.ted.europa.eu/EPO/latest/glossaries.html

To retrieve the deadlines for all notices published on 2024-11-06, I ran the following query:

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX epo: <http://data.europa.eu/a4g/ontology#>
PREFIX cdm: <http://publications.europa.eu/ontology/cdm#>

SELECT DISTINCT *
WHERE {
  GRAPH ?noticeNamedGraph {
    
    ?notice epo:hasPublicationDate ?publicationDate .
    
    ?submissionTerm a epo:SubmissionTerm ;
        epo:hasReceiptTenderDeadline ?deadline ;
        epo:hasSubmissionURL ?submissionUrl 
  }
  FILTER ( ?publicationDate = "2024-11-06"^^xsd:date)

} 
LIMIT 100

It will grab all the submission terms referenced in the notices.

I hope this helps

Cristian