Finish removing the BigInts from * for FD{Int128}!

Finally implements the fast-multiplication optimization from
#45, but this
time for 128-bit FixedDecimals! :)

This is a follow-up to
#93, which
introduces an Int256 type for widemul. However, the fldmod still
required 2 BigInt allocations.

Now, this PR uses a custom implementation of the LLVM div-by-const
optimization for (U)Int256, which briefly widens to Int512 (😅) to
perform the fldmod by the constant 10^f coefficient.

This brings 128-bit FD multiply to the same performance as 64-bit. :)

Author: NHDaly

src/FixedPointDecimals.jl

@@ -36,9 +36,11 @@ export checked_abs, checked_add, checked_cld, checked_div, checked_fld,
 
 using Base: decompose, BitInteger
 
-import BitIntegers  # For 128-bit _widemul / _widen
+using BitIntegers: BitIntegers, UInt256, Int256
 import Parsers
 
+include("fldmod-by-const.jl")
+
 # floats that support fma and are roughly IEEE-like
 const FMAFloat = Union{Float16, Float32, Float64, BigFloat}
 
@@ -129,8 +131,10 @@ _widemul(x::Unsigned,y::Signed) = signed(_widen(x)) * _widen(y)
 
 # Custom widen implementation to avoid the cost of widening to BigInt.
 # FD{Int128} operations should widen to 256 bits internally, rather than to a BigInt.
-_widen(::Type{Int128}) = BitIntegers.Int256
-_widen(::Type{UInt128}) = BitIntegers.UInt256
+_widen(::Type{Int128}) = Int256
+_widen(::Type{UInt128}) = UInt256
+_widen(::Type{Int256}) = BitIntegers.Int512
+_widen(::Type{UInt256}) = BitIntegers.UInt512
 _widen(t::Type) = widen(t)
 _widen(x::T) where {T} = (_widen(T))(x)
 
@@ -196,18 +200,12 @@ function _round_to_nearest(quotient::T,
 end
 _round_to_nearest(q, r, d, m=RoundNearest) = _round_to_nearest(promote(q, r, d)..., m)
 
-# In many of our calls to fldmod, `y` is a constant (the coefficient, 10^f). However, since
-# `fldmod` is sometimes not being inlined, that constant information is not available to the
-# optimizer. We need an inlined version of fldmod so that the compiler can replace expensive
-# divide-by-power-of-ten instructions with the cheaper multiply-by-inverse-coefficient.
-@inline fldmodinline(x,y) = (fld(x,y), mod(x,y))
-
 # multiplication rounds to nearest even representation
 # TODO: can we use floating point to speed this up? after we build a
 # correctness test suite.
 function Base.:*(x::FD{T, f}, y::FD{T, f}) where {T, f}
     powt = coefficient(FD{T, f})
-    quotient, remainder = fldmodinline(_widemul(x.i, y.i), powt)
+    quotient, remainder = fldmod_by_const(_widemul(x.i, y.i), Val(powt))
     reinterpret(FD{T, f}, _round_to_nearest(quotient, remainder, powt))
 end
 
@@ -234,12 +232,12 @@ function Base.round(x::FD{T, f},
                              RoundingMode{:NearestTiesUp},
                              RoundingMode{:NearestTiesAway}}=RoundNearest) where {T, f}
     powt = coefficient(FD{T, f})
-    quotient, remainder = fldmodinline(x.i, powt)
+    quotient, remainder = fldmod_by_const(x.i, Val(powt))
     FD{T, f}(_round_to_nearest(quotient, remainder, powt, m))
 end
 function Base.ceil(x::FD{T, f}) where {T, f}
     powt = coefficient(FD{T, f})
-    quotient, remainder = fldmodinline(x.i, powt)
+    quotient, remainder = fldmod_by_const(x.i, Val(powt))
     if remainder > 0
         FD{T, f}(quotient + one(quotient))
     else
@@ -435,7 +433,7 @@ function Base.checked_sub(x::T, y::T) where {T<:FD}
 end
 function Base.checked_mul(x::FD{T,f}, y::FD{T,f}) where {T<:Integer,f}
     powt = coefficient(FD{T, f})
-    quotient, remainder = fldmodinline(_widemul(x.i, y.i), powt)
+    quotient, remainder = fldmod_by_const(_widemul(x.i, y.i), Val(powt))
     v = _round_to_nearest(quotient, remainder, powt)
     typemin(T) <= v <= typemax(T) || Base.Checked.throw_overflowerr_binaryop(:*, x, y)
     return reinterpret(FD{T, f}, T(v))

src/fldmod-by-const.jl

@@ -0,0 +1,96 @@
+
+const BitInteger256 = Union{UInt256, Int256}
+
+@inline function fldmod_by_const(x, ::Val{y}) where y
+    # For small-to-normal integers, LLVM can correctly optimize away the division, if it
+    # knows it's dividing by a const. We cannot call `Base.fldmod` since it's not
+    # inlined, so here we have explictly inlined it instead.
+    return (fld(x,y), mod(x,y))
+end
+@inline function fldmod_by_const(x::BitInteger256, y::Val{C}) where C
+    # For large or non-standard Int types, LLVM doesn't optimize
+    # well, so we use a custom implementation of fldmod.
+    d = fld_by_const(x, y)
+    return d, manual_mod(promote(x, C, d)...)
+end
+
+# Calculate fld(x,y) when y is a Val constant.
+# The implementation for fld_by_const was lifted directly from Base.fld(x,y), except that
+# it uses `div_by_const` instead of `div`.
+fld_by_const(x::T, y::Val{C}) where {T<:UInt256, C} = div_by_const(x, y)
+function fld_by_const(x::T, y::Val{C}) where {T<:Int256, C}
+    d = div_by_const(x, y)
+    return d - (signbit(x ⊻ C) & (d * C != x))
+end
+
+# Calculate `mod(x,y)` after you've already acquired quotient, the result of `fld(x,y)`.
+# REQUIRES:
+#   - `y != -1`
+@inline function manual_mod(x::T, y::T, quotient::T) where T<:BitInteger256
+    return x - quotient * y
+end
+
+Base.@assume_effects :total function div_by_const(x::T, ::Val{C}) where {T, C}
+    # These checks will be compiled away during specialization.
+    # While for `*(FixedDecimal, FixedDecimal)`, C will always be a power of 10, these
+    # checks allow this function to work for any `C > 0`, in case that's useful in the
+    # future.
+    if C == 1
+        return x
+    elseif ispow2(C)
+        return div(x, C)  # Will already do the right thing
+    elseif C <= 0
+        throw(DomainError("C must be > 0"))
+    end
+    # Calculate the magic number 2^N/C. Note that this is computed statically, not at
+    # runtime.
+    inverse_coeff, toshift = calculate_inverse_coeff(T, C)
+    # Compute the upper-half of widemul(x, 2^nbits(T)/C).
+    # By keeping only the upper half, we're essentially dividing by 2^nbits(T), undoing the
+    # numerator of the multiplication, so that the result is equal to x/C.
+    out = mul_hi(x, inverse_coeff)
+    # This condition will be compiled away during specialization.
+    if T <: Signed
+        # Because our magic number has a leading one (since we shift all-the-way left), the
+        # result is negative if it's Signed. We add x to give us the positive equivalent.
+        out += x
+        signshift = (nbits(x) - 1)
+        isnegative = T(out >>> signshift)  # 1 if < 0 else 0 (Unsigned bitshift to read top bit)
+    end
+    # Undo the bitshifts used to calculate the invoeff magic number with maximum precision.
+    out = out >> toshift
+    if T <: Signed
+        out =  out + isnegative
+    end
+    return T(out)
+end
+
+Base.@assume_effects :foldable function calculate_inverse_coeff(::Type{T}, C) where {T}
+    # First, calculate 2^nbits(T)/C
+    # We shift away leading zeros to preserve the most precision when we use it to multiply
+    # in the next step. At the end, we will shift the final answer back to undo this
+    # operation (which is why we need to return `toshift`).
+    # Note, also, that we calculate invcoeff at double-precision so that the left-shift
+    # doesn't leave trailing zeros. We truncate to only the upper-half before returning.
+    UT = _unsigned(T)
+    invcoeff = typemax(_widen(UT)) ÷ C
+    toshift = leading_zeros(invcoeff)
+    invcoeff = invcoeff << toshift
+    # Now, truncate to only the upper half of invcoeff, after we've shifted. Instead of
+    # bitshifting, we round to maintain precision. (This is needed to prevent off-by-ones.)
+    # -- This is equivalent to `invcoeff = T(invcoeff >> sizeof(T))`, except rounded. --
+    invcoeff = _round_to_nearest(fldmod(invcoeff, typemax(UT))..., typemax(UT)) % T
+    return invcoeff, toshift
+end
+
+function mul_hi(x::T, y::T) where T
+    xy = _widemul(x, y)  # support Int256 -> Int512 (!!)
+    (xy >> nbits(T)) % T
+end
+
+# Annoyingly, Unsigned(T) isn't defined for BitIntegers types:
+# https://github.com/rfourquet/BitIntegers.jl/pull/2
+_unsigned(x) = unsigned(x)
+_unsigned(::Type{Int256}) = UInt256
+
+nbits(x) = sizeof(x) * 8

test/fldmod-by-const_tests.jl

@@ -0,0 +1,58 @@
+using Test
+using FixedPointDecimals
+
+@testset "calculate_inverse_coeff signed" begin
+    using FixedPointDecimals: calculate_inverse_coeff
+
+    # The correct magic number here comes from investigating the following native code
+    # produced on an m2 aarch64 macbook pro:
+    # @code_native ((x)->fld(x,100))(2)
+    #   ...
+    #         mov     x8, #55051
+    #         movk    x8, #28835, lsl #16
+    #         movk    x8, #2621, lsl #32
+    #         movk    x8, #41943, lsl #48
+    # Where:
+    # julia> 55051 | 28835 << 16 | 2621 << 32 | 41943 << 48
+    # -6640827866535438581
+    @test calculate_inverse_coeff(Int64, 100) == (-6640827866535438581, 6)
+
+    # Same for the tests below:
+
+    # (LLVM's magic number is shifted one bit less, then they shift by 2, instead of 3,
+    #  but the result is the same.)
+    @test calculate_inverse_coeff(Int64, 10) == (7378697629483820647 << 1, 3)
+
+    @test calculate_inverse_coeff(Int64, 1) == (1, 0)
+end
+
+@testset "calculate_inverse_coeff signed 4" begin
+    using FixedPointDecimals: calculate_inverse_coeff
+
+    # Same here, our magic number is shifted 2 bits more than LLVM's
+    @test calculate_inverse_coeff(UInt64, 100) == (0xa3d70a3d70a3d70b, 6)
+
+    @test calculate_inverse_coeff(UInt64, 1) == (UInt64(0x1), 0)
+end
+
+@testset "div_by_const" begin
+    vals = [2432, 100, 0x1, Int32(10000), typemax(Int64), typemax(Int16), 8, Int64(2)^32]
+    for a_base in vals
+        # Only test negative numbers on `a`, since div_by_const requires b > 0.
+        @testset for (a, b, f) in Iterators.product((a_base, -a_base), vals, (unsigned, signed))
+            a, b = promote(f(a), f(b))
+            @test FixedPointDecimals.div_by_const(a, Val(b)) == a ÷ b
+        end
+    end
+end
+
+@testset "fldmod_by_const" begin
+    vals = [2432, 100, 0x1, Int32(10000), typemax(Int64), typemax(Int16), 8, Int64(2)^32]
+    for a_base in vals
+        # Only test negative numbers on `a`, since fldmod_by_const requires b > 0.
+        @testset for (a, b, f) in Iterators.product((a_base, -a_base), vals, (unsigned, signed))
+            a, b = promote(f(a), f(b))
+            @test FixedPointDecimals.fldmod_by_const(a, Val(b)) == fldmod(a, b)
+        end
+    end
+end

test/runtests.jl

@@ -10,4 +10,9 @@ include(joinpath(pkg_path, "test", "utils.jl"))
 
 @testset "FixedPointDecimals" begin
     include("FixedDecimal.jl")
-end  # global testset
+end
+
+@testset "FixedPointDecimals" begin
+    include("fldmod-by-const_tests.jl")
+end
+