Add manage_shards to interactively remove compiler shards (#303)

* Add `manage_shards` to interactively remove compiler shards

* Add total size output

* Apply suggestions from code review

Co-authored-by: Mosè Giordano <giordano@users.noreply.github.com>

* isfile -> !isdir

* Make `isless` for shards a local function

---------

Co-authored-by: Mosè Giordano <giordano@users.noreply.github.com>

Author: sloede

Project.toml

@@ -19,7 +19,9 @@ Logging = "56ddb016-857b-54e1-b83d-db4d58db5568"
 OrderedCollections = "bac558e1-5e72-5ebc-8fee-abe8a469f55d"
 OutputCollectors = "6c11c7d4-943b-4e2b-80de-f2cfc2930a8c"
 Pkg = "44cfe95a-1eb2-52ea-b672-e2afdf69b78f"
+Printf = "de0858da-6303-5e67-8744-51eddeeeb8d7"
 ProgressMeter = "92933f4c-e287-5a05-a399-4b506db050ca"
+REPL = "3fa0cd96-eef1-5676-8a61-b3b8758bbffb"
 Random = "9a3f8284-a2c9-5f02-9a11-845980a1fd5c"
 SHA = "ea8e919c-243c-51af-8825-aaa63cd721ce"
 Scratch = "6c6a2e73-6563-6170-7368-637461726353"

src/BinaryBuilderBase.jl

@@ -22,7 +22,8 @@ export AbstractSource, AbstractDependency, SetupSource, PatchSource,
     nbits, proc_family, storage_dir, extract_kwargs, extract_fields,
     download_source, setup_workspace, setup_dependencies, update_registry,
     getname, cleanup_dependencies, compress_dir, prepare_for_deletion,
-    run_interactive, sourcify, dependencify, with_logfile, get_concrete_platform
+    run_interactive, sourcify, dependencify, with_logfile, get_concrete_platform,
+    manage_shards
 
 include("compat.jl")
 

src/Rootfs.jl

@@ -1,7 +1,9 @@
 export supported_platforms, expand_gfortran_versions, expand_cxxstring_abis, expand_microarchitectures
 
-using Pkg.Artifacts: load_artifacts_toml, ensure_all_artifacts_installed
+using Pkg.Artifacts: load_artifacts_toml, ensure_all_artifacts_installed, artifact_path
 using Base.BinaryPlatforms: set_compare_strategy!, compare_version_cap
+using REPL.TerminalMenus
+using Printf: @sprintf
 
 # This is a type that encompasses a shard; it makes it easy to pass it around,
 # get its download url, extraction url, mounting url, etc...
@@ -1100,3 +1102,88 @@ function installed_shards()
 
     return all_compiler_shards()[idx]
 end
+
+"""
+    manage_shards(; sort_by=:name, rev=false)
+
+Open a prompt allowing a user to selectively remove downloaded compiler shards.
+By default, the shards are sorted by name, alternatively you can sort them by
+file size on disk by specifying `sort_by=:size`. With `rev=true` you can
+reverse the sort order.
+"""
+function manage_shards(; sort_by=:name, rev=false)
+    # Get all installed shards
+    shards = installed_shards()
+
+    # Obtain directory sizes for the artifacts
+    totalsizes = totalsize.(Artifacts.artifact_path.(shard_source_artifact_hash.(shards)))
+
+    # Sort shards and totalsizes
+    if sort_by === :name
+        function isless_shards(a::CompilerShard, b::CompilerShard)
+            return isless((a.name, a.version, string(a.target), a.host, a.archive_type),
+                          (b.name, b.version, string(b.target), b.host, b.archive_type))
+        end
+
+        perm = sortperm(shards; rev, lt=isless_shards)
+    elseif sort_by == :size
+        perm = sortperm(totalsizes; rev)
+    else
+      error("unsupported sort value: :$sort_by (allowed: :name, :size)")
+    end
+    shards .= shards[perm]
+    totalsizes .= totalsizes[perm]
+
+    # Build menu items
+    menuitems = similar(shards, String)
+    for i in eachindex(shards, totalsizes)
+        menuitems[i] = @sprintf("(%5.3f GiB) %s", totalsizes[i] / 2^30, shards[i])
+    end
+
+    # Prompt user
+    ts = @sprintf("%5.3f", sum(totalsizes) / 2^30)
+    manage_shards_menu = TerminalMenus.request(
+        "Which compiler shards should be removed (total size on disk: $ts GiB)?",
+        TerminalMenus.MultiSelectMenu(menuitems; pagesize = 10, charset=:ascii)
+    )
+
+    # Handle no selection
+    if isempty(manage_shards_menu)
+        println("Removed 0 compiler shards.")
+        return nothing
+    end
+
+    # Otherwise prompt for confirmation
+    println("\nThe following shards have been marked for removal:\n")
+    for item in menuitems[sort(Int.(manage_shards_menu))]
+        println("  ", item)
+    end
+    print("\nAre you sure that these should be removed? [Y/n]: ")
+    answer = lowercase(strip(readline()))
+
+    # If removal is confirmed, deleting the relevant artifacts
+    if isempty(answer) || answer == "yes" || answer == "y"
+        Pkg.remove_artifact.(shard_source_artifact_hash.(shards[Int.(manage_shards_menu)]))
+        println("Removed ", length(manage_shards_menu), " compiler shards.")
+    else
+        println("Removed 0 compiler shards.")
+    end
+end
+
+# Return total size on a disk of a file or directory
+function totalsize(path)
+  if !isdir(path)
+      return filesize(path)
+  end
+
+  total = 0
+  for (root, dirs, files) in walkdir(path)
+    total += filesize(root)
+
+    for file in files
+      total += filesize(joinpath(root, file))
+    end
+  end
+
+  return total
+end