Using remote debugging and download prefs

[code4dough2000]

If we look at the answer here: https://stackoverflow.com/questions/63091842/cannot-parse-capability-googchromeoptions-from-invalid-argument-unrecognized where it shows passing 2 different option objects to the constructor to get both remote debugging and setting the download folder with prefs - is there a way to do this?

[GCuser99]

Hi @code4dough2000,

Yes, you can read up on how to use the WebCapabilities object in the following links, as well as looking at the examples in the test_Capabilities and test_FileUpDownload modules.

https://github.com/GCuser99/SeleniumVBA/wiki#working-with-capabilities
https://github.com/GCuser99/SeleniumVBA/wiki#information-capture
Discussion 155

Hope that helps,

Mike

[code4dough2000]

Right, I used those as examples, but you can't combine SetDebuggerAddress and SetDownloadPrefs on the same driver capabilities, it will throw an exception saying "cannot parse capability: goog:chromeOptions from invalid argument: unrecognized chrome option: prefs.. either work in isolation, but not together. So far the only solution I've seen is the one referenced in the SSO link

[GCuser99]

Ok, try this where we set the download folder using CDP (in the background):

Sub test_remoteDebugger()
    'This test demonstrates how to connect to an existing Edge\Chrome browser instance and automate tasks.
    'An example usage case - you need to manually login to a website first and then run some automation tasks.
    'The pre-existing browser instance must be started on port 9222 for this to work.
    'One way to launch the pre-existing browser is to create and run a shortcut on Desktop:
    '   "C:\Program Files\Google\Chrome\Application\chrome.exe" --remote-debugging-port=9222 --user-data-dir="<path to temp user profile directory>"
    
    'For more info, see https://github.com/GCuser99/SeleniumVBA/discussions/155
    Dim driver As New WebDriver
    Dim caps As WebCapabilities
    
    'now we start automating the existing browser instance
    driver.StartChrome
    
    Set caps = driver.CreateCapabilities(initializeFromSettingsFile:=False)
    
    'set debugger address to same port as browser
    caps.SetDebuggerAddress "localhost:9222"
    
    driver.OpenBrowser caps
    
    driver.NavigateTo "https://www.selenium.dev/selenium/web/downloads/download.html"
    driver.Wait 500
    
    driver.SetDownloadFolder "%USERPROFILE%\Downloads" 'for Edge and Chrome only - no need to set in capabilities
    
    driver.DeleteFiles "%USERPROFILE%\Downloads\file_1.txt", "%USERPROFILE%\Downloads\file_2.jpg"
    
    driver.FindElementByCssSelector("#file-1").Click
    driver.WaitForDownload "%USERPROFILE%\Downloads\file_1.txt"
    
    driver.FindElementByCssSelector("#file-2").Click
    driver.WaitForDownload "%USERPROFILE%\Downloads\file_2.jpg"
            
    driver.CloseBrowser
    driver.Shutdown
End Sub

[code4dough2000]

Haven't figured out why I am getting a timeout setting capabilities with this snippet - I do see when it sends client.send WebJsonConverter.ConvertToJson(cmdArgs), the driverurl doesn't have the same port for debugging (and yes I am starting chrome with remote debugger switch, I added the code that creates and opens the shortcut to ensure) - not sure though if it should as it maybe a different piece of software running in the middle

[GCuser99]

Haven't figured out why I am getting a timeout setting capabilities with this snippet - I do see when it sends client.send WebJsonConverter.ConvertToJson(cmdArgs), the driverurl doesn't have the same port for debugging (and yes I am starting chrome with remote debugger switch, I added the code that creates and opens the shortcut to ensure) - not sure though if it should as it maybe a different piece of software running in the middle

In the shortcut, are you adding --user-data-dir="path to temp user profile directory"? See this link for recent info. The rule now applies to both Chrome and Edge.

Also, make sure that you kill all Chrome browser processes through the TaskManager before you open your debugger Chrome instance.

If it provides any encouragement, the code I provided above works for me. The driver.SetDownloadFolder must be invoked AFTER driver.OpenBrowser.

[code4dough2000]

Setting the user-data-dir worked - thanks!!

[hanamichi77777]

"driver.SetDownloadFolder ~" downloads to the specified folder on port 9222

[dornech]

I have some code for the preferences for Firefox and Chrome

Sub setBrowserProfile_directDownload(ByRef objWebCapabilities As SeleniumVBA.WebCapabilities, ByVal s_WebdriverBrowser As String, ByRef s_Path As String)

'  check/determine path for direct download
   If (s_Path = vbNullString) Or Not DirExists(s_Path) Then
      s_Path = TempDir()
   End If

'  set browser preferences
   If (s_WebdriverBrowser = s_WebdriverBrowser_Chrome) Then
      objWebCapabilities.SetPreference "download.default_directory", s_Path
      objWebCapabilities.SetPreference "download.prompt_for_download", False
      objWebCapabilities.SetPreference "plugins.plugins_disabled", "[""Chrome PDF Viewer""]"
      objWebCapabilities.SetPreference "plugins.always_open_pdf_externally", True
   ElseIf (s_WebdriverBrowser = s_WebdriverBrowser_FireFox) Then
      objWebCapabilities.SetPreference "browser.download.folderList", 2
      objWebCapabilities.SetPreference "browser.download.dir", s_Path
      objWebCapabilities.SetPreference "browser.download.manager.showWhenStarting", False
      objWebCapabilities.SetPreference "browser.helperApps.alwaysAsk.force", False
      objWebCapabilities.SetPreference "browser.helperApps.neverAsk.saveToDisk", "application/pdf,text/csv"
      objWebCapabilities.SetPreference "pdfjs.disabled", True
   End If

End Sub

However, from the discussion I learned I probably have to get familiar with CDP :-)