Easy switch between DLL and VBA Addin reference type

[dornech]

Hi,

I thought it might be beneficial to be able to switch between DLL and VBA AddIn type. Without having to replace the calls all the time to the ClassFactory back and forth. I developed a instantion wrapper which is switched via VBA compiler directives. Have fun.

#Const ModeSeleniumVBA = "DLL"
' #Const ModeSeleniumVBA = "VBA"

#If ModeSeleniumVBA = "DLL" Then

'  factory for reference type DLL
   Function instantiateSeleniumVBA(s_Typ) As Object

      Static s_ReferenceFullpath As String
      Static s_ReferenceFile As String

'     check reference
      If s_ReferenceFile = vbNullString Then
         s_ReferenceFullpath = Application.VBE.ActiveVBProject.References("SeleniumVBA").FullPath
         Dim objFSO As New FileSystemObject
         s_ReferenceFile = objFSO.GetFileName(s_ReferenceFullpath)
         Set objFSO = Nothing
         If LCase(Right(s_ReferenceFile, 4)) <> ".dll" Then
            Err.Raise vbObjectError, "SeleniumVBA caller", "Compile option does not match SeleniumVBA reference type."
         End If
      End If
      
'     generate class
      If s_Typ = "WebCookie" Then
         Set instantiateSeleniumVBA = New SeleniumVBA.WebCookie
      ElseIf s_Typ = "WebDriver" Then
         Set instantiateSeleniumVBA = New SeleniumVBA.WebDriver
      ElseIf s_Typ = "WebDriverManager" Then
         Set instantiateSeleniumVBA = New SeleniumVBA.WebDriverManager
      ElseIf s_Typ = "WebElements" Then
         Set instantiateSeleniumVBA = New SeleniumVBA.WebElements
      ElseIf s_Typ = "WebJsonConverter" Then
         Set instantiateSeleniumVBA = New SeleniumVBA.WebJsonConverter
      ElseIf s_Typ = "WebKeyboard" Then
         Set instantiateSeleniumVBA = New SeleniumVBA.WebKeyboard
      ElseIf s_Typ = "WebPrintSettings" Then
         Set instantiateSeleniumVBA = New SeleniumVBA.WebPrintSettings
      Else
         Err.Raise vbObjectError, "SeleniumVBA caller", "SeleniumVBA: invalid class for factory request."
      End If

   End Function

#ElseIf ModeSeleniumVBA = "VBA" Then

'  factory for reference type VBA-AddIn
   Function instantiateSeleniumVBA(s_Typ) As Object

      Static s_ReferenceFullpath As String
      Static s_ReferenceFile As String

'     check reference
      If s_ReferenceFile = vbNullString Then
         s_ReferenceFullpath = Application.VBE.ActiveVBProject.References("SeleniumVBA").FullPath
         Dim objFSO As New FileSystemObject
         s_ReferenceFile = objFSO.GetFileName(s_ReferenceFullpath)
         Set objFSO = Nothing
         If LCase(Right(s_ReferenceFile, 4)) = ".dll" Then
            Err.Raise vbObjectError, "SeleniumVBA caller", "SeleniumVBA caller: Compile option does not match SeleniumVBA reference type."
         End If
      End If

'     generate class
      If s_Typ = "WebCookie" Or s_Typ = "WebDriver" Or s_Typ = "WebDriverManager" Or s_Typ = "WebElements" Or s_Typ = "WebJsonConverter" Or s_Typ = "WebKeyboard" Or s_Typ = "WebPrintSettings" Then
         Set instantiateSeleniumVBA = Application.Run(s_ReferenceFile & "!New_" & s_Typ)
      Else
         Err.Raise vbObjectError, "SeleniumVBA caller", "SeleniumVBA: invalid class for factory request."
      End If
      
   End Function

#Else

' no compile -> leads to error when factory is used

#End If

[GCuser99]

Very cool @dornech - thanks for sharing. BTW, did you know that with the DLL you can instantiate both ways - using the "New" keyword and using the Class Factory? I designed it that way to allow you to copy/paste code from the VBA Add-in to use with the DLL without modification. Of course that only solves the problem of using Class Factory with the DLL , and not the problem of code using "New" with the Add-in, like is solved with your code above. Below is a snapshot of the DLL object model showing the Class Factory class. Anyway, glad you are using the DLL - was wondering whether it was being used...

[dornech]

Obviously i did not know :-)
I think this easens switching. I have to do two things: a) change compiler setting b) change reference.
With your feature only b) change of recerence is necessary (if rest of code is accordingly adjusted).