Replace On_DidChangeConfiguration_Notification

with a job. Increment Project_Stamp on job creation to
shutdown indexing jobs.

Refs #1141

Author: reznikmm

source/ada/lsp-ada_configurations.ads

@@ -26,7 +26,7 @@ with LSP.Structures;
 
 package LSP.Ada_Configurations is
 
-   type Configuration is tagged limited private;
+   type Configuration is tagged private;
 
    procedure Read_JSON
      (Self   : in out Configuration'Class;
@@ -116,7 +116,7 @@ private
 
    use type VSS.Strings.Virtual_String;
 
-   type Configuration is tagged limited record
+   type Configuration is tagged record
       Project_File             : VSS.Strings.Virtual_String;
       Charset                  : VSS.Strings.Virtual_String;
       Relocate_Build_Tree      : VSS.Strings.Virtual_String;

source/ada/lsp-ada_did_change_configurations.adb

@@ -0,0 +1,100 @@
+------------------------------------------------------------------------------
+--                         Language Server Protocol                         --
+--                                                                          --
+--                        Copyright (C) 2024, AdaCore                       --
+--                                                                          --
+-- This is free software;  you can redistribute it  and/or modify it  under --
+-- terms of the  GNU General Public License as published  by the Free Soft- --
+-- ware  Foundation;  either version 3,  or (at your option) any later ver- --
+-- sion.  This software is distributed in the hope  that it will be useful, --
+-- but WITHOUT ANY WARRANTY;  without even the implied warranty of MERCHAN- --
+-- TABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public --
+-- License for  more details.  You should have  received  a copy of the GNU --
+-- General  Public  License  distributed  with  this  software;   see  file --
+-- COPYING3.  If not, go to http://www.gnu.org/licenses for a complete copy --
+-- of the license.                                                          --
+------------------------------------------------------------------------------
+
+with LSP.Ada_Configurations;
+with LSP.Client_Message_Receivers;
+with LSP.Server_Notifications.DidChangeConfiguration;
+
+package body LSP.Ada_Did_Change_Configurations is
+
+   type Apply_Config_Job
+     (Parent : not null access constant Ada_Did_Change_Handler)
+   is limited new LSP.Server_Jobs.Server_Job with record
+      Message       : LSP.Server_Messages.Server_Message_Access;
+      Configuration : LSP.Ada_Configurations.Configuration;
+      Reload        : Boolean;
+      Is_Done       : Boolean := False;
+   end record;
+
+   type Apply_Config_Job_Access is access all Apply_Config_Job;
+
+   overriding function Priority
+     (Self : Apply_Config_Job) return LSP.Server_Jobs.Job_Priority is
+       (LSP.Server_Jobs.Fence);
+
+   overriding function Is_Done (Self : Apply_Config_Job) return Boolean is
+     (Self.Is_Done);
+
+   overriding procedure Execute
+     (Self   : in out Apply_Config_Job;
+      Client :
+        in out LSP.Client_Message_Receivers.Client_Message_Receiver'Class);
+
+   overriding function Message (Self : Apply_Config_Job)
+     return LSP.Server_Messages.Server_Message_Access is (Self.Message);
+
+   -------------
+   -- Execute --
+   -------------
+
+   overriding procedure Execute
+     (Self   : in out Apply_Config_Job;
+      Client :
+        in out LSP.Client_Message_Receivers.Client_Message_Receiver'Class) is
+   begin
+      Self.Parent.Context.Set_Configuration (Self.Configuration);
+
+      if Self.Reload then
+         Self.Parent.Context.Reload_Project;
+      end if;
+
+      Self.Is_Done := True;
+   end Execute;
+
+   ----------------
+   -- Create_Job --
+   ----------------
+
+   overriding function Create_Job
+     (Self    : Ada_Did_Change_Handler;
+      Message : LSP.Server_Messages.Server_Message_Access)
+      return LSP.Server_Jobs.Server_Job_Access
+   is
+      Value : LSP.Server_Notifications.DidChangeConfiguration.Notification
+        renames LSP.Server_Notifications.DidChangeConfiguration.Notification
+          (Message.all);
+
+      Result : constant Apply_Config_Job_Access :=
+        new Apply_Config_Job (Self'Unchecked_Access);
+
+      Reload : Boolean renames Result.Reload;
+   begin
+      Result.Configuration := Self.Context.Get_Configuration.all;
+      Result.Configuration.Read_JSON (Value.Params.settings, Reload);
+
+      --  Always reload project if Project_Tree isn't ready
+      Reload := Reload or not Self.Context.Project_Tree_Is_Defined;
+
+      if Reload then
+         --  Stop indexing by changing project stamp
+         Self.Context.Increment_Project_Timestamp;
+      end if;
+
+      return LSP.Server_Jobs.Server_Job_Access (Result);
+   end Create_Job;
+
+end LSP.Ada_Did_Change_Configurations;

source/ada/lsp-ada_did_change_configurations.ads

@@ -0,0 +1,38 @@
+------------------------------------------------------------------------------
+--                         Language Server Protocol                         --
+--                                                                          --
+--                        Copyright (C) 2024, AdaCore                       --
+--                                                                          --
+-- This is free software;  you can redistribute it  and/or modify it  under --
+-- terms of the  GNU General Public License as published  by the Free Soft- --
+-- ware  Foundation;  either version 3,  or (at your option) any later ver- --
+-- sion.  This software is distributed in the hope  that it will be useful, --
+-- but WITHOUT ANY WARRANTY;  without even the implied warranty of MERCHAN- --
+-- TABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public --
+-- License for  more details.  You should have  received  a copy of the GNU --
+-- General  Public  License  distributed  with  this  software;   see  file --
+-- COPYING3.  If not, go to http://www.gnu.org/licenses for a complete copy --
+-- of the license.                                                          --
+------------------------------------------------------------------------------
+--
+--  This package provides handler and job types for didChangeConfiguration
+--  notifications.
+
+with LSP.Ada_Job_Contexts;
+with LSP.Server_Jobs;
+with LSP.Server_Message_Handlers;
+with LSP.Server_Messages;
+
+package LSP.Ada_Did_Change_Configurations is
+
+   type Ada_Did_Change_Handler
+     (Context : not null access LSP.Ada_Job_Contexts.Ada_Job_Context'Class) is
+       limited new LSP.Server_Message_Handlers.Server_Message_Handler
+         with null record;
+
+   overriding function Create_Job
+     (Self    : Ada_Did_Change_Handler;
+      Message : LSP.Server_Messages.Server_Message_Access)
+        return LSP.Server_Jobs.Server_Job_Access;
+
+end LSP.Ada_Did_Change_Configurations;

source/ada/lsp-ada_driver.adb

@@ -38,6 +38,7 @@ with GNATCOLL.VFS;            use GNATCOLL.VFS;
 with GNATCOLL.Utils;
 
 with LSP.Ada_Commands;
+with LSP.Ada_Did_Change_Configurations;
 with LSP.Ada_Handlers;
 with LSP.Ada_Handlers.Executables_Commands;
 with LSP.Ada_Handlers.Mains_Commands;
@@ -69,6 +70,7 @@ with LSP.GPR_External_Tools;
 with LSP.Memory_Statistics;
 with LSP.Predefined_Completion;
 with LSP.Secure_Message_Loggers;
+with LSP.Server_Notifications.DidChangeConfiguration;
 with LSP.Servers;
 with LSP.Stdio_Streams;
 
@@ -166,6 +168,11 @@ procedure LSP.Ada_Driver is
    GPR_Handler : aliased LSP.GPR_Handlers.Message_Handler
      (Server'Access, Tracer'Unchecked_Access);
 
+   --  Job handlers
+   Ada_Did_Change_Handler : aliased
+     LSP.Ada_Did_Change_Configurations.Ada_Did_Change_Handler
+       (Ada_Handler'Unchecked_Access);
+
    Fuzzing_Activated      : constant Boolean :=
      not VSS.Application.System_Environment.Value ("ALS_FUZZING").Is_Empty;
    pragma Unreferenced (Fuzzing_Activated);
@@ -358,6 +365,10 @@ begin
          LSP.Predefined_Completion.Load_Predefined_Completion_Db
            (Server_Trace);
 
+         Server.Register_Handler
+           (LSP.Server_Notifications.DidChangeConfiguration.Notification'Tag,
+            Ada_Did_Change_Handler'Unchecked_Access);
+
          Server.Run
            (Ada_Handler'Unchecked_Access,
             Tracer'Unchecked_Access,

source/ada/lsp-ada_handlers-project_loading.adb

@@ -654,7 +654,6 @@ package body LSP.Ada_Handlers.Project_Loading is
       Self.Contexts.Cleanup;
 
       Self.Project_Tree.Unload;
-      --  Self.Project_Environment := Empty_Environment;
       Self.Project_Predefined_Sources.Clear;
       Self.Project_Dirs_Loaded.Clear;
 

source/ada/lsp-ada_handlers.adb

@@ -412,6 +412,16 @@ package body LSP.Ada_Handlers is
          Imprecise => Imprecise);
    end Imprecise_Resolve_Name;
 
+   ---------------------------------
+   -- Increment_Project_Timestamp --
+   ---------------------------------
+
+   overriding procedure Increment_Project_Timestamp
+     (Self : in out Message_Handler) is
+   begin
+      Self.Project_Stamp := Self.Project_Stamp + 1;
+   end Increment_Project_Timestamp;
+
    ----------------
    -- Initialize --
    ----------------
@@ -2155,26 +2165,6 @@ package body LSP.Ada_Handlers is
       Self.Publish_Diagnostics (Document);
    end On_DidChange_Notification;
 
-   --------------------------------------------
-   -- On_DidChangeConfiguration_Notification --
-   --------------------------------------------
-
-   overriding procedure On_DidChangeConfiguration_Notification
-     (Self  : in out Message_Handler;
-      Value : LSP.Structures.DidChangeConfigurationParams)
-   is
-      Reload : Boolean;
-   begin
-      Self.Configuration.Read_JSON (Value.settings, Reload);
-
-      --  Always reload project if Project_Tree isn't ready
-      Reload := Reload or not Self.Project_Tree.Is_Defined;
-
-      if Reload then
-         LSP.Ada_Handlers.Project_Loading.Reload_Project (Self);
-      end if;
-   end On_DidChangeConfiguration_Notification;
-
    -------------------------------------------
    -- On_DidChangeWatchedFiles_Notification --
    -------------------------------------------
@@ -4686,6 +4676,26 @@ package body LSP.Ada_Handlers is
       end if;
    end Publish_Diagnostics;
 
+   --------------------
+   -- Reload_Project --
+   --------------------
+
+   overriding procedure Reload_Project (Self : in out Message_Handler) is
+   begin
+      LSP.Ada_Handlers.Project_Loading.Reload_Project (Self);
+   end Reload_Project;
+
+   -----------------------
+   -- Set_Configuration --
+   -----------------------
+
+   overriding procedure Set_Configuration
+     (Self  : in out Message_Handler;
+      Value : LSP.Ada_Configurations.Configuration) is
+   begin
+      Self.Configuration := Value;
+   end Set_Configuration;
+
    -----------------------
    -- To_Workspace_Edit --
    -----------------------

source/ada/lsp-ada_handlers.ads

@@ -33,6 +33,7 @@ with LSP.Ada_Context_Sets;
 with LSP.Ada_Documents;
 with LSP.Ada_File_Sets;
 with LSP.Ada_Highlighters;
+with LSP.Ada_Job_Contexts;
 with LSP.Client_Message_Receivers;
 with LSP.File_Monitors;
 with LSP.Server_Message_Visitors;
@@ -60,6 +61,7 @@ package LSP.Ada_Handlers is
    new LSP.Server_Message_Visitors.Server_Message_Visitor
      and LSP.Server_Request_Receivers.Server_Request_Receiver
      and LSP.Server_Notification_Receivers.Server_Notification_Receiver
+     and LSP.Ada_Job_Contexts.Ada_Job_Context
    with private;
 
    procedure Initialize
@@ -203,9 +205,10 @@ private
    new LSP.Unimplemented_Handlers.Unimplemented_Handler
      and LSP.Server_Message_Visitors.Server_Message_Visitor
      and LSP.Server_Notification_Receivers.Server_Notification_Receiver
+     and LSP.Ada_Job_Contexts.Ada_Job_Context
    with record
       Client : LSP.Ada_Client_Capabilities.Client_Capability;
-      Configuration : LSP.Ada_Configurations.Configuration;
+      Configuration : aliased LSP.Ada_Configurations.Configuration;
 
       Contexts : LSP.Ada_Context_Sets.Context_Set;
       --  There is one context in this list per loaded project.
@@ -362,10 +365,6 @@ private
       Id    : LSP.Structures.Integer_Or_Virtual_String;
       Value : LSP.Structures.DocumentRangeFormattingParams);
 
-   overriding procedure On_DidChangeConfiguration_Notification
-     (Self  : in out Message_Handler;
-      Value : LSP.Structures.DidChangeConfigurationParams);
-
    overriding procedure On_DidChangeWatchedFiles_Notification
      (Self  : in out Message_Handler;
       Value : LSP.Structures.DidChangeWatchedFilesParams);
@@ -488,4 +487,24 @@ private
    --  project tree, or is a runtime file for this project. If the file
    --  is not known to any project, return an empty list.
 
+   ------------------
+   --  Job_Context --
+   ------------------
+
+   overriding function Get_Configuration (Self : Message_Handler)
+     return access constant LSP.Ada_Configurations.Configuration is
+       (Self.Configuration'Unchecked_Access);
+
+   overriding procedure Set_Configuration
+      (Self  : in out Message_Handler;
+       Value : LSP.Ada_Configurations.Configuration);
+
+   overriding procedure Increment_Project_Timestamp
+     (Self : in out Message_Handler);
+
+   overriding function Project_Tree_Is_Defined (Self : Message_Handler)
+     return Boolean is (Self.Project_Tree.Is_Defined);
+
+   overriding procedure Reload_Project (Self : in out Message_Handler);
+
 end LSP.Ada_Handlers;

source/ada/lsp-ada_job_contexts.ads

@@ -0,0 +1,42 @@
+------------------------------------------------------------------------------
+--                         Language Server Protocol                         --
+--                                                                          --
+--                        Copyright (C) 2024, AdaCore                       --
+--                                                                          --
+-- This is free software;  you can redistribute it  and/or modify it  under --
+-- terms of the  GNU General Public License as published  by the Free Soft- --
+-- ware  Foundation;  either version 3,  or (at your option) any later ver- --
+-- sion.  This software is distributed in the hope  that it will be useful, --
+-- but WITHOUT ANY WARRANTY;  without even the implied warranty of MERCHAN- --
+-- TABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public --
+-- License for  more details.  You should have  received  a copy of the GNU --
+-- General  Public  License  distributed  with  this  software;   see  file --
+-- COPYING3.  If not, go to http://www.gnu.org/licenses for a complete copy --
+-- of the license.                                                          --
+------------------------------------------------------------------------------
+--
+--  This package provides interface for data shared between jobs. This data
+--  includes open documents, non-aggregate project trees, settings, etc
+
+with LSP.Ada_Configurations;
+
+package LSP.Ada_Job_Contexts is
+
+   type Ada_Job_Context is limited interface;
+
+   function Get_Configuration (Self : Ada_Job_Context)
+     return access constant LSP.Ada_Configurations.Configuration is abstract;
+
+   procedure Set_Configuration
+      (Self  : in out Ada_Job_Context;
+       Value : LSP.Ada_Configurations.Configuration) is abstract;
+
+   procedure Increment_Project_Timestamp (Self : in out Ada_Job_Context)
+     is abstract;
+
+   function Project_Tree_Is_Defined
+     (Self : Ada_Job_Context) return Boolean is abstract;
+
+   procedure Reload_Project (Self : in out Ada_Job_Context) is abstract;
+
+end LSP.Ada_Job_Contexts;