add opencv as external dependency to mitk diffusion

Author: peterneher

CMake/BuildConfigurations/DiffusionRelease.cmake

@@ -1,2 +1,2 @@
-include(${CMAKE_CURRENT_LIST_DIR}/DiffusionAll.cmake)
+include(${CMAKE_CURRENT_LIST_DIR}/DiffusionDebug.cmake)
 include(${CMAKE_CURRENT_LIST_DIR}/set_release.txt)

CMake/PackageDepends/MITK_OpenCV_Config.cmake

@@ -0,0 +1,26 @@
+foreach(opencv_module ${OpenCV_REQUIRED_COMPONENTS_BY_MODULE})
+  if(NOT opencv_module MATCHES "^opencv_")
+    set(opencv_module "opencv_${opencv_module}")
+  endif()
+  list(APPEND _opencv_required_components_by_module ${opencv_module})
+endforeach()
+
+find_package(OpenCV COMPONENTS ${_opencv_required_components_by_module} REQUIRED)
+
+foreach(opencv_module ${_opencv_required_components_by_module})
+  list(APPEND ALL_LIBRARIES ${opencv_module})
+endforeach()
+
+if(WIN32)
+  if (EXISTS ${OpenCV_LIB_PATH})
+    list(APPEND opencv_path "${OpenCV_LIB_PATH}/../bin") # OpenCV is built in superbuild
+  else()
+    list(APPEND opencv_path "${OpenCV_DIR}/bin") # External OpenCV build is used
+  endif()
+
+  get_property(library_search_paths GLOBAL PROPERTY MITK_ADDITIONAL_LIBRARY_SEARCH_PATHS)
+
+  if(NOT opencv_path IN_LIST library_search_paths)
+    set_property(GLOBAL APPEND PROPERTY MITK_ADDITIONAL_LIBRARY_SEARCH_PATHS "${opencv_path}")
+  endif()
+endif()

CMakeExternals/ExternalProjectList.cmake

@@ -0,0 +1 @@
+mitkFunctionAddExternalProject(NAME OpenCV ON)

CMakeExternals/OpenCV.cmake

@@ -0,0 +1,71 @@
+#-----------------------------------------------------------------------------
+# OpenCV
+#-----------------------------------------------------------------------------
+if(MITK_USE_OpenCV)
+
+  # Sanity checks
+  if(DEFINED OpenCV_DIR AND NOT EXISTS ${OpenCV_DIR})
+    message(FATAL_ERROR "OpenCV_DIR variable is defined but corresponds to non-existing directory")
+  endif()
+
+  set(proj OpenCV)
+  set(proj_DEPENDENCIES)
+  set(OpenCV_DEPENDS ${proj})
+
+  if(NOT DEFINED OpenCV_DIR)
+
+    set(additional_cmake_args)
+
+    if(CTEST_USE_LAUNCHERS)
+      list(APPEND additional_cmake_args
+        "-DCMAKE_PROJECT_${proj}_INCLUDE:FILEPATH=${CMAKE_ROOT}/Modules/CTestUseLaunchers.cmake"
+      )
+    endif()
+
+    mitk_query_custom_ep_vars()
+
+    ExternalProject_Add(${proj}
+      GIT_REPOSITORY https://github.com/opencv/opencv.git
+      GIT_TAG dad8af6b17f8e60d7b95a1203a1b4d22f56574cf # 4.9.0 (2023-12-27)
+      LIST_SEPARATOR ${sep}
+      CMAKE_GENERATOR ${gen}
+      CMAKE_GENERATOR_PLATFORM ${gen_platform}
+      CMAKE_ARGS
+        ${ep_common_args}
+        -DBUILD_JAVA:BOOL=OFF
+        -DBUILD_opencv_ts:BOOL=OFF
+        -DBUILD_PERF_TESTS:BOOL=OFF
+        -DBUILD_opencv_python3:BOOL=OFF
+        -DBUILD_opencv_python_bindings_generator:BOOL=OFF
+        -DBUILD_opencv_python_tests:BOOL=OFF
+        -DWITH_QT:BOOL=OFF
+        -DBUILD_TESTS:BOOL=OFF
+        -DBUILD_DOCS:BOOL=OFF
+        -DBUILD_EXAMPLES:BOOL=OFF
+        -DOPENCV_PYTHON_SKIP_DETECTION:BOOL=ON
+        -DWITH_CUDA:BOOL=OFF
+        -DWITH_VTK:BOOL=OFF
+        -DWITH_IPP:BOOL=OFF
+        -DBUILD_IPP_IW:BOOL=OFF
+        -DENABLE_PRECOMPILED_HEADERS:BOOL=OFF
+        ${additional_cmake_args}
+        ${${proj}_CUSTOM_CMAKE_ARGS}
+      CMAKE_CACHE_ARGS
+        ${ep_common_cache_args}
+        ${${proj}_CUSTOM_CMAKE_CACHE_ARGS}
+      CMAKE_CACHE_DEFAULT_ARGS
+        ${ep_common_cache_default_args}
+        ${${proj}_CUSTOM_CMAKE_CACHE_DEFAULT_ARGS}
+      DEPENDS ${proj_DEPENDENCIES}
+      )
+
+    set(OpenCV_DIR ${ep_prefix})
+    mitkFunctionInstallExternalCMakeProject(${proj})
+
+  else()
+
+    mitkMacroEmptyExternalProject(${proj} "${proj_DEPENDENCIES}")
+
+  endif()
+
+endif()