integrate logic of puppeteer-extra-plugin-stealth

[dornech]

The puppeteer stealth plugin is for example implemented in Python package Stealthenium, i think this can be easily integrated.
Only requirement is the separate directory to load the JavaScripts.

'stealthenize WebDriver / WebBrowser as anti-bot detection measure
' migration of Python package stealthenium

' stealthenize master routine
Sub stealthenizeWebDriver(objWebDriver As SeleniumVBA.WebDriver)

   Dim _
      dictCDPparam As Dictionary, _
      s_Useragent As String

   Set dictCDPparam = New Dictionary
   dictCDPparam.Add "userAgent", Replace(objWebDriver.GetUserAgent, "HeadlessChrome", "Chrome")
   dictCDPparam.Add "acceptLanguage", "en-US,en,de-DE,de"
   dictCDPparam.Add "platform", "Win32"
   objWebDriver.ExecuteCDP "Network.setUserAgentOverride", dictCDPparam
   Set dictCDPparam = Nothing

   evaluateOnNewDocu objWebDriver, "utils.js"
   evaluateOnNewDocu objWebDriver, "chrome.app.js"
   evaluateOnNewDocu objWebDriver, "chrome.runtime.js", False
   evaluateOnNewDocu objWebDriver, "iframe.contentWindows.js"
   evaluateOnNewDocu objWebDriver, "media.codecs.js"
   evaluateOnNewDocu objWebDriver, "navigator.languages.js", Array("en-US", "en", "de-DE", "de")
   evaluateOnNewDocu objWebDriver, "navigator.permissions.js"
   evaluateOnNewDocu objWebDriver, "navigator.plugins.js"
   evaluateOnNewDocu objWebDriver, "navigator.vendor.js", "Google Inc."
   evaluateOnNewDocu objWebDriver, "navigator.webdriver.js"
   evaluateOnNewDocu objWebDriver, "webgl.vendor.js", "Intel Inc.", "Intel Iris OpenGL Engine"
   evaluateOnNewDocu objWebDriver, "window.outerdimensions.js"
   evaluateOnNewDocu objWebDriver, "hairline.fix.js"

End Sub


Sub evaluateOnNewDocu(objWebDriver As SeleniumVBA.WebDriver, s_ScriptFile As String, ParamArray params() As Variant)

   Static s_PathJS As String

   Dim _
      dictCDPparam As Dictionary, _
      s_Script As String, _
      s_Params As String, _
      var_Param As Variant

   If s_PathJS = vbNullString Then
      s_PathJS = getParamFromINIfile("SeleniumWebUtils", "JSpath")
      If right(s_PathJS, 1) <> "\" Then s_PathJS = s_PathJS & "\"
   End If

   s_Script = readFileToString(s_PathJS & s_ScriptFile)

   s_Params = vbNullString
   For Each var_Param In params()
      If s_Params <> vbNullString Then s_Params = s_Params & ","
      s_Params = s_Params & ConvertToJson(var_Param)
   Next

   Set dictCDPparam = New Dictionary
   dictCDPparam.Add "source", "(" & s_Script & ")(" & s_Params & ")"
   objWebDriver.ExecuteCDP "Page.addScriptToEvaluateOnNewDocument", dictCDPparam

End Sub

[GCuser99]

Very cool and nice use of CDP - I'll try it when I get a chance! I see that evaluateOnNewDocu has a few dependencies not shown in your code block (getParamFromINIfile, readFileToString, and ConvertToJson). For completeness and to make it easier to try, can you provide those in your code block above? For anyone who wishes to try @dornech's migrated stealth plugin above, the javascripts can be found here.

[dornech]

I wanted to focus on the main stuff.
getParamFromINI file is just used to read the JS directory from an INI file. Might be set as constant or parameter as well.
readFileToString just reads the Javascript code to a string - sure everbody else has such a routine.
Amd ConvertToJson is the Json-converter already contained in SeleniumVBA :-)

Moreover: I did not provide settings via parameter as the original stealth plugin does. It is really very straightforward migration from Python to VBA with not to much flexibility.

[dornech]

Actually I used the Javascript from https://github.com/markmelnic/stealthenium/tree/main/stealthenium/js which seems to be a maintained version of the older selenium-stealth Python package

[GCuser99]

Successfully tested your Stealthenium port on bot.sannysoft. Now I need to find a particular use-case for it :-)! Once we have a use-case to demonstrate, then would consider adding to our test suite as a standalone application using SeleniumVBA.

[dornech]

Yea, I did the same. bot.sannysoft is the reference for verification of successful antibot measures or has been for a long time. However, cloudflare WAF is not being passed.